sysdeps/i386/fpu/s_expm1l.S

   1 /* ix87 specific implementation of exp(x)-1.
   2    Copyright (C) 1996-1997, 2002, 2005, 2008, 2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5    Based on code by John C. Bowman <bowman@ipp-garching.mpg.de>.
   6    Corrections by H.J. Lu (hjl@gnu.ai.mit.edu), 1997.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, write to the Free
  20    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21    02111-1307 USA.  */
  22
  23         /* Using: e^x - 1 = 2^(x * log2(e)) - 1 */
  24
  25 #include <sysdep.h>
  26 #include <machine/asm.h>
  27
  28         .section .rodata
  29
  30         .align ALIGNARG(4)
  31         ASM_TYPE_DIRECTIVE(minus1,@object)
  32 minus1: .double -1.0
  33         ASM_SIZE_DIRECTIVE(minus1)
  34         ASM_TYPE_DIRECTIVE(one,@object)
  35 one:    .double 1.0
  36         ASM_SIZE_DIRECTIVE(one)
  37         ASM_TYPE_DIRECTIVE(l2e,@object)
  38 l2e:    .tfloat 1.442695040888963407359924681002
  39         ASM_SIZE_DIRECTIVE(l2e)
  40
  41 #ifdef PIC
  42 #define MO(op) op##@GOTOFF(%edx)
  43 #else
  44 #define MO(op) op
  45 #endif
  46
  47         .text
  48 ENTRY(__expm1l)
  49         movzwl  4+8(%esp), %eax // load sign bit and 15-bit exponent
  50         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  51         cmpl    $0xc006, %eax   // is num positive and exp >= 6 (number is >= 128.0)?
  52         jae     HIDDEN_JUMPTARGET (__expl) // (if num is denormal, it is at least >= 64.0)
  53
  54         fldt    4(%esp)         // x
  55         fxam                    // Is NaN or +-Inf?
  56         fstsw   %ax
  57         movb    $0x45, %ch
  58         andb    %ah, %ch
  59         cmpb    $0x40, %ch
  60         je      3f              // If +-0, jump.
  61 #ifdef  PIC
  62         LOAD_PIC_REG (dx)
  63 #endif
  64         cmpb    $0x05, %ch
  65         je      2f              // If +-Inf, jump.
  66
  67         fldt    MO(l2e)         // log2(e) : x
  68         fmulp                   // log2(e)*x
  69         fld     %st             // log2(e)*x : log2(e)*x
  70         frndint                 // int(log2(e)*x) : log2(e)*x
  71         fsubr   %st, %st(1)     // int(log2(e)*x) : fract(log2(e)*x)
  72         fxch                    // fract(log2(e)*x) : int(log2(e)*x)
  73         f2xm1                   // 2^fract(log2(e)*x)-1 : int(log2(e)*x)
  74         fscale                  // 2^(log2(e)*x)-2^int(log2(e)*x) : int(log2(e)*x)
  75         fxch                    // int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  76         fldl    MO(one)         // 1 : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  77         fscale                  // 2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  78         fsubrl  MO(one)         // 1-2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  79         fstp    %st(1)          // 1-2^int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  80         fsubrp  %st, %st(1)     // 2^(log2(e)*x)
  81         ret
  82
  83 2:      testl   $0x200, %eax    // Test sign.
  84         jz      3f              // If positive, jump.
  85         fstp    %st
  86         fldl    MO(minus1)      // Set result to -1.0.
  87 3:      ret
  88 END(__expm1l)
  89 libm_hidden_def (__expm1l)
  90 weak_alias (__expm1l, expm1l)