sysdeps/alpha/alphaev67/strcat.S

   1 /* Copyright (C) 2000, 2003 Free Software Foundation, Inc.
   2    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   3    EV67 optimized by Rick Gorton <rick.gorton@alpha-processor.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* Append a null-terminated string from SRC to DST.  */
  22
  23 #include <sysdep.h>
  24
  25         .arch ev6
  26         .set noreorder
  27         .text
  28
  29 ENTRY(strcat)
  30         ldgp    gp, 0(pv)
  31 #ifdef PROF
  32         .set noat
  33         lda     AT, _mcount
  34         jsr     AT, (AT), _mcount
  35         .set at
  36 #endif
  37         .prologue 1
  38
  39         mov     $16, $0         # E : set up return value
  40         /* Find the end of the string.  */
  41         ldq_u   $1, 0($16)      # L : load first quadword (a0 may be misaligned)
  42         lda     $2, -1          # E :
  43         insqh   $2, $16, $2     # U :
  44
  45         andnot  $16, 7, $16     # E :
  46         or      $2, $1, $1      # E :
  47         cmpbge  $31, $1, $2     # E : bits set iff byte == 0
  48         bne     $2, $found      # U :
  49
  50 $loop:  ldq     $1, 8($16)      # L :
  51         addq    $16, 8, $16     # E :
  52         cmpbge  $31, $1, $2     # E :
  53         beq     $2, $loop       # U :
  54
  55 $found: cttz    $2, $3          # U0 :
  56         addq    $16, $3, $16    # E :
  57         /* Now do the append.  */
  58         mov     $26, $23        # E :
  59         jmp     $31, __stxcpy   # L0 :
  60
  61         END(strcat)
  62 libc_hidden_builtin_def (strcat)