subprojects/gst-plugins-bad/sys/bluez/meson.build

   1 bluez_sources = [
   2   'bluez-plugin.c',
   3   'gstbluezelement.c',
   4   'gsta2dpsink.c',
   5   'gstavdtpsink.c',
   6   'gstavdtpsrc.c',
   7   'gstavdtputil.c',
   8   'gstavrcputil.c',
   9 ]
  10
  11 if host_system == 'windows'
  12   subdir_done()
  13 endif
  14
  15 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez'))
  16 gio_unix_dep = dependency('gio-unix-2.0', version : glib_req,
  17                           fallback: ['glib', 'libgiounix_dep'],
  18                           required : get_option('bluez'))
  19
  20 if bluez_dep.found() and gio_unix_dep.found()
  21   bluez_ch = gnome.gdbus_codegen('bluez',
  22       sources : 'org.bluez.xml',
  23       interface_prefix : 'org.bluez',
  24       namespace : 'Bluez')
  25
  26   gstbluez = library('gstbluez',
  27     bluez_sources, bluez_ch,
  28     c_args : gst_plugins_bad_args,
  29     include_directories : [configinc],
  30     dependencies : [gstaudio_dep, gstrtp_dep, gstbase_dep, gio_unix_dep, bluez_dep],
  31     install : true,
  32     install_dir : plugins_install_dir,
  33   )
  34   pkgconfig.generate(gstbluez, install_dir : plugins_pkgconfig_install_dir)
  35   plugins += [gstbluez]
  36 endif