sys/oss/meson.build

   1 oss_header_locations = [
   2   # Linux and newer BSD versions
   3   ['sys/soundcard.h', 'HAVE_OSS_INCLUDE_IN_SYS', 'OSS includes are in sys/'],
   4   # Some old BSD versions and also newer OpenBSD versions
   5   ['soundcard.h', 'HAVE_OSS_INCLUDE_IN_ROOT', 'OSS includes are in root'],
   6   # Some old BSD versions
   7   ['machine/soundcard.h', 'HAVE_OSS_INCLUDE_IN_MACHINE', 'OSS includes are in machine/'],
   8 ]
   9
  10 have_oss = false
  11 foreach hdr : oss_header_locations
  12   if not have_oss
  13     if cc.has_header(hdr[0])
  14       cdata.set(hdr[1], 1, description: hdr[2])
  15       have_oss = true
  16     endif
  17   endif
  18 endforeach
  19
  20 if have_oss
  21   library('gstossaudio',
  22     'gstossaudio.c', 'gstosshelper.c', 'gstosssink.c', 'gstosssrc.c',
  23     c_args : gst_plugins_good_args,
  24     include_directories : [configinc, libsinc],
  25     dependencies : [gstaudio_dep, gstbase_dep],
  26     install : true,
  27     install_dir : plugins_install_dir)
  28 endif