subprojects/gst-plugins-base/gst-libs/gst/sdp/meson.build

   1 gst_sdp_headers = files([
   2   'sdp.h',
   3   'sdp-prelude.h',
   4   'gstsdp.h',
   5   'gstmikey.h',
   6   'gstsdpmessage.h',
   7 ])
   8 install_headers(gst_sdp_headers, subdir : 'gstreamer-1.0/gst/sdp/')
   9
  10 sdp_deps = [rtp_dep, gst_dep, gio_dep, pbutils_dep]
  11 gst_sdp_sources = files(['gstsdpmessage.c', 'gstmikey.c'])
  12 gstsdp = library('gstsdp-@0@'.format(api_version),
  13   gst_sdp_sources,
  14   c_args : gst_plugins_base_args + ['-DBUILDING_GST_SDP', '-DG_LOG_DOMAIN="GStreamer-SDP"'],
  15   include_directories: [configinc, libsinc],
  16   version : libversion,
  17   soversion : soversion,
  18   darwin_versions : osxversion,
  19   install : true,
  20   dependencies : sdp_deps,
  21 )
  22
  23 library_def = {'lib': gstsdp}
  24 pkg_name = 'gstreamer-sdp-1.0'
  25 sdp_gen_sources  = []
  26 pkgconfig.generate(gstsdp,
  27   libraries : [glib_deps],
  28   variables : pkgconfig_variables,
  29   subdirs : pkgconfig_subdirs,
  30   name : pkg_name,
  31   description : 'SDP helper functions',
  32 )
  33
  34 if build_gir
  35   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/sdp/sdp.h' ]
  36   gir = {
  37     'sources' : gst_sdp_sources + gst_sdp_headers,
  38     'namespace' : 'GstSdp',
  39     'nsversion' : api_version,
  40     'identifier_prefix' : 'Gst',
  41     'symbol_prefix' : 'gst',
  42     'export_packages' : pkg_name,
  43     'includes' : ['Gst-1.0'],
  44     'install' : true,
  45     'extra_args' : gst_gir_extra_args,
  46     'dependencies' : sdp_deps
  47   }
  48
  49   library_def = {'lib': library_def['lib'], 'gir': [gir]}
  50   if not static_build
  51     sdp_gir = gnome.generate_gir(gstsdp, kwargs: gir)
  52     sdp_gen_sources += [sdp_gir]
  53   endif
  54 endif
  55 libraries += [[pkg_name, library_def]]
  56
  57 sdp_dep = declare_dependency(link_with: gstsdp,
  58   include_directories : [libsinc],
  59   dependencies : sdp_deps,
  60   sources: sdp_gen_sources)
  61
  62 meson.override_dependency(pkg_name, sdp_dep)