subprojects/gst-plugins-base/ext/cdparanoia/meson.build

   1 cdparanoia_deps = []
   2 cdparanoia_found = false
   3 cdparanoia_option = get_option('cdparanoia')
   4 if cdparanoia_option.disabled()
   5   subdir_done()
   6 endif
   7
   8 # cdparanoia upstream has a pkg-config file only in post-10.2 SVN so far, no release yet
   9 cdparanoia_dep = dependency('cdparanoia-3', version : '>=10.2', required : false)
  10 if cdparanoia_dep.found()
  11   cdparanoia_deps = [cdparanoia_dep]
  12   cdparanoia_found = true
  13 else
  14   cdparanoia_dep = cc.find_library('cdda_paranoia', required : cdparanoia_option)
  15   cdinterface_dep = cc.find_library('cdda_interface', required : cdparanoia_option)
  16   if cdparanoia_dep.found() and cdinterface_dep.found()
  17     cdparanoia_deps = [cdparanoia_dep, cdinterface_dep]
  18     cdparanoia_found = true
  19     if cc.has_header_symbol('cdda/cdda_interface.h', 'cdda_open')
  20       core_conf.set('CDPARANOIA_HEADERS_IN_DIR', true)
  21     elif cc.has_header_symbol('cdda_interface.h', 'cdda_open')
  22       core_conf.set('CDPARANOIA_HEADERS_IN_DIR', false)
  23     endif
  24   endif
  25 endif
  26
  27 if not cdparanoia_found and cdparanoia_option.enabled()
  28   error('cdparanoia plugin enabled but library not found')
  29 endif
  30
  31 if cdparanoia_found
  32   gstcdparanoia = library('gstcdparanoia',
  33     ['gstcdparanoiasrc.c'],
  34     include_directories: [configinc, libsinc],
  35     c_args : gst_plugins_base_args,
  36     dependencies : cdparanoia_deps + glib_deps + [audio_dep, gst_dep, gst_base_dep],
  37     install : true,
  38     install_dir : plugins_install_dir,
  39   )
  40   pkgconfig.generate(gstcdparanoia, install_dir : plugins_pkgconfig_install_dir)
  41   plugins += [gstcdparanoia]
  42 endif