sysdeps/i386/fpu/s_frexpf.S

   1 /* ix87 specific frexp implementation for float.
   2    Copyright (C) 1997-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include "bp-sym.h"
  22 #include "bp-asm.h"
  23
  24         .section .rodata
  25
  26         .align ALIGNARG(4)
  27         .type two25,@object
  28 two25:  .byte 0, 0, 0, 0x4c
  29         ASM_SIZE_DIRECTIVE(two25)
  30
  31 #ifdef PIC
  32 #define MO(op) op##@GOTOFF(%edx)
  33 #else
  34 #define MO(op) op
  35 #endif
  36
  37 #define PARMS   LINKAGE         /* no space for saved regs */
  38 #define VAL     PARMS
  39 #define EXPP    VAL+4
  40
  41         .text
  42 ENTRY (BP_SYM (__frexpf))
  43
  44         movl    VAL(%esp), %eax
  45         xorl    %ecx, %ecx
  46         movl    %eax, %edx
  47         andl    $0x7fffffff, %eax
  48         jz      1f
  49         cmpl    $0x7f800000, %eax
  50         jae     1f
  51
  52         cmpl    $0x00800000, %eax
  53         jae     2f
  54
  55         flds    VAL(%esp)
  56 #ifdef  PIC
  57         LOAD_PIC_REG (dx)
  58 #endif
  59         fmuls   MO(two25)
  60         movl    $-25, %ecx
  61         fstps   VAL(%esp)
  62         fwait
  63         movl    VAL(%esp), %eax
  64         movl    %eax, %edx
  65         andl    $0x7fffffff, %eax
  66
  67 2:      shrl    $23, %eax
  68         andl    $0x807fffff, %edx
  69         subl    $126, %eax
  70         orl     $0x3f000000, %edx
  71         addl    %eax, %ecx
  72         movl    %edx, VAL(%esp)
  73
  74         /* Store %ecx in the variable pointed to by the second argument,
  75            get the factor from the stack and return.  */
  76 1:      movl    EXPP(%esp), %eax
  77         flds    VAL(%esp)
  78         movl    %ecx, (%eax)
  79
  80         ret
  81 END (BP_SYM (__frexpf))
  82 weak_alias (BP_SYM (__frexpf), BP_SYM (frexpf))