subprojects/gst-plugins-base/gst/videotestsrc/meson.build

   1 videotestsrc_deps = glib_deps + [video_dep, gst_dep, gst_base_dep, libm]
   2 orcsrc = 'gstvideotestsrcorc'
   3 if have_orcc
   4   videotestsrc_deps += [orc_dep]
   5   orc_h = custom_target(orcsrc + '.h',
   6     input : orcsrc + '.orc',
   7     output : orcsrc + '.h',
   8     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
   9   orc_c = custom_target(orcsrc + '.c',
  10     input : orcsrc + '.orc',
  11     output : orcsrc + '.c',
  12     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  13   orc_targets += {'name': orcsrc, 'orc-source': files(orcsrc + '.orc'), 'header': orc_h, 'source': orc_c}
  14 else
  15   orc_h = configure_file(input : orcsrc + '-dist.h',
  16     output : orcsrc + '.h',
  17     copy : true)
  18   orc_c = configure_file(input : orcsrc + '-dist.c',
  19     output : orcsrc + '.c',
  20     copy : true)
  21 endif
  22
  23 gstvideotestsrc = library('gstvideotestsrc',
  24   'gstvideotestsrc.c', 'videotestsrc.c', orc_c, orc_h,
  25   c_args : gst_plugins_base_args,
  26   include_directories: [configinc, libsinc],
  27   dependencies : videotestsrc_deps,
  28   install : true,
  29   install_dir : plugins_install_dir,
  30 )
  31 pkgconfig.generate(gstvideotestsrc, install_dir : plugins_pkgconfig_install_dir)
  32 plugins += [gstvideotestsrc]