subprojects/gst-plugins-good/tests/check/meson.build

   1 valgrind_dep = dependency('valgrind', required: false).partial_dependency(compile_args : true)
   2 if valgrind_dep.found()
   3   cdata.set('HAVE_VALGRIND', 1)
   4 endif
   5
   6 # internal helper lib for unit testing audio parsers
   7 libparser = static_library('libparser', 'elements/parser.c',
   8   c_args : gst_plugins_good_args + ['-DGST_USE_UNSTABLE_API'],
   9   include_directories : [configinc],
  10   dependencies : [gstcheck_dep],
  11   install : false)
  12
  13 libparser_dep = declare_dependency(link_with : libparser,
  14   dependencies : gstcheck_dep)
  15
  16 # name, condition when to skip the test and extra dependencies
  17 good_tests = [
  18   [ 'elements/audioamplify', false, [gstfft_dep] ],
  19   [ 'elements/audiochebband', false, [gstfft_dep] ],
  20   [ 'elements/audiocheblimit', false, [gstfft_dep] ],
  21   [ 'elements/audiodynamic', false, [gstfft_dep] ],
  22   [ 'elements/audioecho', false, [gstfft_dep] ],
  23   [ 'elements/audiofirfilter', false, [gstfft_dep] ],
  24   [ 'elements/audioiirfilter', false, [gstfft_dep] ],
  25   [ 'elements/audioinvert', false, [gstfft_dep] ],
  26   [ 'elements/audiopanorama', false, [gstfft_dep] ],
  27   [ 'elements/audiowsincband', false, [gstfft_dep] ],
  28   [ 'elements/audiowsinclimit', false, [gstfft_dep] ],
  29   [ 'elements/alphacolor' ],
  30   [ 'elements/alpha' ],
  31   [ 'elements/avimux', false, [gstriff_dep] ],
  32   [ 'elements/avisubtitle', false, [gstriff_dep] ],
  33   [ 'elements/capssetter' ],
  34   [ 'elements/aacparse', false, [libparser_dep] ],
  35   [ 'elements/ac3parse', false, [libparser_dep] ],
  36   [ 'elements/amrparse', false, [libparser_dep] ],
  37   [ 'elements/flacparse', false, [libparser_dep] ],
  38   [ 'elements/mpegaudioparse', false, [libparser_dep] ],
  39   [ 'elements/autodetect' ],
  40   [ 'elements/deinterlace' ],
  41   [ 'elements/dtmf' ],
  42   [ 'elements/flvdemux' ],
  43   [ 'elements/flvmux' ],
  44   [ 'elements/mulawdec' ],
  45   [ 'elements/mulawenc' ],
  46   [ 'elements/icydemux' ],
  47   [ 'elements/id3demux' ],
  48   [ 'elements/imagefreeze' ],
  49   [ 'elements/deinterleave' ],
  50   [ 'elements/interleave' ],
  51   [ 'elements/level' ],
  52   [ 'elements/matroskademux', false, [gstriff_dep] ],
  53   [ 'elements/matroskamux', false, [gstriff_dep] ],
  54   [ 'elements/matroskaparse', false, [gstriff_dep] ],
  55   [ 'elements/multifile' ],
  56   [ 'elements/splitmuxsink', ],
  57   [ 'elements/splitmuxsinktimecode', ],
  58   [ 'elements/splitmuxsrc', ],
  59   [ 'elements/qtmux', false, [gstriff_dep, zlib_dep] ],
  60   [ 'elements/qtdemux', false, [gstriff_dep, zlib_dep] ],
  61   [ 'elements/rganalysis' ],
  62   [ 'elements/rglimiter' ],
  63   [ 'elements/rgvolume' ],
  64   [ 'elements/rtphdrext-colorspace' ],
  65   [ 'elements/rtph261' ],
  66   [ 'elements/rtph263' ],
  67   [ 'elements/rtph264' ],
  68   [ 'elements/rtph265' ],
  69   [ 'elements/rtpopus' ],
  70   [ 'elements/rtpvp8' ],
  71   [ 'elements/rtpvp9' ],
  72   [ 'elements/rtpbin' ],
  73   [ 'elements/rtpbin_buffer_list' ],
  74   [ 'elements/rtpcollision' ],
  75   [ 'elements/rtpfunnel' ],
  76   [ 'elements/rtphdrextclientaudiolevel', false, [gstsdp_dep, gstaudio_dep] ],
  77   [ 'elements/rtphdrextsdes', false, [gstrtp_dep, gstsdp_dep] ],
  78   [ 'elements/rtpjitterbuffer' ],
  79   [ 'elements/rtpjpeg' ],
  80
  81   [ 'elements/rtptimerqueue', false, [gstrtp_dep],
  82       ['../../gst/rtpmanager/rtptimerqueue.c']],
  83
  84   [ 'elements/rtpmux' ],
  85   [ 'elements/rtpptdemux' ],
  86   [ 'elements/rtprtx' ],
  87   [ 'elements/rtpsession' ],
  88   [ 'elements/rtpstorage', false, [],  ['../../gst/rtp/gstrtpstorage.c',
  89                                         '../../gst/rtp/gstrtpelement.c',
  90                                         '../../gst/rtp/gstrtputils.c',
  91                                         '../../gst/rtp/rtpstorage.c',
  92                                         '../../gst/rtp/rtpstoragestream.c']],
  93   [ 'elements/rtpred' ],
  94   [ 'elements/rtpulpfec' ],
  95   [ 'elements/rtpssrcdemux' ],
  96   [ 'elements/rtp-payloading' ],
  97   [ 'elements/rtpst2022-1-fecdec' ],
  98   [ 'elements/rtpst2022-1-fecenc' ],
  99   [ 'elements/spectrum', false, [gstfft_dep] ],
 100   [ 'elements/shapewipe' ],
 101   [ 'elements/udpsink' ],
 102   [ 'elements/udpsrc' ],
 103   [ 'elements/videobox' ],
 104   [ 'elements/videocrop' ],
 105   [ 'elements/videofilter' ],
 106   [ 'elements/videoflip' ],
 107   [ 'elements/videomixer' ],
 108   [ 'elements/aspectratiocrop' ],
 109   [ 'pipelines/wavenc' ],
 110   [ 'elements/wavparse', false, [gstriff_dep] ],
 111   [ 'elements/wavpackparse', ],
 112   [ 'elements/y4menc' ],
 113   [ 'pipelines/effectv' ],
 114   [ 'elements/equalizer' ],
 115   [ 'pipelines/simple-launch-lines' ],
 116   [ 'pipelines/tagschecking' ],
 117   [ 'generic/states' ],
 118 ]
 119
 120 # FIXME: valgrind elements/rtp-payloading - needs fixing
 121 # elements/videocrop should be disabled since it takes way too long in valgrind
 122
 123 libsoup2_dep = dependency('libsoup-2.4', version : '>=2.48',
 124                           required : false, fallback : ['libsoup', 'libsoup_dep'],
 125                           default_options: ['sysprof=disabled'])
 126 libsoup3_dep = dependency('libsoup-3.0', required : false,
 127                            fallback : ['libsoup3', 'libsoup_dep'])
 128
 129 # FIXME: unistd dependency or not tested yet on windows
 130 if host_machine.system() != 'windows'
 131   good_tests += [
 132     [ 'pipelines/flacdec', not flac_dep.found() ],
 133     [ 'elements/gdkpixbufsink', not gdkpixbuf_dep.found(), [gdkpixbuf_dep] ],
 134     [ 'elements/gdkpixbufoverlay', not gdkpixbuf_dep.found() ],
 135     [ 'elements/jpegdec', not jpeglib.found() ],
 136     [ 'elements/jpegenc', not jpeglib.found() ],
 137     [ 'elements/mpg123audiodec', not mpg123_dep.found(), [gstfft_dep]],
 138     [ 'elements/souphttpsrc', not libsoup2_dep.found(), [libsoup2_dep], [], 'elements/souphttpsrc2'],
 139     [ 'elements/souphttpsrc', not libsoup3_dep.found(), [libsoup3_dep], [], 'elements/souphttpsrc3'],
 140     [ 'elements/id3v2mux', not taglib_dep.found() ],
 141     [ 'elements/apev2mux', not taglib_dep.found() ],
 142     [ 'elements/vp8enc', not vpx_dep.found() or not have_vp8_encoder ],
 143     [ 'elements/vp8dec', not vpx_dep.found() or not have_vp8_decoder ],
 144     [ 'elements/vp9enc', not vpx_dep.found() or not have_vp9_encoder ],
 145     [ 'pipelines/lame', not lame_dep.found() ],
 146     [ 'elements/wavpackdec', not wavpack_dep.found() ],
 147     [ 'elements/wavpackenc', not wavpack_dep.found() ],
 148     [ 'pipelines/wavpack', not wavpack_dep.found() ],
 149   ]
 150 endif
 151
 152 foo='''
 153 if HAVE_ORC
 154 check_orc = orc/deinterlace orc/videomixer orc/videobox
 155 else
 156 check_orc =
 157 endif
 158 '''
 159
 160 test_defines = [
 161   '-UG_DISABLE_ASSERT',
 162   '-UG_DISABLE_CAST_CHECKS',
 163   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_PLUGIN_LOADING_WHITELIST"',
 164   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 165   '-DGST_USE_UNSTABLE_API',
 166 ]
 167
 168 pluginsdirs = []
 169 if gst_dep.type_name() == 'pkgconfig'
 170   pbase = dependency('gstreamer-plugins-base-' + api_version, required: true)
 171   pluginsdirs = [gst_dep.get_variable('pluginsdir'),
 172                  pbase.get_variable('pluginsdir')]
 173   gst_plugin_scanner_dir = gst_dep.get_variable('pluginscannerdir')
 174 else
 175   gst_plugin_scanner_dir = subproject('gstreamer').get_variable('gst_scanner_dir')
 176 endif
 177 gst_plugin_scanner_path = join_paths(gst_plugin_scanner_dir, 'gst-plugin-scanner')
 178
 179 # fake device drivers: we could run hardware element tests against dummy drivers
 180 # v4l2: vivo (part of normal kernel)
 181 #   modprobe vivo;
 182 #   gst-launch v4l2src device="/dev/video1" ! xvimagesink;
 183 #   rmmod vivo
 184 #
 185 # alsa: snd-dummy (part of normal alsa, not removable)
 186 #   modprobe snd-dummy;
 187 #   gst-launch alsasrc device="hw:2" ! fakesink
 188 #   gst-launch fakesrc ! alsasink device="hw:2"
 189 #
 190 # need a way to figure out value for the device property
 191 state_ignore_elements = '''aasink autoaudiosrc autoaudiosink autovideosrc
 192  autovideosink cacasink cairotextoverlay gtkglsink gtksink jackaudiosrc
 193  jackaudiosink osssrc osssink osxaudiosink osxaudiosrc osxvideosrc osxvideosink
 194  pulsesink pulsesrc pulsemixer v4l2src'''
 195
 196 # FIXME: check, also + PTHREAD_CFLAGS
 197 test_deps = [gst_dep, gstbase_dep, gstnet_dep, gstcheck_dep, gstaudio_dep,
 198   gstvideo_dep, gstpbutils_dep, gstrtp_dep, gstrtsp_dep, gsttag_dep,
 199   gstapp_dep, gio_dep, valgrind_dep] + glib_deps
 200
 201 # FIXME: add valgrind suppression common/gst.supp gst-plugins-good.supp
 202 foreach t : good_tests
 203   fname = '@0@.c'.format(t.get(0))
 204   test_name = t.get(4, t.get(0)).underscorify()
 205   extra_sources = t.get(3, [ ])
 206   extra_deps = t.get(2, [ ])
 207   skip_test = t.get(1, false)
 208   if not skip_test
 209     env = environment()
 210     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 211     env.set('GST_STATE_IGNORE_ELEMENTS', state_ignore_elements)
 212     env.set('CK_DEFAULT_TIMEOUT', '20')
 213     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 214       'timecode', 'gst-plugins-good@' + meson.project_build_root())
 215     env.set('GST_PLUGIN_PATH_1_0', [meson.global_build_root()] + pluginsdirs)
 216     env.set('GSETTINGS_BACKEND', 'memory')
 217
 218     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 219     env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
 220     exe = executable(test_name, fname, extra_sources,
 221       include_directories : [configinc, libsinc],
 222       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 223       dependencies : [libm] + test_deps + extra_deps,
 224     )
 225     test(test_name, exe, env: env, timeout: 3 * 60)
 226   endif
 227 endforeach
 228
 229 # orc tests
 230 orc_tests = [
 231   ['orc_deinterlace', files('../../gst/deinterlace/tvtime.orc')],
 232   ['orc_videomixer', files('../../gst/videomixer/videomixerorc.orc')],
 233   ['orc_videobox', files('../../gst/videobox/gstvideoboxorc.orc')],
 234 ]
 235
 236 orc_test_dep = dependency('', required : false)
 237 if have_orcc
 238   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 239   if orc_dep.type_name() == 'pkgconfig'
 240     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 241   else
 242     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 243   endif
 244 endif
 245
 246 if have_orcc and orc_test_dep.found()
 247   foreach t : orc_tests
 248     tname = t[0]
 249     torcfile = t[1]
 250     tcfilename = '@0@.c'.format(tname)
 251     test_c = custom_target(tcfilename,
 252       output: tcfilename,
 253       input: torcfile,
 254       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 255     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 256     test(tname, test_exe)
 257   endforeach
 258 endif