sysdeps/i386/fpu/e_powf.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996-1997, 1999, 2001, 2004, 2005, 2007, 2011-2012
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <machine/asm.h>
  22
  23         .section .rodata.cst8,"aM",@progbits,8
  24
  25         .p2align 3
  26         ASM_TYPE_DIRECTIVE(one,@object)
  27 one:    .double 1.0
  28         ASM_SIZE_DIRECTIVE(one)
  29         ASM_TYPE_DIRECTIVE(limit,@object)
  30 limit:  .double 0.29
  31         ASM_SIZE_DIRECTIVE(limit)
  32         ASM_TYPE_DIRECTIVE(p31,@object)
  33 p31:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x41
  34         ASM_SIZE_DIRECTIVE(p31)
  35
  36         .section .rodata.cst16,"aM",@progbits,16
  37
  38         .p2align 3
  39         ASM_TYPE_DIRECTIVE(infinity,@object)
  40 inf_zero:
  41 infinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  43         ASM_SIZE_DIRECTIVE(infinity)
  44         ASM_TYPE_DIRECTIVE(zero,@object)
  45 zero:   .double 0.0
  46         ASM_SIZE_DIRECTIVE(zero)
  47         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  48 minf_mzero:
  49 minfinity:
  50         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  51 mzero:
  52         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  53         ASM_SIZE_DIRECTIVE(minf_mzero)
  54
  55 #ifdef PIC
  56 # define MO(op) op##@GOTOFF(%ecx)
  57 # define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  58 #else
  59 # define MO(op) op
  60 # define MOX(op,x,f) op(,x,f)
  61 #endif
  62
  63         .text
  64 ENTRY(__ieee754_powf)
  65         flds    8(%esp) // y
  66         fxam
  67
  68 #ifdef  PIC
  69         LOAD_PIC_REG (cx)
  70 #endif
  71
  72         fnstsw
  73         movb    %ah, %dl
  74         andb    $0x45, %ah
  75         cmpb    $0x40, %ah      // is y == 0 ?
  76         je      11f
  77
  78         cmpb    $0x05, %ah      // is y == ±inf ?
  79         je      12f
  80
  81         cmpb    $0x01, %ah      // is y == NaN ?
  82         je      30f
  83
  84         flds    4(%esp)         // x : y
  85
  86         subl    $4, %esp
  87         cfi_adjust_cfa_offset (4)
  88
  89         fxam
  90         fnstsw
  91         movb    %ah, %dh
  92         andb    $0x45, %ah
  93         cmpb    $0x40, %ah
  94         je      20f             // x is ±0
  95
  96         cmpb    $0x05, %ah
  97         je      15f             // x is ±inf
  98
  99         fxch                    // y : x
 100
 101         /* fistpl raises invalid exception for |y| >= 1L<<31.  */
 102         fld     %st             // y : y : x
 103         fabs                    // |y| : y : x
 104         fcompl  MO(p31)         // y : x
 105         fnstsw
 106         sahf
 107         jnc     2f
 108
 109         /* First see whether `y' is a natural number.  In this case we
 110            can use a more precise algorithm.  */
 111         fld     %st             // y : y : x
 112         fistpl  (%esp)          // y : x
 113         fildl   (%esp)          // int(y) : y : x
 114         fucomp  %st(1)          // y : x
 115         fnstsw
 116         sahf
 117         jne     3f
 118
 119         /* OK, we have an integer value for y.  */
 120         popl    %edx
 121         cfi_adjust_cfa_offset (-4)
 122         orl     $0, %edx
 123         fstp    %st(0)          // x
 124         jns     4f              // y >= 0, jump
 125         fdivrl  MO(one)         // 1/x          (now referred to as x)
 126         negl    %edx
 127 4:      fldl    MO(one)         // 1 : x
 128         fxch
 129
 130 6:      shrl    $1, %edx
 131         jnc     5f
 132         fxch
 133         fmul    %st(1)          // x : ST*x
 134         fxch
 135 5:      fmul    %st(0), %st     // x*x : ST*x
 136         testl   %edx, %edx
 137         jnz     6b
 138         fstp    %st(0)          // ST*x
 139         ret
 140
 141         /* y is ±NAN */
 142 30:     flds    4(%esp)         // x : y
 143         fldl    MO(one)         // 1.0 : x : y
 144         fucomp  %st(1)          // x : y
 145         fnstsw
 146         sahf
 147         je      31f
 148         fxch                    // y : x
 149 31:     fstp    %st(1)
 150         ret
 151
 152         cfi_adjust_cfa_offset (4)
 153         .align ALIGNARG(4)
 154 2:      /* y is a large integer (so even).  */
 155         fxch                    // x : y
 156         fabs                    // |x| : y
 157         fxch                    // y : x
 158         .align ALIGNARG(4)
 159 3:      /* y is a real number.  */
 160         fxch                    // x : y
 161         fldl    MO(one)         // 1.0 : x : y
 162         fldl    MO(limit)       // 0.29 : 1.0 : x : y
 163         fld     %st(2)          // x : 0.29 : 1.0 : x : y
 164         fsub    %st(2)          // x-1 : 0.29 : 1.0 : x : y
 165         fabs                    // |x-1| : 0.29 : 1.0 : x : y
 166         fucompp                 // 1.0 : x : y
 167         fnstsw
 168         fxch                    // x : 1.0 : y
 169         sahf
 170         ja      7f
 171         fsub    %st(1)          // x-1 : 1.0 : y
 172         fyl2xp1                 // log2(x) : y
 173         jmp     8f
 174
 175 7:      fyl2x                   // log2(x) : y
 176 8:      fmul    %st(1)          // y*log2(x) : y
 177         fst     %st(1)          // y*log2(x) : y*log2(x)
 178         frndint                 // int(y*log2(x)) : y*log2(x)
 179         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 180         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 181         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 182         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 183         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 184         addl    $4, %esp
 185         cfi_adjust_cfa_offset (-4)
 186         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 187         ret
 188
 189
 190         // pow(x,±0) = 1
 191         .align ALIGNARG(4)
 192 11:     fstp    %st(0)          // pop y
 193         fldl    MO(one)
 194         ret
 195
 196         // y == ±inf
 197         .align ALIGNARG(4)
 198 12:     fstp    %st(0)          // pop y
 199         fldl    MO(one)         // 1
 200         flds    4(%esp)         // x : 1
 201         fabs                    // abs(x) : 1
 202         fucompp                 // < 1, == 1, or > 1
 203         fnstsw
 204         andb    $0x45, %ah
 205         cmpb    $0x45, %ah
 206         je      13f             // jump if x is NaN
 207
 208         cmpb    $0x40, %ah
 209         je      14f             // jump if |x| == 1
 210
 211         shlb    $1, %ah
 212         xorb    %ah, %dl
 213         andl    $2, %edx
 214         fldl    MOX(inf_zero, %edx, 4)
 215         ret
 216
 217         .align ALIGNARG(4)
 218 14:     fldl    MO(one)
 219         ret
 220
 221         .align ALIGNARG(4)
 222 13:     flds    4(%esp)         // load x == NaN
 223         ret
 224
 225         cfi_adjust_cfa_offset (4)
 226         .align ALIGNARG(4)
 227         // x is ±inf
 228 15:     fstp    %st(0)          // y
 229         testb   $2, %dh
 230         jz      16f             // jump if x == +inf
 231
 232         // fistpl raises invalid exception for |y| >= 1L<<31, so test
 233         // that (in which case y is certainly even) before testing
 234         // whether y is odd.
 235         fld     %st             // y : y
 236         fabs                    // |y| : y
 237         fcompl  MO(p31)         // y
 238         fnstsw
 239         sahf
 240         jnc     16f
 241
 242         // We must find out whether y is an odd integer.
 243         fld     %st             // y : y
 244         fistpl  (%esp)          // y
 245         fildl   (%esp)          // int(y) : y
 246         fucompp                 // <empty>
 247         fnstsw
 248         sahf
 249         jne     17f
 250
 251         // OK, the value is an integer.
 252         popl    %edx
 253         cfi_adjust_cfa_offset (-4)
 254         testb   $1, %dl
 255         jz      18f             // jump if not odd
 256         // It's an odd integer.
 257         shrl    $31, %edx
 258         fldl    MOX(minf_mzero, %edx, 8)
 259         ret
 260
 261         cfi_adjust_cfa_offset (4)
 262         .align ALIGNARG(4)
 263 16:     fcompl  MO(zero)
 264         addl    $4, %esp
 265         cfi_adjust_cfa_offset (-4)
 266         fnstsw
 267         shrl    $5, %eax
 268         andl    $8, %eax
 269         fldl    MOX(inf_zero, %eax, 1)
 270         ret
 271
 272         cfi_adjust_cfa_offset (4)
 273         .align ALIGNARG(4)
 274 17:     shll    $30, %edx       // sign bit for y in right position
 275         addl    $4, %esp
 276         cfi_adjust_cfa_offset (-4)
 277 18:     shrl    $31, %edx
 278         fldl    MOX(inf_zero, %edx, 8)
 279         ret
 280
 281         cfi_adjust_cfa_offset (4)
 282         .align ALIGNARG(4)
 283         // x is ±0
 284 20:     fstp    %st(0)          // y
 285         testb   $2, %dl
 286         jz      21f             // y > 0
 287
 288         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 289         testb   $2, %dh
 290         jz      25f
 291
 292         // fistpl raises invalid exception for |y| >= 1L<<31, so test
 293         // that (in which case y is certainly even) before testing
 294         // whether y is odd.
 295         fld     %st             // y : y
 296         fabs                    // |y| : y
 297         fcompl  MO(p31)         // y
 298         fnstsw
 299         sahf
 300         jnc     25f
 301
 302         fld     %st             // y : y
 303         fistpl  (%esp)          // y
 304         fildl   (%esp)          // int(y) : y
 305         fucompp                 // <empty>
 306         fnstsw
 307         sahf
 308         jne     26f
 309
 310         // OK, the value is an integer.
 311         popl    %edx
 312         cfi_adjust_cfa_offset (-4)
 313         testb   $1, %dl
 314         jz      27f             // jump if not odd
 315         // It's an odd integer.
 316         // Raise divide-by-zero exception and get minus infinity value.
 317         fldl    MO(one)
 318         fdivl   MO(zero)
 319         fchs
 320         ret
 321
 322         cfi_adjust_cfa_offset (4)
 323 25:     fstp    %st(0)
 324 26:     addl    $4, %esp
 325         cfi_adjust_cfa_offset (-4)
 326 27:     // Raise divide-by-zero exception and get infinity value.
 327         fldl    MO(one)
 328         fdivl   MO(zero)
 329         ret
 330
 331         cfi_adjust_cfa_offset (4)
 332         .align ALIGNARG(4)
 333         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 334 21:     testb   $2, %dh
 335         jz      22f
 336
 337         // fistpl raises invalid exception for |y| >= 1L<<31, so test
 338         // that (in which case y is certainly even) before testing
 339         // whether y is odd.
 340         fcoml   MO(p31)         // y
 341         fnstsw
 342         sahf
 343         jnc     22f
 344
 345         fld     %st             // y : y
 346         fistpl  (%esp)          // y
 347         fildl   (%esp)          // int(y) : y
 348         fucompp                 // <empty>
 349         fnstsw
 350         sahf
 351         jne     23f
 352
 353         // OK, the value is an integer.
 354         popl    %edx
 355         cfi_adjust_cfa_offset (-4)
 356         testb   $1, %dl
 357         jz      24f             // jump if not odd
 358         // It's an odd integer.
 359         fldl    MO(mzero)
 360         ret
 361
 362         cfi_adjust_cfa_offset (4)
 363 22:     fstp    %st(0)
 364 23:     addl    $4, %esp        // Don't use pop.
 365         cfi_adjust_cfa_offset (-4)
 366 24:     fldl    MO(zero)
 367         ret
 368
 369 END(__ieee754_powf)
 370 strong_alias (__ieee754_powf, __powf_finite)