sysdeps/i386/fpu/e_powf.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996-1997, 1999, 2001, 2004, 2005, 2007, 2011-2012
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <machine/asm.h>
  22
  23         .section .rodata.cst8,"aM",@progbits,8
  24
  25         .p2align 3
  26         ASM_TYPE_DIRECTIVE(one,@object)
  27 one:    .double 1.0
  28         ASM_SIZE_DIRECTIVE(one)
  29         ASM_TYPE_DIRECTIVE(limit,@object)
  30 limit:  .double 0.29
  31         ASM_SIZE_DIRECTIVE(limit)
  32         ASM_TYPE_DIRECTIVE(p31,@object)
  33 p31:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x41
  34         ASM_SIZE_DIRECTIVE(p31)
  35
  36         .section .rodata.cst16,"aM",@progbits,16
  37
  38         .p2align 3
  39         ASM_TYPE_DIRECTIVE(infinity,@object)
  40 inf_zero:
  41 infinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  43         ASM_SIZE_DIRECTIVE(infinity)
  44         ASM_TYPE_DIRECTIVE(zero,@object)
  45 zero:   .double 0.0
  46         ASM_SIZE_DIRECTIVE(zero)
  47         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  48 minf_mzero:
  49 minfinity:
  50         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  51 mzero:
  52         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  53         ASM_SIZE_DIRECTIVE(minf_mzero)
  54
  55 #ifdef PIC
  56 # define MO(op) op##@GOTOFF(%ecx)
  57 # define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  58 #else
  59 # define MO(op) op
  60 # define MOX(op,x,f) op(,x,f)
  61 #endif
  62
  63         .text
  64 ENTRY(__ieee754_powf)
  65         flds    8(%esp) // y
  66         fxam
  67
  68 #ifdef  PIC
  69         LOAD_PIC_REG (cx)
  70 #endif
  71
  72         fnstsw
  73         movb    %ah, %dl
  74         andb    $0x45, %ah
  75         cmpb    $0x40, %ah      // is y == 0 ?
  76         je      11f
  77
  78         cmpb    $0x05, %ah      // is y == ±inf ?
  79         je      12f
  80
  81         cmpb    $0x01, %ah      // is y == NaN ?
  82         je      30f
  83
  84         flds    4(%esp)         // x : y
  85
  86         subl    $4, %esp
  87         cfi_adjust_cfa_offset (4)
  88
  89         fxam
  90         fnstsw
  91         movb    %ah, %dh
  92         andb    $0x45, %ah
  93         cmpb    $0x40, %ah
  94         je      20f             // x is ±0
  95
  96         cmpb    $0x05, %ah
  97         je      15f             // x is ±inf
  98
  99         fxch                    // y : x
 100
 101         /* fistpl raises invalid exception for |y| >= 1L<<31.  */
 102         fld     %st             // y : y : x
 103         fabs                    // |y| : y : x
 104         fcompl  MO(p31)         // y : x
 105         fnstsw
 106         sahf
 107         jnc     2f
 108
 109         /* First see whether `y' is a natural number.  In this case we
 110            can use a more precise algorithm.  */
 111         fld     %st             // y : y : x
 112         fistpl  (%esp)          // y : x
 113         fildl   (%esp)          // int(y) : y : x
 114         fucomp  %st(1)          // y : x
 115         fnstsw
 116         sahf
 117         jne     2f
 118
 119         /* OK, we have an integer value for y.  */
 120         popl    %edx
 121         cfi_adjust_cfa_offset (-4)
 122         orl     $0, %edx
 123         fstp    %st(0)          // x
 124         jns     4f              // y >= 0, jump
 125         fdivrl  MO(one)         // 1/x          (now referred to as x)
 126         negl    %edx
 127 4:      fldl    MO(one)         // 1 : x
 128         fxch
 129
 130 6:      shrl    $1, %edx
 131         jnc     5f
 132         fxch
 133         fmul    %st(1)          // x : ST*x
 134         fxch
 135 5:      fmul    %st(0), %st     // x*x : ST*x
 136         testl   %edx, %edx
 137         jnz     6b
 138         fstp    %st(0)          // ST*x
 139         ret
 140
 141         /* y is ±NAN */
 142 30:     flds    4(%esp)         // x : y
 143         fldl    MO(one)         // 1.0 : x : y
 144         fucomp  %st(1)          // x : y
 145         fnstsw
 146         sahf
 147         je      31f
 148         fxch                    // y : x
 149 31:     fstp    %st(1)
 150         ret
 151
 152         cfi_adjust_cfa_offset (4)
 153         .align ALIGNARG(4)
 154 2:      /* y is a real number.  */
 155         fxch                    // x : y
 156         fldl    MO(one)         // 1.0 : x : y
 157         fldl    MO(limit)       // 0.29 : 1.0 : x : y
 158         fld     %st(2)          // x : 0.29 : 1.0 : x : y
 159         fsub    %st(2)          // x-1 : 0.29 : 1.0 : x : y
 160         fabs                    // |x-1| : 0.29 : 1.0 : x : y
 161         fucompp                 // 1.0 : x : y
 162         fnstsw
 163         fxch                    // x : 1.0 : y
 164         sahf
 165         ja      7f
 166         fsub    %st(1)          // x-1 : 1.0 : y
 167         fyl2xp1                 // log2(x) : y
 168         jmp     8f
 169
 170 7:      fyl2x                   // log2(x) : y
 171 8:      fmul    %st(1)          // y*log2(x) : y
 172         fst     %st(1)          // y*log2(x) : y*log2(x)
 173         frndint                 // int(y*log2(x)) : y*log2(x)
 174         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 175         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 176         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 177         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 178         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 179         addl    $4, %esp
 180         cfi_adjust_cfa_offset (-4)
 181         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 182         ret
 183
 184
 185         // pow(x,±0) = 1
 186         .align ALIGNARG(4)
 187 11:     fstp    %st(0)          // pop y
 188         fldl    MO(one)
 189         ret
 190
 191         // y == ±inf
 192         .align ALIGNARG(4)
 193 12:     fstp    %st(0)          // pop y
 194         fldl    MO(one)         // 1
 195         flds    4(%esp)         // x : 1
 196         fabs                    // abs(x) : 1
 197         fucompp                 // < 1, == 1, or > 1
 198         fnstsw
 199         andb    $0x45, %ah
 200         cmpb    $0x45, %ah
 201         je      13f             // jump if x is NaN
 202
 203         cmpb    $0x40, %ah
 204         je      14f             // jump if |x| == 1
 205
 206         shlb    $1, %ah
 207         xorb    %ah, %dl
 208         andl    $2, %edx
 209         fldl    MOX(inf_zero, %edx, 4)
 210         ret
 211
 212         .align ALIGNARG(4)
 213 14:     fldl    MO(one)
 214         ret
 215
 216         .align ALIGNARG(4)
 217 13:     flds    4(%esp)         // load x == NaN
 218         ret
 219
 220         cfi_adjust_cfa_offset (4)
 221         .align ALIGNARG(4)
 222         // x is ±inf
 223 15:     fstp    %st(0)          // y
 224         testb   $2, %dh
 225         jz      16f             // jump if x == +inf
 226
 227         // We must find out whether y is an odd integer.
 228         fld     %st             // y : y
 229         fistpl  (%esp)          // y
 230         fildl   (%esp)          // int(y) : y
 231         fucompp                 // <empty>
 232         fnstsw
 233         sahf
 234         jne     17f
 235
 236         // OK, the value is an integer, but is the number of bits small
 237         // enough so that all are coming from the mantissa?
 238         popl    %edx
 239         cfi_adjust_cfa_offset (-4)
 240         testb   $1, %dl
 241         jz      18f             // jump if not odd
 242         movl    %edx, %eax
 243         orl     %edx, %edx
 244         jns     155f
 245         negl    %eax
 246 155:    cmpl    $0x01000000, %eax
 247         ja      18f             // does not fit in mantissa bits
 248         // It's an odd integer.
 249         shrl    $31, %edx
 250         fldl    MOX(minf_mzero, %edx, 8)
 251         ret
 252
 253         cfi_adjust_cfa_offset (4)
 254         .align ALIGNARG(4)
 255 16:     fcompl  MO(zero)
 256         addl    $4, %esp
 257         cfi_adjust_cfa_offset (-4)
 258         fnstsw
 259         shrl    $5, %eax
 260         andl    $8, %eax
 261         fldl    MOX(inf_zero, %eax, 1)
 262         ret
 263
 264         cfi_adjust_cfa_offset (4)
 265         .align ALIGNARG(4)
 266 17:     shll    $30, %edx       // sign bit for y in right position
 267         addl    $4, %esp
 268         cfi_adjust_cfa_offset (-4)
 269 18:     shrl    $31, %edx
 270         fldl    MOX(inf_zero, %edx, 8)
 271         ret
 272
 273         cfi_adjust_cfa_offset (4)
 274         .align ALIGNARG(4)
 275         // x is ±0
 276 20:     fstp    %st(0)          // y
 277         testb   $2, %dl
 278         jz      21f             // y > 0
 279
 280         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 281         testb   $2, %dh
 282         jz      25f
 283
 284         fld     %st             // y : y
 285         fistpl  (%esp)          // y
 286         fildl   (%esp)          // int(y) : y
 287         fucompp                 // <empty>
 288         fnstsw
 289         sahf
 290         jne     26f
 291
 292         // OK, the value is an integer, but is the number of bits small
 293         // enough so that all are coming from the mantissa?
 294         popl    %edx
 295         cfi_adjust_cfa_offset (-4)
 296         testb   $1, %dl
 297         jz      27f             // jump if not odd
 298         cmpl    $0xff000000, %edx
 299         jbe     27f             // does not fit in mantissa bits
 300         // It's an odd integer.
 301         // Raise divide-by-zero exception and get minus infinity value.
 302         fldl    MO(one)
 303         fdivl   MO(zero)
 304         fchs
 305         ret
 306
 307         cfi_adjust_cfa_offset (4)
 308 25:     fstp    %st(0)
 309 26:     addl    $4, %esp
 310         cfi_adjust_cfa_offset (-4)
 311 27:     // Raise divide-by-zero exception and get infinity value.
 312         fldl    MO(one)
 313         fdivl   MO(zero)
 314         ret
 315
 316         cfi_adjust_cfa_offset (4)
 317         .align ALIGNARG(4)
 318         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 319 21:     testb   $2, %dh
 320         jz      22f
 321
 322         fld     %st             // y : y
 323         fistpl  (%esp)          // y
 324         fildl   (%esp)          // int(y) : y
 325         fucompp                 // <empty>
 326         fnstsw
 327         sahf
 328         jne     23f
 329
 330         // OK, the value is an integer, but is the number of bits small
 331         // enough so that all are coming from the mantissa?
 332         popl    %edx
 333         cfi_adjust_cfa_offset (-4)
 334         testb   $1, %dl
 335         jz      24f             // jump if not odd
 336         cmpl    $0xff000000, %edx
 337         jae     24f             // does not fit in mantissa bits
 338         // It's an odd integer.
 339         fldl    MO(mzero)
 340         ret
 341
 342         cfi_adjust_cfa_offset (4)
 343 22:     fstp    %st(0)
 344 23:     addl    $4, %esp        // Don't use pop.
 345         cfi_adjust_cfa_offset (-4)
 346 24:     fldl    MO(zero)
 347         ret
 348
 349 END(__ieee754_powf)
 350 strong_alias (__ieee754_powf, __powf_finite)