sys/v4l2/meson.build

   1 v4l2_sources = [
   2   'gstv4l2.c',
   3   'gstv4l2allocator.c',
   4   'gstv4l2colorbalance.c',
   5   'gstv4l2deviceprovider.c',
   6   'gstv4l2object.c',
   7   'gstv4l2bufferpool.c',
   8   'gstv4l2sink.c',
   9   'gstv4l2src.c',
  10   'gstv4l2radio.c',
  11   'gstv4l2tuner.c',
  12   'gstv4l2transform.c',
  13   'gstv4l2videodec.c',
  14   'gstv4l2videoenc.c',
  15   'gstv4l2h263enc.c',
  16   'gstv4l2h264enc.c',
  17   'gstv4l2mpeg4enc.c',
  18   'gstv4l2vidorient.c',
  19   'gstv4l2vp8enc.c',
  20   'gstv4l2vp9enc.c',
  21   'v4l2_calls.c',
  22   'v4l2-utils.c',
  23   'tuner.c',
  24   'tunerchannel.c',
  25   'tunernorm.c'
  26 ]
  27
  28 cdata.set('GST_V4L2_ENABLE_PROBE', get_option('v4l2-probe'))
  29
  30 if cc.has_header('linux/videodev2.h') or cc.has_header('sys/videodev2.h') or cc.has_header('sys/videoio.h')
  31   message('building v4l2 plugin')
  32   cdata.set('HAVE_GST_V4L2', true)
  33   gudev_dep = dependency('gudev-1.0', version : '>=147', required : false)
  34   cdata.set('HAVE_GUDEV', gudev_dep.found())
  35
  36   # libv4l2 is only needed for converting some obscure formats
  37   # FIXME: Add a full list of the formats here
  38   if get_option('with-libv4l2')
  39     libv4l2_dep = dependency('libv4l2', required : false)
  40     cdata.set('HAVE_LIBV4L2', libv4l2_dep.found())
  41     libv4l2_deps = [libv4l2_dep]
  42   else
  43     libv4l2_deps = []
  44   endif
  45
  46   gstv4l2 = library('gstvideo4linux2',
  47     v4l2_sources,
  48     c_args : gst_plugins_good_args,
  49     include_directories : [configinc, libsinc],
  50     dependencies : [gstbase_dep, gstvideo_dep, gstallocators_dep, gudev_dep] + libv4l2_deps,
  51     install : true,
  52     install_dir : plugins_install_dir,
  53   )
  54 endif