sys/d3d11/meson.build

   1 d3d11_sources = [
   2   'gstd3d11bufferpool.c',
   3   'gstd3d11device.c',
   4   'gstd3d11memory.c',
   5   'gstd3d11utils.c',
   6   'gstd3d11videosink.c',
   7   'gstd3d11window.c',
   8   'plugin.c',
   9 ]
  10
  11 have_d3d11 = false
  12 extra_c_args = []
  13 extra_dep = []
  14
  15 d3d11_option = get_option('d3d11')
  16 if host_system != 'windows' or d3d11_option.disabled()
  17   subdir_done()
  18 endif
  19
  20 d3d11_lib = cc.find_library('d3d11', required : d3d11_option)
  21 dxgi_lib = cc.find_library('dxgi', required : d3d11_option)
  22
  23 have_d3d11 = d3d11_lib.found() and dxgi_lib.found() and cc.has_header('d3d11.h') and cc.has_header('dxgi.h')
  24 if not have_d3d11
  25   if d3d11_option.enabled()
  26     error('The d3d11 plugin was enabled explicitly, but required dependencies were not found.')
  27   endif
  28   subdir_done()
  29 endif
  30
  31 # required for HDR meatadata
  32 if cc.has_header('dxgi1_5.h')
  33   extra_c_args += ['-DHAVE_DXGI_1_5_H']
  34 endif
  35
  36 # for enabling debug layer
  37 if cc.has_header('d3d11sdklayers.h')
  38   extra_c_args += ['-DHAVE_D3D11SDKLAYER_H']
  39   extra_dep += [gmodule_dep]
  40 endif
  41
  42 gstd3d11 = library('gstd3d11',
  43   d3d11_sources,
  44   c_args : gst_plugins_bad_args + extra_c_args,
  45   include_directories : [configinc],
  46   dependencies : [gstbase_dep, gstvideo_dep, d3d11_lib, dxgi_lib] + extra_dep,
  47   install : true,
  48   install_dir : plugins_install_dir,
  49 )
  50 pkgconfig.generate(gstd3d11, install_dir : plugins_pkgconfig_install_dir)
  51 plugins += [gstd3d11]