sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <jmpbuf-offsets.h>
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27 #include <stap-probe.h>
  28
  29 #define PARMS   LINKAGE         /* no space for saved regs */
  30 #define JMPBUF  PARMS
  31 #define SIGMSK  JMPBUF+PTR_SIZE
  32
  33 ENTRY (BP_SYM (_setjmp))
  34
  35         xorl %eax, %eax
  36         movl JMPBUF(%esp), %edx
  37
  38         /* Save registers.  */
  39         movl %ebx, (JB_BX*4)(%edx)
  40         movl %esi, (JB_SI*4)(%edx)
  41         movl %edi, (JB_DI*4)(%edx)
  42         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%ecx)
  45 #endif
  46         movl %ecx, (JB_SP*4)(%edx)
  47         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  48         LIBC_PROBE (setjmp, 3, 4@%edx, -4@$0, 4@%ecx)
  49 #ifdef PTR_MANGLE
  50         PTR_MANGLE (%ecx)
  51 #endif
  52         movl %ecx, (JB_PC*4)(%edx)
  53         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  54
  55         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  56         ret
  57 END (BP_SYM (_setjmp))
  58 libc_hidden_def (_setjmp)