subprojects/gst-plugins-bad/meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.20.0',
   3   meson_version : '>= 0.59',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 glib_req = '>= 2.56.0'
  21 orc_req = '>= 0.4.17'
  22
  23 if gst_version_is_stable
  24   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25 else
  26   gst_req = '>= ' + gst_version
  27 endif
  28
  29 api_version = '1.0'
  30 soversion = 0
  31 # maintaining compatibility with the previous libtool versioning
  32 # current = minor * 100 + micro
  33 curversion = gst_version_minor * 100 + gst_version_micro
  34 libversion = '@0@.@1@.0'.format(soversion, curversion)
  35 osxversion = curversion + 1
  36
  37 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  38 static_build = get_option('default_library') == 'static'
  39 plugins = []
  40 libraries = []
  41
  42 cc = meson.get_compiler('c')
  43 cxx = meson.get_compiler('cpp')
  44 host_system = host_machine.system()
  45
  46 if host_system in ['ios', 'darwin']
  47   have_objc = add_languages('objc', native: false)
  48   have_objcpp = add_languages('objcpp', native: false)
  49 else
  50   have_objc = false
  51   have_objcpp = false
  52 endif
  53
  54 cdata = configuration_data()
  55
  56 if cc.get_id() == 'msvc'
  57   msvc_args = [
  58       # Ignore several spurious warnings for things gstreamer does very commonly
  59       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  60       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  61       # NOTE: Only add warnings here if you are sure they're spurious
  62       '/wd4018', # implicit signed/unsigned conversion
  63       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  64       '/wd4244', # lossy type conversion (e.g. double -> int)
  65       '/wd4305', # truncating type conversion (e.g. double -> float)
  66       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  67
  68       # Enable some warnings on MSVC to match GCC/Clang behaviour
  69       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  70       '/w14101', # 'identifier' : unreferenced local variable
  71       '/w14189', # 'identifier' : local variable is initialized but not referenced
  72   ]
  73   add_project_arguments(msvc_args, language: ['c', 'cpp'])
  74   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  75   # are built with MinGW
  76   noseh_link_args = ['/SAFESEH:NO']
  77 else
  78   if cxx.has_argument('-Wno-non-virtual-dtor')
  79     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  80   endif
  81
  82   noseh_link_args = []
  83 endif
  84
  85 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  86   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  87 endif
  88
  89 # Symbol visibility
  90 if cc.get_id() == 'msvc'
  91   export_define = '__declspec(dllexport) extern'
  92 elif cc.has_argument('-fvisibility=hidden')
  93   add_project_arguments('-fvisibility=hidden', language: 'c')
  94   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  95   if have_objc
  96     add_project_arguments('-fvisibility=hidden', language: 'objc')
  97   endif
  98   export_define = 'extern __attribute__ ((visibility ("default")))'
  99 else
 100   export_define = 'extern'
 101 endif
 102
 103 # Passing this through the command line would be too messy
 104 cdata.set('GST_API_EXPORT', export_define)
 105
 106 # Disable strict aliasing
 107 if cc.has_argument('-fno-strict-aliasing')
 108   add_project_arguments('-fno-strict-aliasing', language: 'c')
 109 endif
 110 if cxx.has_argument('-fno-strict-aliasing')
 111   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
 112 endif
 113
 114 # Define G_DISABLE_DEPRECATED for development versions
 115 if gst_version_is_dev
 116   message('Disabling deprecated GLib API')
 117   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 118 endif
 119
 120 cast_checks = get_option('gobject-cast-checks')
 121 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 122   message('Disabling GLib cast checks')
 123   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 124 endif
 125
 126 glib_asserts = get_option('glib-asserts')
 127 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 128   message('Disabling GLib asserts')
 129   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 130 endif
 131
 132 glib_checks = get_option('glib-checks')
 133 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 134   message('Disabling GLib checks')
 135   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 136 endif
 137
 138 check_headers = [
 139   ['HAVE_DLFCN_H', 'dlfcn.h'],
 140   ['HAVE_FCNTL_H', 'fcntl.h'],
 141   ['HAVE_INTTYPES_H', 'inttypes.h'],
 142   ['HAVE_MEMORY_H', 'memory.h'],
 143   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 144   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 145   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 146   ['HAVE_PTHREAD_H', 'pthread.h'],
 147   ['HAVE_STDINT_H', 'stdint.h'],
 148   ['HAVE_STDLIB_H', 'stdlib.h'],
 149   ['HAVE_STRINGS_H', 'strings.h'],
 150   ['HAVE_STRING_H', 'string.h'],
 151   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 152   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 153   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 154   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 155   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 156   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 157   ['HAVE_UNISTD_H', 'unistd.h'],
 158   ['HAVE_WINDOWS_H', 'windows.h'],
 159   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 160   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 161 ]
 162
 163 foreach h : check_headers
 164   if cc.has_header(h.get(1))
 165     cdata.set(h.get(0), 1)
 166   endif
 167 endforeach
 168
 169 check_functions = [
 170   ['HAVE_DCGETTEXT', 'dcgettext'],
 171   ['HAVE_GETPAGESIZE', 'getpagesize'],
 172   ['HAVE_GMTIME_R', 'gmtime_r'],
 173   ['HAVE_MEMFD_CREATE', 'memfd_create'],
 174   ['HAVE_MMAP', 'mmap'],
 175   ['HAVE_PIPE2', 'pipe2'],
 176   ['HAVE_GETRUSAGE', 'getrusage', '#include<sys/resource.h>'],
 177 ]
 178
 179 foreach f : check_functions
 180   prefix = ''
 181   if f.length() == 3
 182     prefix = f.get(2)
 183   endif
 184   if cc.has_function(f.get(1), prefix: prefix)
 185     cdata.set(f.get(0), 1)
 186   endif
 187 endforeach
 188
 189 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 190 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 191 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 192 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 193 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 194
 195 cdata.set_quoted('VERSION', gst_version)
 196 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 197 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 198 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad/issues/new')
 199 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 200 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 201 cdata.set_quoted('GST_API_VERSION', api_version)
 202 cdata.set_quoted('GST_LICENSE', 'LGPL')
 203 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 204 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 205
 206 warning_flags = [
 207   '-Wmissing-declarations',
 208   '-Wredundant-decls',
 209   '-Wwrite-strings',
 210   '-Wformat',
 211   '-Wformat-security',
 212   '-Winit-self',
 213   '-Wmissing-include-dirs',
 214   '-Waddress',
 215   '-Wno-multichar',
 216   '-Wvla',
 217   '-Wpointer-arith',
 218 ]
 219
 220 warning_c_flags = [
 221   '-Wmissing-prototypes',
 222   '-Wdeclaration-after-statement',
 223   '-Wold-style-definition',
 224 ]
 225
 226 warning_cxx_flags = [
 227   '-Wformat-nonliteral',
 228 ]
 229
 230 foreach extra_arg : warning_c_flags
 231   if cc.has_argument (extra_arg)
 232     add_project_arguments([extra_arg], language: 'c')
 233   endif
 234 endforeach
 235
 236 foreach extra_arg : warning_cxx_flags
 237   if cxx.has_argument (extra_arg)
 238     add_project_arguments([extra_arg], language: 'cpp')
 239   endif
 240 endforeach
 241
 242 foreach extra_arg : warning_flags
 243   if cc.has_argument (extra_arg)
 244     add_project_arguments([extra_arg], language: 'c')
 245   endif
 246   if cxx.has_argument (extra_arg)
 247     add_project_arguments([extra_arg], language: 'cpp')
 248   endif
 249 endforeach
 250
 251 # GStreamer package name and origin url
 252 gst_package_name = get_option('package-name')
 253 if gst_package_name == ''
 254   if gst_version_nano == 0
 255     gst_package_name = 'GStreamer Bad Plug-ins source release'
 256   elif gst_version_nano == 1
 257     gst_package_name = 'GStreamer Bad Plug-ins git'
 258   else
 259     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 260   endif
 261 endif
 262 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 263 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 264
 265 # FIXME: This should be exposed as a configuration option
 266 if host_system == 'linux'
 267   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 268 elif ['darwin', 'ios'].contains(host_system)
 269   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 270   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 271   # Yes, we set this for iOS too. Same as Autotools.
 272   cdata.set('HAVE_OSX', 1)
 273 else
 274   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 275 endif
 276
 277 # Mandatory GST deps
 278 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 279   fallback : ['gstreamer', 'gst_dep'])
 280 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 281   fallback : ['gstreamer', 'gst_base_dep'])
 282 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 283   fallback : ['gstreamer', 'gst_net_dep'])
 284 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 285   fallback : ['gstreamer', 'gst_controller_dep'])
 286
 287 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 288     fallback : ['gst-plugins-base', 'pbutils_dep'])
 289 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 290     fallback : ['gst-plugins-base', 'allocators_dep'])
 291 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 292     fallback : ['gst-plugins-base', 'app_dep'])
 293 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 294     fallback : ['gst-plugins-base', 'audio_dep'])
 295 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 296     fallback : ['gst-plugins-base', 'fft_dep'])
 297 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 298     fallback : ['gst-plugins-base', 'riff_dep'])
 299 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 300     fallback : ['gst-plugins-base', 'rtp_dep'])
 301 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 302     fallback : ['gst-plugins-base', 'rtsp_dep'])
 303 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 304     fallback : ['gst-plugins-base', 'sdp_dep'])
 305 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 306     fallback : ['gst-plugins-base', 'tag_dep'])
 307 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 308     fallback : ['gst-plugins-base', 'video_dep'])
 309 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 310     required : get_option('tests'),
 311     fallback : ['gstreamer', 'gst_check_dep'])
 312
 313 # GStreamer OpenGL
 314 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 315     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 316 gstglproto_dep = dependency('gstreamer-gl-prototypes-1.0', version : gst_req,
 317     fallback : ['gst-plugins-base', 'gstglproto_dep'], required: get_option('gl'))
 318 gstglx11_dep = dependency('', required : false)
 319 gstglwayland_dep = dependency('', required : false)
 320 gstglegl_dep = dependency('', required : false)
 321
 322 if gstgl_dep.found()
 323   if gstgl_dep.type_name() == 'pkgconfig'
 324     gst_gl_apis = gstgl_dep.get_variable('gl_apis').split()
 325     gst_gl_winsys = gstgl_dep.get_variable('gl_winsys').split()
 326     gst_gl_platforms = gstgl_dep.get_variable('gl_platforms').split()
 327   else
 328     gstbase = subproject('gst-plugins-base')
 329     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 330     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 331     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 332   endif
 333
 334   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 335   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 336   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 337
 338   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 339     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 340   endforeach
 341
 342   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 343     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 344   endforeach
 345
 346   foreach api : ['gl', 'gles2']
 347     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 348   endforeach
 349
 350   # Behind specific checks because meson fails at optional dependencies with a
 351   # fallback to the same subproject.  On the first failure, meson will never
 352   # check the system again even if the fallback never existed.
 353   # Last checked with meson 0.54.3
 354   if gst_gl_have_window_x11
 355     gstglx11_dep = dependency('gstreamer-gl-x11-1.0', version : gst_req,
 356         fallback : ['gst-plugins-base', 'gstglx11_dep'], required: true)
 357   endif
 358   if gst_gl_have_window_wayland
 359     gstglwayland_dep = dependency('gstreamer-gl-wayland-1.0', version : gst_req,
 360         fallback : ['gst-plugins-base', 'gstglwayland_dep'], required: true)
 361   endif
 362   if gst_gl_have_platform_egl
 363     gstglegl_dep = dependency('gstreamer-gl-egl-1.0', version : gst_req,
 364         fallback : ['gst-plugins-base', 'gstglegl_dep'], required: true)
 365   endif
 366 endif
 367
 368 libm = cc.find_library('m', required : false)
 369 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 370 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 371 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 372 # gio-unix-2.0 is used by sys/bluez
 373
 374 # Optional dep of ext/gl and gst/librfb
 375 x11_dep = dependency('x11', required : get_option('x11'))
 376 if x11_dep.found()
 377   cdata.set('HAVE_X11', 1)
 378 endif
 379
 380 if host_machine.system() == 'windows'
 381   winsock2 = [cc.find_library('ws2_32')]
 382 else
 383   winsock2 = []
 384 endif
 385
 386 if ['darwin', 'ios'].contains(host_system)
 387   if not have_objc
 388     error('Building on MacOS/iOS/etc requires an ObjC compiler')
 389   endif
 390   if host_system == 'ios'
 391     cdata.set('HAVE_IOS', 1)
 392   endif
 393
 394   avfoundation_dep = dependency('AVFoundation', required : false)
 395   if avfoundation_dep.found()
 396       cdata.set('HAVE_AVFOUNDATION', 1)
 397   endif
 398
 399   videotoolbox_dep = dependency('VideoToolbox', required : false)
 400   if videotoolbox_dep.found()
 401       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 402   endif
 403
 404 #  FIXME: framework.version() returns 'unknown'
 405 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 406 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 407 #  endif
 408 endif
 409
 410 have_orcc = false
 411 orcc_args = []
 412 orc_targets = []
 413 # Used by various libraries/elements that use Orc code
 414 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 415     fallback : ['orc', 'orc_dep'])
 416 orcc = find_program('orcc', required : get_option('orc'))
 417 if orc_dep.found() and orcc.found()
 418   have_orcc = true
 419   orcc_args = [orcc, '--include', 'glib.h']
 420   cdata.set('HAVE_ORC', 1)
 421 else
 422   message('Orc Compiler not found or disabled, will use backup C code')
 423   cdata.set('DISABLE_ORC', 1)
 424 endif
 425 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 426
 427 gnustl_dep = declare_dependency()
 428 if host_system == 'android'
 429   gnustl_dep = dependency('gnustl', required : false)
 430 endif
 431
 432 # TIZEN BUILD OPTION
 433
 434 # TIZEN_FEATURE_XXX can be generally used for all of modules in this subproject
 435 cdata.set('TIZEN_FEATURE_FIX_MEMORY_LEAK', true)
 436
 437 # TIZEN_FEATURE_[MODULE]_XXX should be used for a particular module
 438 cdata.set('TIZEN_FEATURE_ADAPTIVE_MODIFICATION', true)
 439 cdata.set('TIZEN_FEATURE_HLSDEMUX_PROPERTY', true)
 440 cdata.set('TIZEN_FEATURE_HLSDEMUX_EMPTY_VTT', true)
 441 cdata.set('TIZEN_FEATURE_HLSDEMUX_UPDATE_SEGMENT', true)
 442 cdata.set('TIZEN_FEATURE_HLSDEMUX_DISCONT_SEQUENCE', true)
 443 cdata.set('TIZEN_FEATURE_TSDEMUX_MODIFICATION', true)
 444 cdata.set('TIZEN_FEATURE_TSDEMUX_INVALID_PCR_PID', true)
 445 cdata.set('TIZEN_FEATURE_TSDEMUX_LANG_TAG', true)
 446 cdata.set('TIZEN_FEATURE_TSDEMUX_UPDATE_PMT', true)
 447 cdata.set('TIZEN_FEATURE_TSDEMUX_UPDATE_STREAM', true)
 448 cdata.set('TIZEN_FEATURE_HLS_WEBVTT', true)
 449 cdata.set('TIZEN_FEATURE_OALSINK_MODIFICATION', true)
 450 cdata.set('TIZEN_FEATURE_MPEGDEMUX_MODIFICATION', true)
 451 cdata.set('TIZEN_FEATURE_H264PARSE_MODIFICATION', true)
 452 cdata.set('TIZEN_FEATURE_AD', true)
 453 cdata.set('TIZEN_FEATURE_HLSDEMUX_LANG_TAG', true)
 454 cdata.set('TIZEN_FEATURE_HLSDEMUX_DISCONT', true)
 455 cdata.set('TIZEN_FEATURE_WEBRTC_MODIFICATION', true)
 456 cdata.set('TIZEN_FEATURE_WEBRTC_IMPORT_NETSIM', true)
 457 cdata.set('TIZEN_FEATURE_PITCH_AUDIO_META', true)
 458
 459 # TIZEN BUILD OPTION end
 460
 461 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 462 if gst_dep.type_name() == 'internal'
 463   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 464 else
 465   # We can't check that in the case of subprojects as we won't
 466   # be able to build against an internal dependency (which is not built yet)
 467   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 468 endif
 469
 470 if gst_debug_disabled
 471   message('GStreamer debug system is disabled')
 472   if cc.has_argument('-Wno-unused')
 473     add_project_arguments('-Wno-unused', language: 'c')
 474   endif
 475   if cxx.has_argument ('-Wno-unused')
 476     add_project_arguments('-Wno-unused', language: 'cpp')
 477   endif
 478 else
 479   message('GStreamer debug system is enabled')
 480 endif
 481
 482 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 483 configinc = include_directories('.')
 484 libsinc = include_directories('gst-libs')
 485
 486 python3 = import('python').find_installation()
 487
 488 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 489 gnome = import('gnome')
 490 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 491 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 492     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 493     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 494     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 495     'gst_init(NULL,NULL);', '--quiet']
 496
 497 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 498
 499 pkgconfig = import('pkgconfig')
 500 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 501 if get_option('default_library') == 'shared'
 502   # If we don't build static plugins there is no need to generate pc files
 503   plugins_pkgconfig_install_dir = disabler()
 504 endif
 505
 506 pkgconfig_variables = ['exec_prefix=${prefix}',
 507     'toolsdir=${exec_prefix}/bin',
 508     'pluginsdir=${libdir}/gstreamer-1.0',
 509     'datarootdir=${prefix}/share',
 510     'datadir=${datarootdir}',
 511     'girdir=${datadir}/gir-1.0',
 512     'typelibdir=${libdir}/girepository-1.0']
 513
 514 pkgconfig_subdirs = ['gstreamer-1.0']
 515
 516 pkgconfig.generate(
 517   libraries : [gst_dep],
 518   variables : pkgconfig_variables,
 519   subdirs : pkgconfig_subdirs,
 520   name : 'gstreamer-plugins-bad-1.0',
 521   description : 'Streaming media framework, bad plugins libraries',
 522 )
 523
 524 gpl_allowed = get_option('gpl').allowed()
 525
 526 subdir('gst-libs')
 527 subdir('gst')
 528 subdir('sys')
 529 subdir('ext')
 530 subdir('tests')
 531 subdir('data')
 532 subdir('tools')
 533
 534 if have_orcc
 535   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 536
 537   orc_update_targets = []
 538   foreach t : orc_targets
 539     orc_name = t.get('name')
 540     orc_file = t.get('orc-source')
 541     header = t.get('header')
 542     source = t.get('source')
 543     # alias_target() only works with build targets, so can't use run_target() here
 544     orc_update_targets += [
 545       custom_target('update-orc-@0@'.format(orc_name),
 546         input: [header, source],
 547         command: [update_orc_dist_files, orc_file, header, source],
 548         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 549     ]
 550   endforeach
 551
 552   if orc_update_targets.length() > 0
 553     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 554   endif
 555 endif
 556
 557 # xgettext is optional (on Windows for instance)
 558 if find_program('xgettext', required : get_option('nls')).found()
 559   cdata.set('ENABLE_NLS', 1)
 560   subdir('po')
 561 endif
 562
 563 subdir('scripts')
 564
 565 # Set release date
 566 if gst_version_nano == 0
 567   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 568   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-bad.doap'), check: true)
 569   release_date = run_result.stdout().strip()
 570   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 571   message('Package release date: ' + release_date)
 572 endif
 573
 574 if glib_dep.version().version_compare('< 2.67.4')
 575   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 576 endif
 577
 578 configure_file(output : 'config.h', configuration : cdata)
 579
 580 subdir('docs')
 581
 582 plugin_names = []
 583 foreach plugin: plugins
 584   if plugin.name().startswith('gst')
 585     plugin_names += [plugin.name().substring(3)]
 586   else
 587     plugin_names += [plugin.name()]
 588   endif
 589 endforeach
 590
 591 summary({
 592     'Plugins': plugin_names,
 593       '(A)GPL license allowed': gpl_allowed,
 594 }, list_sep: ', ')