sys/v4l2/meson.build

   1 v4l2_sources = [
   2   'gstv4l2.c',
   3   'gstv4l2allocator.c',
   4   'gstv4l2colorbalance.c',
   5   'gstv4l2deviceprovider.c',
   6   'gstv4l2object.c',
   7   'gstv4l2bufferpool.c',
   8   'gstv4l2sink.c',
   9   'gstv4l2src.c',
  10   'gstv4l2radio.c',
  11   'gstv4l2tuner.c',
  12   'gstv4l2transform.c',
  13   'gstv4l2videodec.c',
  14   'gstv4l2videoenc.c',
  15   'gstv4l2h263enc.c',
  16   'gstv4l2h264enc.c',
  17   'gstv4l2mpeg4enc.c',
  18   'gstv4l2vidorient.c',
  19   'gstv4l2vp8enc.c',
  20   'gstv4l2vp9enc.c',
  21   'v4l2_calls.c',
  22   'v4l2-utils.c',
  23   'tuner.c',
  24   'tunerchannel.c',
  25   'tunernorm.c'
  26 ]
  27
  28 v4l2 = get_option('v4l2')
  29 if v4l2.disabled()
  30   have_v4l2 = false
  31   message('V4L2 plugin is disabled')
  32 else
  33   have_v4l2 = cc.has_header('linux/videodev2.h') or cc.has_header('sys/videodev2.h') or cc.has_header('sys/videoio.h')
  34   if v4l2.enabled() and not have_v4l2
  35     error('V4L2 is requested but headers were not found')
  36   endif
  37 endif
  38
  39 cdata.set('GST_V4L2_ENABLE_PROBE', get_option('v4l2-probe'))
  40
  41 if have_v4l2
  42   message('building v4l2 plugin')
  43   cdata.set('HAVE_GST_V4L2', true)
  44   gudev_dep = dependency('gudev-1.0', version : '>=147', required : get_option('v4l2-gudev'))
  45   cdata.set('HAVE_GUDEV', gudev_dep.found())
  46
  47   # libv4l2 is only needed for converting some obscure formats
  48   # FIXME: Add a full list of the formats here
  49   libv4l2_dep = dependency('libv4l2', required : get_option('v4l2-libv4l2'))
  50   cdata.set('HAVE_LIBV4L2', libv4l2_dep.found())
  51
  52   gstv4l2 = library('gstvideo4linux2',
  53     v4l2_sources,
  54     c_args : gst_plugins_good_args,
  55     include_directories : [configinc, libsinc],
  56     dependencies : [gstbase_dep, gstvideo_dep, gstallocators_dep, gudev_dep, libv4l2_dep],
  57     install : true,
  58     install_dir : plugins_install_dir,
  59   )
  60   pkgconfig.generate(gstv4l2, install_dir : plugins_pkgconfig_install_dir)
  61 endif