subprojects/gst-editing-services/tools/meson.build

   1 deps = [ges_dep, gstpbutils_dep, gio_dep, gstvideo_dep, gstaudio_dep]
   2
   3 ges_tool_args = [ges_c_args, '-UG_LOG_DOMAIN']
   4 if gstvalidate_dep.found()
   5   deps = deps + [gstvalidate_dep]
   6   ges_tool_args += ['-DGST_USE_UNSTABLE_API']
   7 endif
   8
   9 ges_launch = executable('ges-launch-@0@'.format(apiversion),
  10     'ges-validate.c', 'ges-launch.c', 'ges-launcher.c', 'utils.c', 'ges-launcher-kb.c',
  11     c_args : [ges_tool_args] + ['-DG_LOG_DOMAIN="ges-launch-@0@"'.format(apiversion)],
  12     pie : true,
  13     dependencies : deps,
  14     install: true
  15 )
  16
  17 #install_man('ges-launch-1.0.1')
  18
  19 # bash completion
  20 bashcomp_option = get_option('bash-completion')
  21 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
  22 bash_completions_dir = ''
  23 bash_helpers_dir = ''
  24
  25 bashcomp_found = false
  26 if bashcomp_dep.found()
  27   bashcomp_found = true
  28   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
  29   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
  30   if bash_completions_dir == ''
  31     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
  32     if bashcomp_option.enabled()
  33       error(msg)
  34     else
  35       message(msg)
  36     endif
  37     bashcomp_found = false
  38   endif
  39
  40   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
  41   if bash_helpers_dir == ''
  42     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
  43     if bashcomp_option.enabled()
  44       error(msg)
  45     else
  46       message(msg)
  47     endif
  48     bashcomp_found = false
  49   endif
  50
  51   if bashcomp_found
  52     install_data('../data/completions/ges-launch-1.0', install_dir : bash_completions_dir)
  53   endif
  54 endif