8060b7495894d982dcb0007de832d0c663bdc772
[platform/upstream/gstreamer.git] / subprojects / gst-rtsp-server / docs / meson.build
1 build_hotdoc = false
2
3 if meson.is_cross_build()
4     if get_option('doc').enabled()
5         error('Documentation enabled but building the doc while cross building is not supported yet.')
6     endif
7
8     message('Documentation not built as building it while cross building is not supported yet.')
9     subdir_done()
10 endif
11
12 required_hotdoc_extensions = ['gi-extension', 'gst-extension']
13 if gst_dep.type_name() == 'internal'
14     gst_proj = subproject('gstreamer')
15     plugins_cache_generator = gst_proj.get_variable('plugins_cache_generator')
16 else
17     required_hotdoc_extensions += ['gst-extension']
18     plugins_cache_generator = find_program(join_paths(gst_dep.get_pkgconfig_variable('libexecdir'), 'gstreamer-' + api_version, 'gst-plugins-doc-cache-generator'),
19         required: false)
20 endif
21
22 plugins_cache = join_paths(meson.current_source_dir(), 'gst_plugins_cache.json')
23 if plugins.length() == 0
24     message('All rtsp-server plugins have been disabled')
25 elif plugins_cache_generator.found()
26     plugins_doc_dep = custom_target('rtsp-server-plugins-doc-cache',
27         command: [plugins_cache_generator, plugins_cache, '@OUTPUT@', '@INPUT@'],
28         input: plugins,
29         output: 'gst_plugins_cache.json',
30     )
31 else
32     warning('GStreamer plugin inspector for documentation not found, can\'t update the cache')
33 endif
34
35 hotdoc_p = find_program('hotdoc', required: get_option('doc'))
36 if not hotdoc_p.found()
37     message('Hotdoc not found, not building the documentation')
38     subdir_done()
39 endif
40
41 hotdoc_req = '>= 0.11.0'
42 hotdoc_version = run_command(hotdoc_p, '--version').stdout()
43 if not hotdoc_version.version_compare(hotdoc_req)
44     if get_option('doc').enabled()
45         error('Hotdoc version @0@ not found, got @1@'.format(hotdoc_req, hotdoc_version))
46     else
47         message('Hotdoc version @0@ not found, got @1@'.format(hotdoc_req, hotdoc_version))
48         subdir_done()
49     endif
50 endif
51
52 hotdoc = import('hotdoc')
53 foreach extension: required_hotdoc_extensions
54     if not hotdoc.has_extensions(extension)
55         if get_option('doc').enabled()
56             error('Documentation enabled but @0@ missing'.format(extension))
57         endif
58
59         message('@0@ extension not found, not building documentation'.format(extension))
60         subdir_done()
61     endif
62 endforeach
63
64 if static_build
65     if get_option('doc').enabled()
66         error('Documentation enabled but not supported when building statically.')
67     endif
68
69     message('Building statically, can\'t build the documentation')
70     subdir_done()
71 endif
72
73 if not build_gir
74     if get_option('doc').enabled()
75         error('Documentation enabled but introspection not built.')
76     endif
77
78     message('Introspection not built, can\'t build the documentation')
79     subdir_done()
80 endif
81
82 build_hotdoc = true
83 hotdoc = import('hotdoc')
84
85 libs_doc = [hotdoc.generate_doc('gst-rtsp-server',
86     project_version: api_version,
87     gi_c_sources: ['../gst/rtsp-server/*.[hc]'],
88     gi_sources: rtsp_server_gir[0].full_path(),
89     sitemap: 'sitemap.txt',
90     index: 'index.md',
91     gi_index: 'index.md',
92     gi_smart_index: true,
93     gi_order_generated_subpages: true,
94 )]
95
96 plugins_doc = [hotdoc.generate_doc('rtspclientsink',
97     project_version: api_version,
98     sitemap: 'plugin-sitemap.txt',
99     index: 'plugin-index.md',
100     gst_index: 'plugin-index.md',
101     gst_c_sources: ['../gst/rtsp-sink/*.[ch]'],
102     gst_dl_sources: [rtspsink.full_path()],
103     gst_smart_index: true,
104     dependencies: gst_rtsp_server_deps + [rtspsink],
105     gst_cache_file: plugins_cache,
106     gst_plugin_name: 'rtspclientsink',
107 )]
108 doc = libs_doc[0]