subprojects/gst-plugins-good/tests/check/meson.build

   1 valgrind_dep = dependency('valgrind', required: false).partial_dependency(compile_args : true)
   2 if valgrind_dep.found()
   3   cdata.set('HAVE_VALGRIND', 1)
   4 endif
   5
   6 # internal helper lib for unit testing audio parsers
   7 libparser = static_library('libparser', 'elements/parser.c',
   8   c_args : gst_plugins_good_args + ['-DGST_USE_UNSTABLE_API'],
   9   include_directories : [configinc],
  10   dependencies : [gstcheck_dep],
  11   install : false)
  12
  13 libparser_dep = declare_dependency(link_with : libparser,
  14   dependencies : gstcheck_dep)
  15
  16 # name, condition when to skip the test and extra dependencies
  17 good_tests = [
  18   [ 'elements/audioamplify', false, [gstfft_dep] ],
  19   [ 'elements/audiochebband', false, [gstfft_dep] ],
  20   [ 'elements/audiocheblimit', false, [gstfft_dep] ],
  21   [ 'elements/audiodynamic', false, [gstfft_dep] ],
  22   [ 'elements/audioecho', false, [gstfft_dep] ],
  23   [ 'elements/audiofirfilter', false, [gstfft_dep] ],
  24   [ 'elements/audioiirfilter', false, [gstfft_dep] ],
  25   [ 'elements/audioinvert', false, [gstfft_dep] ],
  26   [ 'elements/audiopanorama', false, [gstfft_dep] ],
  27   [ 'elements/audiowsincband', false, [gstfft_dep] ],
  28   [ 'elements/audiowsinclimit', false, [gstfft_dep] ],
  29   [ 'elements/alphacolor' ],
  30   [ 'elements/alpha' ],
  31   [ 'elements/avimux', false, [gstriff_dep] ],
  32   [ 'elements/avisubtitle', false, [gstriff_dep] ],
  33   [ 'elements/capssetter' ],
  34   [ 'elements/aacparse', false, [libparser_dep] ],
  35   [ 'elements/ac3parse', false, [libparser_dep] ],
  36   [ 'elements/amrparse', false, [libparser_dep] ],
  37   [ 'elements/flacparse', false, [libparser_dep] ],
  38   [ 'elements/mpegaudioparse', false, [libparser_dep] ],
  39   [ 'elements/autodetect' ],
  40   [ 'elements/deinterlace' ],
  41   [ 'elements/dtmf' ],
  42   [ 'elements/flvdemux' ],
  43   [ 'elements/flvmux' ],
  44   [ 'elements/hlsdemux_m3u8' , not hls_dep.found() or not adaptivedemux2_dep.found(), [hls_dep, adaptivedemux2_dep] ],
  45   [ 'elements/mulawdec' ],
  46   [ 'elements/mulawenc' ],
  47   [ 'elements/icydemux' ],
  48   [ 'elements/id3demux' ],
  49   [ 'elements/imagefreeze' ],
  50   [ 'elements/deinterleave' ],
  51   [ 'elements/interleave' ],
  52   [ 'elements/level' ],
  53   [ 'elements/matroskademux', false, [gstriff_dep] ],
  54   [ 'elements/matroskamux', false, [gstriff_dep] ],
  55   [ 'elements/matroskaparse', false, [gstriff_dep] ],
  56   [ 'elements/multifile' ],
  57   [ 'elements/splitmuxsink', ],
  58   [ 'elements/splitmuxsinktimecode', ],
  59   [ 'elements/splitmuxsrc', ],
  60   [ 'elements/qtmux', false, [gstriff_dep, zlib_dep] ],
  61   [ 'elements/qtdemux', false, [gstriff_dep, zlib_dep] ],
  62   [ 'elements/rganalysis' ],
  63   [ 'elements/rglimiter' ],
  64   [ 'elements/rgvolume' ],
  65   [ 'elements/rtphdrext-colorspace' ],
  66   [ 'elements/rtph261' ],
  67   [ 'elements/rtph263' ],
  68   [ 'elements/rtph264' ],
  69   [ 'elements/rtph265' ],
  70   [ 'elements/rtpopus' ],
  71   [ 'elements/rtpvp8' ],
  72   [ 'elements/rtpvp9' ],
  73   [ 'elements/rtpbin' ],
  74   [ 'elements/rtpbin_buffer_list' ],
  75   [ 'elements/rtpcollision' ],
  76   [ 'elements/rtpfunnel' ],
  77   [ 'elements/rtphdrextclientaudiolevel', false, [gstsdp_dep, gstaudio_dep] ],
  78   [ 'elements/rtphdrextsdes', false, [gstrtp_dep, gstsdp_dep] ],
  79   [ 'elements/rtpjitterbuffer' ],
  80   [ 'elements/rtpjpeg' ],
  81
  82   [ 'elements/rtptimerqueue', false, [gstrtp_dep],
  83       ['../../gst/rtpmanager/rtptimerqueue.c']],
  84
  85   [ 'elements/rtpmux' ],
  86   [ 'elements/rtpptdemux' ],
  87   [ 'elements/rtprtx' ],
  88   [ 'elements/rtpsession' ],
  89   [ 'elements/rtpstorage', false, [],  ['../../gst/rtp/gstrtpstorage.c',
  90                                         '../../gst/rtp/gstrtpelement.c',
  91                                         '../../gst/rtp/gstrtputils.c',
  92                                         '../../gst/rtp/rtpstorage.c',
  93                                         '../../gst/rtp/rtpstoragestream.c']],
  94   [ 'elements/rtpred' ],
  95   [ 'elements/rtpulpfec' ],
  96   [ 'elements/rtpssrcdemux' ],
  97   [ 'elements/rtp-payloading' ],
  98   [ 'elements/rtpst2022-1-fecdec' ],
  99   [ 'elements/rtpst2022-1-fecenc' ],
 100   [ 'elements/spectrum', false, [gstfft_dep] ],
 101   [ 'elements/shapewipe' ],
 102   [ 'elements/udpsink' ],
 103   [ 'elements/udpsrc' ],
 104   [ 'elements/videobox' ],
 105   [ 'elements/videocrop' ],
 106   [ 'elements/videofilter' ],
 107   [ 'elements/videoflip' ],
 108   [ 'elements/videomixer' ],
 109   [ 'elements/aspectratiocrop' ],
 110   [ 'pipelines/wavenc' ],
 111   [ 'elements/wavparse', false, [gstriff_dep] ],
 112   [ 'elements/wavpackparse', ],
 113   [ 'elements/y4menc' ],
 114   [ 'pipelines/effectv' ],
 115   [ 'elements/equalizer' ],
 116   [ 'pipelines/simple-launch-lines' ],
 117   [ 'pipelines/tagschecking' ],
 118   [ 'generic/states' ],
 119 ]
 120
 121 # FIXME: valgrind elements/rtp-payloading - needs fixing
 122 # elements/videocrop should be disabled since it takes way too long in valgrind
 123
 124 libsoup2_dep = dependency('libsoup-2.4', version : '>=2.48',
 125                           required : false, fallback : ['libsoup', 'libsoup_dep'],
 126                           default_options: ['sysprof=disabled'])
 127 libsoup3_dep = dependency('libsoup-3.0', required : false,
 128                            fallback : ['libsoup3', 'libsoup_dep'])
 129
 130 # FIXME: unistd dependency or not tested yet on windows
 131 if host_machine.system() != 'windows'
 132   good_tests += [
 133     [ 'elements/dash_mpd', not adaptivedemux2_dep.found(), [adaptivedemux2_dep] ],
 134     [ 'pipelines/flacdec', not flac_dep.found() ],
 135     [ 'elements/gdkpixbufsink', not gdkpixbuf_dep.found(), [gdkpixbuf_dep] ],
 136     [ 'elements/gdkpixbufoverlay', not gdkpixbuf_dep.found() ],
 137     [ 'elements/jpegdec', not jpeglib.found() ],
 138     [ 'elements/jpegenc', not jpeglib.found() ],
 139     [ 'elements/mpg123audiodec', not mpg123_dep.found(), [gstfft_dep]],
 140     [ 'elements/souphttpsrc', not libsoup2_dep.found(), [libsoup2_dep], [], 'elements/souphttpsrc2'],
 141     [ 'elements/souphttpsrc', not libsoup3_dep.found(), [libsoup3_dep], [], 'elements/souphttpsrc3'],
 142     [ 'elements/id3v2mux', not taglib_dep.found() ],
 143     [ 'elements/apev2mux', not taglib_dep.found() ],
 144     [ 'elements/vp8enc', not vpx_dep.found() or not have_vp8_encoder ],
 145     [ 'elements/vp8dec', not vpx_dep.found() or not have_vp8_decoder ],
 146     [ 'elements/vp9enc', not vpx_dep.found() or not have_vp9_encoder ],
 147     [ 'pipelines/lame', not lame_dep.found() ],
 148     [ 'elements/wavpackdec', not wavpack_dep.found() ],
 149     [ 'elements/wavpackenc', not wavpack_dep.found() ],
 150     [ 'pipelines/wavpack', not wavpack_dep.found() ],
 151   ]
 152 endif
 153
 154 foo='''
 155 if HAVE_ORC
 156 check_orc = orc/deinterlace orc/videomixer orc/videobox
 157 else
 158 check_orc =
 159 endif
 160 '''
 161
 162 test_defines = [
 163   '-UG_DISABLE_ASSERT',
 164   '-UG_DISABLE_CAST_CHECKS',
 165   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_PLUGIN_LOADING_WHITELIST"',
 166   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 167   '-DGST_USE_UNSTABLE_API',
 168 ]
 169
 170 pluginsdirs = []
 171 if gst_dep.type_name() == 'pkgconfig'
 172   pbase = dependency('gstreamer-plugins-base-' + api_version, required: true)
 173   pluginsdirs = [gst_dep.get_variable('pluginsdir'),
 174                  pbase.get_variable('pluginsdir')]
 175   gst_plugin_scanner_dir = gst_dep.get_variable('pluginscannerdir')
 176 else
 177   gst_plugin_scanner_dir = subproject('gstreamer').get_variable('gst_scanner_dir')
 178 endif
 179 gst_plugin_scanner_path = join_paths(gst_plugin_scanner_dir, 'gst-plugin-scanner')
 180
 181 # fake device drivers: we could run hardware element tests against dummy drivers
 182 # v4l2: vivo (part of normal kernel)
 183 #   modprobe vivo;
 184 #   gst-launch v4l2src device="/dev/video1" ! xvimagesink;
 185 #   rmmod vivo
 186 #
 187 # alsa: snd-dummy (part of normal alsa, not removable)
 188 #   modprobe snd-dummy;
 189 #   gst-launch alsasrc device="hw:2" ! fakesink
 190 #   gst-launch fakesrc ! alsasink device="hw:2"
 191 #
 192 # need a way to figure out value for the device property
 193 state_ignore_elements = '''aasink autoaudiosrc autoaudiosink autovideosrc
 194  autovideosink cacasink cairotextoverlay gtkglsink gtksink jackaudiosrc
 195  jackaudiosink osssrc osssink osxaudiosink osxaudiosrc osxvideosrc osxvideosink
 196  pulsesink pulsesrc pulsemixer v4l2src'''
 197
 198 # FIXME: check, also + PTHREAD_CFLAGS
 199 test_deps = [gst_dep, gstbase_dep, gstnet_dep, gstcheck_dep, gstaudio_dep,
 200   gstvideo_dep, gstpbutils_dep, gstrtp_dep, gstrtsp_dep, gsttag_dep,
 201   gstapp_dep, gio_dep, valgrind_dep]
 202
 203 # FIXME: add valgrind suppression common/gst.supp gst-plugins-good.supp
 204 foreach t : good_tests
 205   fname = '@0@.c'.format(t.get(0))
 206   test_name = t.get(4, t.get(0)).underscorify()
 207   extra_sources = t.get(3, [ ])
 208   extra_deps = t.get(2, [ ])
 209   skip_test = t.get(1, false)
 210   if not skip_test
 211     env = environment()
 212     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 213     env.set('GST_STATE_IGNORE_ELEMENTS', state_ignore_elements)
 214     env.set('CK_DEFAULT_TIMEOUT', '20')
 215     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 216       'timecode', 'gst-plugins-good@' + meson.project_build_root())
 217     env.set('GST_PLUGIN_PATH_1_0', [meson.global_build_root()] + pluginsdirs)
 218     env.set('GSETTINGS_BACKEND', 'memory')
 219
 220     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 221     env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
 222     exe = executable(test_name, fname, extra_sources,
 223       include_directories : [configinc, libsinc],
 224       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 225       dependencies : [libm] + test_deps + extra_deps,
 226     )
 227     test(test_name, exe, env: env, timeout: 3 * 60)
 228   endif
 229 endforeach
 230
 231 # orc tests
 232 orc_tests = [
 233   ['orc_deinterlace', files('../../gst/deinterlace/tvtime.orc')],
 234   ['orc_videomixer', files('../../gst/videomixer/videomixerorc.orc')],
 235   ['orc_videobox', files('../../gst/videobox/gstvideoboxorc.orc')],
 236 ]
 237
 238 orc_test_dep = dependency('', required : false)
 239 if have_orcc
 240   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 241   if orc_dep.type_name() == 'pkgconfig'
 242     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 243   else
 244     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 245   endif
 246 endif
 247
 248 if have_orcc and orc_test_dep.found()
 249   foreach t : orc_tests
 250     tname = t[0]
 251     torcfile = t[1]
 252     tcfilename = '@0@.c'.format(tname)
 253     test_c = custom_target(tcfilename,
 254       output: tcfilename,
 255       input: torcfile,
 256       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 257     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 258     test(tname, test_exe)
 259   endforeach
 260 endif