subprojects/gst-plugins-bad/ext/vulkan/meson.build

   1 if get_option('vulkan').disabled()
   2   subdir_done()
   3 endif
   4
   5 if not gstvulkan_dep.found()
   6   if get_option('vulkan').enabled()
   7     error('GStreamer Vulkan plugin required via options, but needed dependencies not found.')
   8   else
   9     subdir_done()
  10   endif
  11 endif
  12
  13 # Should already have checked for this
  14 assert(glslc.found(), 'Expected glslc to be available')
  15
  16 subdir('shaders')
  17
  18 vulkan_sources = [
  19   'gstvulkan.c',
  20   'gstvulkanelement.c',
  21   'vkcolorconvert.c',
  22   'vkdownload.c',
  23   'vkdeviceprovider.c',
  24   'vkimageidentity.c',
  25   'vkshaderspv.c',
  26   'vksink.c',
  27   'vkupload.c',
  28   'vkviewconvert.c',
  29 ]
  30
  31 vulkan_plugin_enum_headers = [
  32   'vkviewconvert.h',
  33 ]
  34
  35 vulkan_plugin_enums = gnome.mkenums_simple('gstvulkan-plugins-enumtypes',
  36     sources : vulkan_plugin_enum_headers,
  37     body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
  38     header_prefix : '#include <gst/gst.h>')
  39 vulkan_plugin_enumtypes_c = vulkan_plugin_enums[0]
  40 vulkan_plugin_enumtypes_h = vulkan_plugin_enums[1]
  41 vulkan_plugin_gen_sources = [vulkan_plugin_enumtypes_h]
  42
  43 gstvulkan_plugin = library('gstvulkan',
  44   vulkan_sources, vulkan_compiled_shader_sources, vulkan_plugin_enumtypes_c, vulkan_plugin_enumtypes_h,
  45   c_args : gst_plugins_bad_args,
  46   objc_args : gst_plugins_bad_args,
  47   link_args : noseh_link_args,
  48   include_directories : [configinc],
  49   dependencies : [gio_dep, gstvideo_dep, gstbase_dep, gstvulkan_dep, vulkan_dep],
  50   install : true,
  51   install_dir : plugins_install_dir,
  52 )
  53 pkgconfig.generate(gstvulkan_plugin, install_dir : plugins_pkgconfig_install_dir)
  54 plugins += [gstvulkan_plugin]