sysdeps/i386/fpu/e_atanh.S

   1 /* ix87 specific implementation of arctanh function.
   2    Copyright (C) 1996, 1999, 2005, 2011-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21
  22         .section .rodata
  23
  24         .align ALIGNARG(4)
  25         .type half,@object
  26 half:   .double 0.5
  27         ASM_SIZE_DIRECTIVE(half)
  28         .type one,@object
  29 one:    .double 1.0
  30         ASM_SIZE_DIRECTIVE(one)
  31         .type limit,@object
  32 limit:  .double 0.29
  33         ASM_SIZE_DIRECTIVE(limit)
  34         .type ln2_2,@object
  35 ln2_2:  .tfloat 0.3465735902799726547086160
  36         ASM_SIZE_DIRECTIVE(ln2_2)
  37
  38 #ifdef PIC
  39 #define MO(op) op##@GOTOFF(%edx)
  40 #else
  41 #define MO(op) op
  42 #endif
  43
  44         .text
  45 ENTRY(__ieee754_atanh)
  46         movl    8(%esp), %ecx
  47
  48         movl    %ecx, %eax
  49         andl    $0x7fffffff, %eax
  50         cmpl    $0x7ff00000, %eax
  51         jae     5f
  52 7:
  53
  54 #ifdef PIC
  55         call    1f
  56         cfi_adjust_cfa_offset (4)
  57 1:      popl    %edx
  58         cfi_adjust_cfa_offset (-4)
  59         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  60 #endif
  61
  62         andl    $0x80000000, %ecx // ECX == 0 iff X >= 0
  63
  64         fldt    MO(ln2_2)       // 0.5*ln2
  65         xorl    %ecx, 8(%esp)
  66         fldl    4(%esp)         // |x| : 0.5*ln2
  67         fcoml   MO(half)        // |x| : 0.5*ln2
  68         fld     %st             // |x| : |x| : 0.5*ln2
  69         fnstsw                  // |x| : |x| : 0.5*ln2
  70         sahf
  71         jae     2f
  72         fadd    %st, %st(1)     // |x| : 2*|x| : 0.5*ln2
  73         fld     %st             // |x| : |x| : 2*|x| : 0.5*ln2
  74         fsubrl  MO(one)         // 1-|x| : |x| : 2*|x| : 0.5*ln2
  75         fxch                    // |x| : 1-|x| : 2*|x| : 0.5*ln2
  76         fmul    %st(2)          // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
  77         fdivp                   // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
  78         faddp                   // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  79         fcoml   MO(limit)       // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  80         fnstsw                  // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  81         sahf
  82         jae     4f
  83         fyl2xp1                 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  84         jecxz   3f
  85         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  86 3:      ret
  87
  88         .align ALIGNARG(4)
  89 4:      faddl   MO(one)         // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  90         fyl2x                   // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  91         jecxz   3f
  92         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  93 3:      ret
  94
  95         .align ALIGNARG(4)
  96 2:      faddl   MO(one)         // 1+|x| : |x| : 0.5*ln2
  97         fxch                    // |x| : 1+|x| : 0.5*ln2
  98         fsubrl  MO(one)         // 1-|x| : 1+|x| : 0.5*ln2
  99         fdivrp                  // (1+|x|)/(1-|x|) : 0.5*ln2
 100         fyl2x                   // 0.5*ln2*ld((1+|x|)/(1-|x|))
 101         jecxz   3f
 102         fchs                    // 0.5*ln2*ld((1+x)/(1-x))
 103 3:      ret
 104
 105         // x == NaN or ±Inf
 106 5:      ja      6f
 107         cmpl    $0, 4(%esp)
 108         je      7b
 109 6:      fldl    4(%esp)
 110         ret
 111 END(__ieee754_atanh)
 112 strong_alias (__ieee754_atanh, __atanh_finite)