sysdeps/i386/fpu/e_pow.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996-1999, 2001, 2004-2005, 2007, 2011-2012
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <machine/asm.h>
  22
  23         .section .rodata.cst8,"aM",@progbits,8
  24
  25         .p2align 3
  26         ASM_TYPE_DIRECTIVE(one,@object)
  27 one:    .double 1.0
  28         ASM_SIZE_DIRECTIVE(one)
  29         ASM_TYPE_DIRECTIVE(limit,@object)
  30 limit:  .double 0.29
  31         ASM_SIZE_DIRECTIVE(limit)
  32         ASM_TYPE_DIRECTIVE(p63,@object)
  33 p63:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x43
  34         ASM_SIZE_DIRECTIVE(p63)
  35
  36         .section .rodata.cst16,"aM",@progbits,16
  37
  38         .p2align 3
  39         ASM_TYPE_DIRECTIVE(infinity,@object)
  40 inf_zero:
  41 infinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  43         ASM_SIZE_DIRECTIVE(infinity)
  44         ASM_TYPE_DIRECTIVE(zero,@object)
  45 zero:   .double 0.0
  46         ASM_SIZE_DIRECTIVE(zero)
  47         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  48 minf_mzero:
  49 minfinity:
  50         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  51 mzero:
  52         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  53         ASM_SIZE_DIRECTIVE(minf_mzero)
  54
  55 #ifdef PIC
  56 # define MO(op) op##@GOTOFF(%ecx)
  57 # define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  58 #else
  59 # define MO(op) op
  60 # define MOX(op,x,f) op(,x,f)
  61 #endif
  62
  63         .text
  64 ENTRY(__ieee754_pow)
  65         fldl    12(%esp)        // y
  66         fxam
  67
  68 #ifdef  PIC
  69         LOAD_PIC_REG (cx)
  70 #endif
  71
  72         fnstsw
  73         movb    %ah, %dl
  74         andb    $0x45, %ah
  75         cmpb    $0x40, %ah      // is y == 0 ?
  76         je      11f
  77
  78         cmpb    $0x05, %ah      // is y == ±inf ?
  79         je      12f
  80
  81         cmpb    $0x01, %ah      // is y == NaN ?
  82         je      30f
  83
  84         fldl    4(%esp)         // x : y
  85
  86         subl    $8,%esp
  87         cfi_adjust_cfa_offset (8)
  88
  89         fxam
  90         fnstsw
  91         movb    %ah, %dh
  92         andb    $0x45, %ah
  93         cmpb    $0x40, %ah
  94         je      20f             // x is ±0
  95
  96         cmpb    $0x05, %ah
  97         je      15f             // x is ±inf
  98
  99         fxch                    // y : x
 100
 101         /* fistpll raises invalid exception for |y| >= 1L<<63.  */
 102         fld     %st             // y : y : x
 103         fabs                    // |y| : y : x
 104         fcompl  MO(p63)         // y : x
 105         fnstsw
 106         sahf
 107         jnc     2f
 108
 109         /* First see whether `y' is a natural number.  In this case we
 110            can use a more precise algorithm.  */
 111         fld     %st             // y : y : x
 112         fistpll (%esp)          // y : x
 113         fildll  (%esp)          // int(y) : y : x
 114         fucomp  %st(1)          // y : x
 115         fnstsw
 116         sahf
 117         jne     2f
 118
 119         /* OK, we have an integer value for y.  */
 120         popl    %eax
 121         cfi_adjust_cfa_offset (-4)
 122         popl    %edx
 123         cfi_adjust_cfa_offset (-4)
 124         orl     $0, %edx
 125         fstp    %st(0)          // x
 126         jns     4f              // y >= 0, jump
 127         fdivrl  MO(one)         // 1/x          (now referred to as x)
 128         negl    %eax
 129         adcl    $0, %edx
 130         negl    %edx
 131 4:      fldl    MO(one)         // 1 : x
 132         fxch
 133
 134 6:      shrdl   $1, %edx, %eax
 135         jnc     5f
 136         fxch
 137         fmul    %st(1)          // x : ST*x
 138         fxch
 139 5:      fmul    %st(0), %st     // x*x : ST*x
 140         shrl    $1, %edx
 141         movl    %eax, %ecx
 142         orl     %edx, %ecx
 143         jnz     6b
 144         fstp    %st(0)          // ST*x
 145         ret
 146
 147         /* y is ±NAN */
 148 30:     fldl    4(%esp)         // x : y
 149         fldl    MO(one)         // 1.0 : x : y
 150         fucomp  %st(1)          // x : y
 151         fnstsw
 152         sahf
 153         je      31f
 154         fxch                    // y : x
 155 31:     fstp    %st(1)
 156         ret
 157
 158         cfi_adjust_cfa_offset (8)
 159         .align ALIGNARG(4)
 160 2:      /* y is a real number.  */
 161         fxch                    // x : y
 162         fldl    MO(one)         // 1.0 : x : y
 163         fldl    MO(limit)       // 0.29 : 1.0 : x : y
 164         fld     %st(2)          // x : 0.29 : 1.0 : x : y
 165         fsub    %st(2)          // x-1 : 0.29 : 1.0 : x : y
 166         fabs                    // |x-1| : 0.29 : 1.0 : x : y
 167         fucompp                 // 1.0 : x : y
 168         fnstsw
 169         fxch                    // x : 1.0 : y
 170         sahf
 171         ja      7f
 172         fsub    %st(1)          // x-1 : 1.0 : y
 173         fyl2xp1                 // log2(x) : y
 174         jmp     8f
 175
 176 7:      fyl2x                   // log2(x) : y
 177 8:      fmul    %st(1)          // y*log2(x) : y
 178         fst     %st(1)          // y*log2(x) : y*log2(x)
 179         frndint                 // int(y*log2(x)) : y*log2(x)
 180         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 181         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 182         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 183         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 184         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 185         addl    $8, %esp
 186         cfi_adjust_cfa_offset (-8)
 187         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 188         ret
 189
 190
 191         // pow(x,±0) = 1
 192         .align ALIGNARG(4)
 193 11:     fstp    %st(0)          // pop y
 194         fldl    MO(one)
 195         ret
 196
 197         // y == ±inf
 198         .align ALIGNARG(4)
 199 12:     fstp    %st(0)          // pop y
 200         fldl    MO(one)         // 1
 201         fldl    4(%esp)         // x : 1
 202         fabs                    // abs(x) : 1
 203         fucompp                 // < 1, == 1, or > 1
 204         fnstsw
 205         andb    $0x45, %ah
 206         cmpb    $0x45, %ah
 207         je      13f             // jump if x is NaN
 208
 209         cmpb    $0x40, %ah
 210         je      14f             // jump if |x| == 1
 211
 212         shlb    $1, %ah
 213         xorb    %ah, %dl
 214         andl    $2, %edx
 215         fldl    MOX(inf_zero, %edx, 4)
 216         ret
 217
 218         .align ALIGNARG(4)
 219 14:     fldl    MO(one)
 220         ret
 221
 222         .align ALIGNARG(4)
 223 13:     fldl    4(%esp)         // load x == NaN
 224         ret
 225
 226         cfi_adjust_cfa_offset (8)
 227         .align ALIGNARG(4)
 228         // x is ±inf
 229 15:     fstp    %st(0)          // y
 230         testb   $2, %dh
 231         jz      16f             // jump if x == +inf
 232
 233         // We must find out whether y is an odd integer.
 234         fld     %st             // y : y
 235         fistpll (%esp)          // y
 236         fildll  (%esp)          // int(y) : y
 237         fucompp                 // <empty>
 238         fnstsw
 239         sahf
 240         jne     17f
 241
 242         // OK, the value is an integer, but is the number of bits small
 243         // enough so that all are coming from the mantissa?
 244         popl    %eax
 245         cfi_adjust_cfa_offset (-4)
 246         popl    %edx
 247         cfi_adjust_cfa_offset (-4)
 248         andb    $1, %al
 249         jz      18f             // jump if not odd
 250         movl    %edx, %eax
 251         orl     %edx, %edx
 252         jns     155f
 253         negl    %eax
 254 155:    cmpl    $0x00200000, %eax
 255         ja      18f             // does not fit in mantissa bits
 256         // It's an odd integer.
 257         shrl    $31, %edx
 258         fldl    MOX(minf_mzero, %edx, 8)
 259         ret
 260
 261         cfi_adjust_cfa_offset (8)
 262         .align ALIGNARG(4)
 263 16:     fcompl  MO(zero)
 264         addl    $8, %esp
 265         cfi_adjust_cfa_offset (-8)
 266         fnstsw
 267         shrl    $5, %eax
 268         andl    $8, %eax
 269         fldl    MOX(inf_zero, %eax, 1)
 270         ret
 271
 272         cfi_adjust_cfa_offset (8)
 273         .align ALIGNARG(4)
 274 17:     shll    $30, %edx       // sign bit for y in right position
 275         addl    $8, %esp
 276         cfi_adjust_cfa_offset (-8)
 277 18:     shrl    $31, %edx
 278         fldl    MOX(inf_zero, %edx, 8)
 279         ret
 280
 281         cfi_adjust_cfa_offset (8)
 282         .align ALIGNARG(4)
 283         // x is ±0
 284 20:     fstp    %st(0)          // y
 285         testb   $2, %dl
 286         jz      21f             // y > 0
 287
 288         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 289         testb   $2, %dh
 290         jz      25f
 291
 292         fld     %st             // y : y
 293         fistpll (%esp)          // y
 294         fildll  (%esp)          // int(y) : y
 295         fucompp                 // <empty>
 296         fnstsw
 297         sahf
 298         jne     26f
 299
 300         // OK, the value is an integer, but is the number of bits small
 301         // enough so that all are coming from the mantissa?
 302         popl    %eax
 303         cfi_adjust_cfa_offset (-4)
 304         popl    %edx
 305         cfi_adjust_cfa_offset (-4)
 306         andb    $1, %al
 307         jz      27f             // jump if not odd
 308         cmpl    $0xffe00000, %edx
 309         jbe     27f             // does not fit in mantissa bits
 310         // It's an odd integer.
 311         // Raise divide-by-zero exception and get minus infinity value.
 312         fldl    MO(one)
 313         fdivl   MO(zero)
 314         fchs
 315         ret
 316
 317         cfi_adjust_cfa_offset (8)
 318 25:     fstp    %st(0)
 319 26:     addl    $8, %esp
 320         cfi_adjust_cfa_offset (-8)
 321 27:     // Raise divide-by-zero exception and get infinity value.
 322         fldl    MO(one)
 323         fdivl   MO(zero)
 324         ret
 325
 326         cfi_adjust_cfa_offset (8)
 327         .align ALIGNARG(4)
 328         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 329 21:     testb   $2, %dh
 330         jz      22f
 331
 332         fld     %st             // y : y
 333         fistpll (%esp)          // y
 334         fildll  (%esp)          // int(y) : y
 335         fucompp                 // <empty>
 336         fnstsw
 337         sahf
 338         jne     23f
 339
 340         // OK, the value is an integer, but is the number of bits small
 341         // enough so that all are coming from the mantissa?
 342         popl    %eax
 343         cfi_adjust_cfa_offset (-4)
 344         popl    %edx
 345         cfi_adjust_cfa_offset (-4)
 346         andb    $1, %al
 347         jz      24f             // jump if not odd
 348         cmpl    $0xffe00000, %edx
 349         jae     24f             // does not fit in mantissa bits
 350         // It's an odd integer.
 351         fldl    MO(mzero)
 352         ret
 353
 354         cfi_adjust_cfa_offset (8)
 355 22:     fstp    %st(0)
 356 23:     addl    $8, %esp        // Don't use 2 x pop
 357         cfi_adjust_cfa_offset (-8)
 358 24:     fldl    MO(zero)
 359         ret
 360
 361 END(__ieee754_pow)
 362 strong_alias (__ieee754_pow, __pow_finite)