subprojects/gst-plugins-base/sys/xvimage/meson.build

   1 xvimage_sources = [
   2   'xvcontext.c',
   3   'xvimage.c',
   4   'xvimageallocator.c',
   5   'xvimagepool.c',
   6   'xvimagesink.c',
   7 ]
   8
   9 no_warn_args = []
  10 # XKeycodeToKeysym is deprecated, but we use it when Xkb is unavailable
  11 if cc.has_argument ('-Wno-deprecated-declarations')
  12   no_warn_args += '-Wno-deprecated-declarations'
  13 endif
  14
  15 xvideo_dep = dependency('xv', required : get_option('xvideo'))
  16
  17 if xvideo_dep.found()
  18   gstxvimage = library('gstxvimagesink',
  19     xvimage_sources,
  20     c_args : gst_plugins_base_args + no_warn_args,
  21     include_directories: [configinc, libsinc],
  22     dependencies : glib_deps + [video_dep, gst_base_dep, gst_dep, x11_dep, xshm_dep, xvideo_dep, xi_dep, libm],
  23     install : true,
  24     install_dir : plugins_install_dir,
  25   )
  26   pkgconfig.generate(gstxvimage, install_dir : plugins_pkgconfig_install_dir)
  27   plugins += [gstxvimage]
  28 endif