subprojects/gst-plugins-bad/sys/dvb/meson.build

   1 dvb_sources = [
   2   'camapplication.c',
   3   'camapplicationinfo.c',
   4   'cam.c',
   5   'camconditionalaccess.c',
   6   'camdevice.c',
   7   'camresourcemanager.c',
   8   'camsession.c',
   9   'camswclient.c',
  10   'camtransport.c',
  11   'camutils.c',
  12   'dvbbasebin.c',
  13   'gstdvb.c',
  14   'gstdvbelement.c',
  15   'gstdvbsrc.c',
  16   'parsechannels.c',
  17 ]
  18
  19 if get_option('dvb').disabled()
  20   subdir_done()
  21 endif
  22
  23 dvb_check_code = '''
  24 #include <linux/dvb/version.h>
  25 #if DVB_API_VERSION < 5 || (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR <= 4)
  26 #error "Incompatible dvb API"
  27 #endif'
  28 '''
  29 have_dvb = cc.compiles(dvb_check_code)
  30 if not have_dvb and get_option('dvb').enabled()
  31   error('DVB plugin enabled but dvb headers not found')
  32 endif
  33
  34 if have_dvb
  35   gstdvb = library('gstdvb',
  36     dvb_sources,
  37     c_args : gst_plugins_bad_args + [ '-DGST_USE_UNSTABLE_API' ],
  38     include_directories : [configinc, libsinc],
  39     dependencies : [gstmpegts_dep, gstbase_dep],
  40     install : true,
  41     install_dir : plugins_install_dir,
  42   )
  43   pkgconfig.generate(gstdvb, install_dir : plugins_pkgconfig_install_dir)
  44   plugins += [gstdvb]
  45 endif