subprojects/gst-plugins-base/tests/examples/overlay/meson.build

   1 if get_option('qt5').disabled()
   2   subdir_done()
   3 endif
   4
   5 if x11_dep.found()
   6   if gtk_x11_dep.found()
   7     executable('gtk-videooverlay', 'gtk-videooverlay.c',
   8       c_args : gst_plugins_base_args,
   9       include_directories: [configinc, libsinc],
  10       dependencies : [glib_deps, gst_dep, video_dep, libm, x11_dep, gtk_x11_dep],
  11       install: false)
  12   endif
  13
  14   if have_cxx                                      # check for C++ support
  15     qt5_mod = import('qt5')
  16     qt5widgets_dep = dependency('qt5', modules : ['Core', 'Gui', 'Widgets'],
  17                                 required: get_option('examples'))
  18
  19     if qt5widgets_dep.found() and qt5_mod.has_tools(required: get_option('examples'))
  20       executable('qt-videooverlay', 'qt-videooverlay.cpp',
  21         cpp_args : gst_plugins_base_args,
  22         include_directories: [configinc, libsinc],
  23         dependencies : [glib_deps, gst_dep, video_dep, libm, x11_dep, qt5widgets_dep],
  24         install: false)
  25
  26       # FIXME: this doesn't work properly yet, no moc_qtgv-videooverlay.cpp generated
  27       moc_files = qt5_mod.preprocess(moc_headers : 'qtgv-videooverlay.h')#moc_sources : 'qtgv-videooverlay.cpp')
  28       executable('qtgv-videooverlay', 'qtgv-videooverlay.cpp', moc_files,
  29         cpp_args : gst_plugins_base_args,
  30         include_directories: [configinc, libsinc],
  31         dependencies : [glib_deps, gst_dep, video_dep, libm, x11_dep, qt5widgets_dep],
  32         install: false)
  33     endif
  34   endif
  35 endif
  36
  37 if host_system == 'windows'
  38   executable('win32-videooverlay', 'win32-videooverlay.c',
  39     c_args : gst_plugins_base_args,
  40     include_directories : [configinc, libsinc],
  41     dependencies : [gst_dep, video_dep],
  42     install: false,
  43   )
  44
  45   executable('win32-videooverlay-playbin', 'win32-videooverlay-playbin.c',
  46     c_args : gst_plugins_base_args,
  47     include_directories : [configinc, libsinc],
  48     dependencies : [gst_dep, video_dep],
  49     install: false,
  50   )
  51 endif