subprojects/gst-plugins-bad/gst-libs/gst/interfaces/meson.build

   1 photography_sources = ['photography.c']
   2 photo_headers = ['photography.h', 'photography-prelude.h']
   3 install_headers(photo_headers, subdir : 'gstreamer-1.0/gst/interfaces')
   4
   5 photo_enums = gnome.mkenums_simple('photography-enumtypes',
   6   sources : photo_headers,
   7   body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
   8   header_prefix : '#include <gst/interfaces/photography-prelude.h>',
   9   decorator: 'GST_PHOTOGRAPHY_API',
  10   install_header: true,
  11   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/interfaces'))
  12
  13 photoenum_c = photo_enums[0]
  14 photoenum_h = photo_enums[1]
  15
  16 gstphotography = library('gstphotography-' + api_version,
  17   photography_sources, photoenum_h, photoenum_c,
  18   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_PHOTOGRAPHY'],
  19   include_directories : [configinc, libsinc],
  20   version : libversion,
  21   soversion : soversion,
  22   darwin_versions : osxversion,
  23   install : true,
  24   dependencies : [gst_dep],
  25 )
  26
  27 pkgconfig.generate(gstphotography,
  28   libraries : [gst_dep, gstbase_dep],
  29   variables : pkgconfig_variables,
  30   subdirs : pkgconfig_subdirs,
  31   name : 'gstreamer-photography-1.0',
  32   description : 'High level API for transcoding using GStreamer',
  33 )
  34
  35 gstphotography_dep = declare_dependency(link_with : gstphotography,
  36   include_directories : [libsinc],
  37   dependencies : [gst_dep],
  38   sources : [photoenum_h])
  39
  40 meson.override_dependency('gstreamer-photography-1.0', gstphotography_dep)