src/util/meson.build

   1 # Copyright © 2017 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21 inc_util = include_directories('.')
  22
  23 subdir('format')
  24
  25 files_mesa_util = files(
  26   'anon_file.h',
  27   'anon_file.c',
  28   'bigmath.h',
  29   'bitscan.c',
  30   'bitscan.h',
  31   'bitset.h',
  32   'blob.c',
  33   'blob.h',
  34   'build_id.c',
  35   'build_id.h',
  36   'cnd_monotonic.h',
  37   'compiler.h',
  38   'compress.c',
  39   'compress.h',
  40   'crc32.c',
  41   'crc32.h',
  42   'dag.c',
  43   'disk_cache.c',
  44   'disk_cache.h',
  45   'disk_cache_os.c',
  46   'disk_cache_os.h',
  47   'double.c',
  48   'double.h',
  49   'enum_operators.h',
  50   'fast_idiv_by_const.c',
  51   'fast_idiv_by_const.h',
  52   'format_r11g11b10f.h',
  53   'format_rgb9e5.h',
  54   'format_srgb.h',
  55   'fossilize_db.c',
  56   'fossilize_db.h',
  57   'futex.c',
  58   'futex.h',
  59   'half_float.c',
  60   'half_float.h',
  61   'hash_table.c',
  62   'hash_table.h',
  63   'u_idalloc.c',
  64   'u_idalloc.h',
  65   'list.h',
  66   'log.c',
  67   'macros.h',
  68   'memstream.c',
  69   'memstream.h',
  70   'mesa-sha1.c',
  71   'mesa-sha1.h',
  72   'os_time.c',
  73   'os_time.h',
  74   'os_file.c',
  75   'os_memory_fd.c',
  76   'os_misc.c',
  77   'os_misc.h',
  78   'os_socket.c',
  79   'os_socket.h',
  80   'ptralloc.h',
  81   'perf/u_trace.h',
  82   'perf/u_trace.c',
  83   'perf/u_trace_priv.h',
  84   'u_process.c',
  85   'u_process.h',
  86   'u_qsort.cpp',
  87   'u_qsort.h',
  88   'rwlock.c',
  89   'rwlock.h',
  90   'sha1/sha1.c',
  91   'sha1/sha1.h',
  92   'ralloc.c',
  93   'ralloc.h',
  94   'rand_xor.c',
  95   'rand_xor.h',
  96   'rb_tree.c',
  97   'rb_tree.h',
  98   'register_allocate.c',
  99   'register_allocate.h',
 100   'rgtc.c',
 101   'rgtc.h',
 102   'rounding.h',
 103   'set.c',
 104   'set.h',
 105   'simple_mtx.c',
 106   'simple_mtx.h',
 107   'slab.c',
 108   'slab.h',
 109   'softfloat.c',
 110   'softfloat.h',
 111   'sparse_array.c',
 112   'sparse_array.h',
 113   'string_buffer.c',
 114   'string_buffer.h',
 115   'strndup.h',
 116   'strtod.c',
 117   'strtod.h',
 118   'texcompress_rgtc_tmp.h',
 119   'timespec.h',
 120   'u_atomic.c',
 121   'u_atomic.h',
 122   'u_call_once.c',
 123   'u_call_once.h',
 124   'u_debug_describe.c',
 125   'u_debug_describe.h',
 126   'u_debug_refcnt.c',
 127   'u_debug_refcnt.h',
 128   'u_dl.c',
 129   'u_dl.h',
 130   'u_dynarray.h',
 131   'u_endian.h',
 132   'u_fifo.h',
 133   'u_hash_table.c',
 134   'u_hash_table.h',
 135   'u_pointer.h',
 136   'u_queue.c',
 137   'u_queue.h',
 138   'u_string.h',
 139   'u_thread.c',
 140   'u_thread.h',
 141   'u_vector.c',
 142   'u_vector.h',
 143   'u_math.c',
 144   'u_math.h',
 145   'u_memset.h',
 146   'u_mm.c',
 147   'u_mm.h',
 148   'u_debug.c',
 149   'u_debug.h',
 150   'u_debug_memory.c',
 151   'u_cpu_detect.c',
 152   'u_cpu_detect.h',
 153   'u_printf.c',
 154   'u_printf.h',
 155   'u_worklist.c',
 156   'u_worklist.h',
 157   'vl_vlc.h',
 158   'vl_rbsp.h',
 159   'vma.c',
 160   'vma.h',
 161   'xxhash.h',
 162   'mesa_cache_db.c',
 163   'mesa_cache_db.h',
 164 )
 165
 166 files_drirc = files('00-mesa-defaults.conf')
 167
 168 install_data(files_drirc, install_dir : join_paths(get_option('datadir'), 'drirc.d'))
 169
 170 if with_tests
 171   prog_xmllint = find_program('xmllint', required : false, native : true)
 172   if prog_xmllint.found()
 173     test(
 174       'drirc xml validation',
 175       prog_xmllint,
 176       args : ['--noout', '--valid', files_drirc],
 177       suite : ['util'],
 178     )
 179   endif
 180 endif
 181
 182 files_xmlconfig = files(
 183   'xmlconfig.c',
 184   'xmlconfig.h',
 185 )
 186
 187 files_xmlconfig += custom_target(
 188   'driconf_static.h',
 189   input: ['driconf_static.py', '00-mesa-defaults.conf'],
 190   output: 'driconf_static.h',
 191   command: [
 192     prog_python, '@INPUT0@', '@INPUT1@', '@OUTPUT@'
 193   ],
 194 )
 195
 196 format_srgb = custom_target(
 197   'format_srgb',
 198   input : ['format_srgb.py'],
 199   output : 'format_srgb.c',
 200   command : [prog_python, '@INPUT0@'],
 201   capture : true,
 202 )
 203
 204 deps_for_libmesa_util = [
 205   dep_zlib,
 206   dep_clock,
 207   dep_thread,
 208   dep_atomic,
 209   dep_m,
 210   dep_valgrind,
 211   dep_zstd,
 212   dep_dl,
 213   dep_unwind,
 214   dep_futex,
 215   idep_mesautilc11
 216 ]
 217
 218 if with_platform_android
 219   deps_for_libmesa_util += dep_android
 220   files_debug_stack = files('u_debug_stack_android.cpp')
 221  else
 222   files_debug_stack = files(
 223     'u_debug_stack.c',
 224     'u_debug_symbol.c',
 225     'u_debug_symbol.h',
 226   )
 227 endif
 228
 229 if with_platform_haiku
 230   deps_for_libmesa_util += dep_network
 231 endif
 232
 233 if with_perfetto
 234   files_mesa_util += files(
 235     'perf/u_perfetto.cc',
 236     'perf/u_perfetto.h',
 237   )
 238   deps_for_libmesa_util += dep_perfetto
 239 endif
 240
 241 u_trace_py = files('perf/u_trace.py')
 242
 243 libmesa_util_sse41 = static_library(
 244                 'mesa_util_sse41',
 245                 files('streaming-load-memcpy.c'),
 246                 c_args : [c_msvc_compat_args, sse41_args],
 247                 include_directories : [inc_include, inc_src, inc_mesa],
 248                 gnu_symbol_visibility : 'hidden',
 249 )
 250
 251 _libmesa_util = static_library(
 252   'mesa_util',
 253   [files_mesa_util, files_debug_stack, format_srgb],
 254   include_directories : [inc_include, inc_src, inc_mapi, inc_mesa, inc_gallium, inc_gallium_aux],
 255   dependencies : deps_for_libmesa_util,
 256   link_with: [libmesa_format, libmesa_util_sse41],
 257   c_args : [c_msvc_compat_args],
 258   gnu_symbol_visibility : 'hidden',
 259   build_by_default : false
 260 )
 261
 262 idep_mesautil = declare_dependency(
 263   link_with : _libmesa_util,
 264   include_directories : [inc_util, inc_gallium],
 265   dependencies : [dep_zlib, dep_clock, dep_thread, dep_atomic, dep_m, dep_valgrind, dep_futex],
 266 )
 267
 268 xmlconfig_deps = []
 269 if not (with_platform_android or with_platform_windows)
 270   xmlconfig_deps += dep_expat
 271 endif
 272 xmlconfig_deps += dep_regex
 273
 274 _libxmlconfig = static_library(
 275   'xmlconfig',
 276   files_xmlconfig,
 277   include_directories : [inc_include, inc_src, inc_mapi, inc_mesa, inc_gallium, inc_gallium_aux],
 278   dependencies : [idep_mesautil, dep_m, xmlconfig_deps],
 279   c_args : [
 280     c_msvc_compat_args,
 281     '-DSYSCONFDIR="@0@"'.format(
 282       join_paths(get_option('prefix'), get_option('sysconfdir'))
 283     ),
 284     '-DDATADIR="@0@"'.format(
 285       join_paths(get_option('prefix'), get_option('datadir'))
 286     ),
 287   ],
 288   gnu_symbol_visibility : 'hidden',
 289   build_by_default : false,
 290 )
 291
 292 idep_xmlconfig = declare_dependency(
 293   dependencies : xmlconfig_deps,
 294   link_with : _libxmlconfig,
 295 )
 296
 297 files_xxd = files('xxd.py')
 298 glsl2spirv = files('glsl2spirv.py')
 299
 300 if with_tests
 301   # DRI_CONF macros use designated initializers (required for union
 302   # initializaiton), so we need c++2a since gtest forces us to use c++
 303   if host_machine.system() != 'windows' and cpp.has_argument('-std=c++2a')
 304     test('xmlconfig',
 305       executable('xmlconfig_test',
 306         files('tests/xmlconfig.cpp'),
 307         include_directories : [inc_include, inc_src],
 308         dependencies : [idep_mesautil, idep_xmlconfig, idep_gtest],
 309         override_options : ['cpp_std=c++2a'],
 310         cpp_args: ['-Wno-write-strings']
 311       ),
 312       suite : ['util'],
 313       env: ['HOME=' + join_paths(meson.current_source_dir(),
 314                                  'tests', 'drirc_home'),
 315             'DRIRC_CONFIGDIR=' + join_paths(meson.current_source_dir(),
 316                                             'tests', 'drirc_configdir')],
 317       protocol : gtest_test_protocol,
 318     )
 319   endif
 320
 321   files_util_tests = files(
 322     'tests/bitset_test.cpp',
 323     'tests/blob_test.cpp',
 324     'tests/dag_test.cpp',
 325     'tests/fast_idiv_by_const_test.cpp',
 326     'tests/fast_urem_by_const_test.cpp',
 327     'tests/half_float_test.cpp',
 328     'tests/int_min_max.cpp',
 329     'tests/mesa-sha1_test.cpp',
 330     'tests/rb_tree_test.cpp',
 331     'tests/register_allocate_test.cpp',
 332     'tests/roundeven_test.cpp',
 333     'tests/set_test.cpp',
 334     'tests/string_buffer_test.cpp',
 335     'tests/timespec_test.cpp',
 336     'tests/u_atomic_test.cpp',
 337     'tests/u_call_once_test.cpp',
 338     'tests/u_debug_stack_test.cpp',
 339     'tests/u_debug_test.cpp',
 340     'tests/u_printf_test.cpp',
 341     'tests/u_qsort_test.cpp',
 342     'tests/vector_test.cpp',
 343   )
 344
 345   # FIXME: this test cause a big timeout on MacOS
 346   if host_machine.system() != 'darwin'
 347     files_util_tests += files(
 348       'tests/sparse_array_test.cpp',
 349     )
 350   endif
 351
 352   if with_shader_cache
 353     files_util_tests += files(
 354       'tests/cache_test.cpp',
 355     )
 356   endif
 357
 358   test(
 359     'util_tests',
 360     executable(
 361       'util_tests',
 362       files_util_tests,
 363       include_directories : [inc_include, inc_src, inc_mapi, inc_mesa, inc_gallium, inc_gallium_aux],
 364       dependencies : [idep_mesautil, idep_gtest],
 365     ),
 366     suite : ['util'],
 367     protocol : gtest_test_protocol,
 368     timeout : 180,
 369   )
 370
 371   process_test_exe = executable(
 372     'process_test',
 373     files('tests/process_test.c'),
 374     include_directories : [inc_include, inc_src, inc_mapi, inc_mesa, inc_gallium, inc_gallium_aux],
 375     dependencies : idep_mesautil,
 376     c_args : [c_msvc_compat_args],
 377   )
 378   if (host_machine.system() == 'windows' and build_machine.system() != 'windows')
 379     # This conversion is only required on mingw crosscompilers, otherwise we hit at least one of these issues
 380     # https://gitlab.freedesktop.org/mesa/mesa/-/issues/2690
 381     # https://gitlab.freedesktop.org/mesa/mesa/-/issues/2788
 382     prog_winepath = find_program('winepath')
 383     process_test_exe_full_path = run_command(
 384       prog_winepath, '-w', process_test_exe.full_path(),
 385       check : true
 386     ).stdout().strip()
 387   else
 388     process_test_exe_full_path = process_test_exe.full_path()
 389   endif
 390
 391   test(
 392     'process',
 393     process_test_exe,
 394     suite : ['util'],
 395     env: ['BUILD_FULL_PATH='+process_test_exe_full_path]
 396   )
 397
 398   subdir('tests/hash_table')
 399   subdir('tests/vma')
 400   subdir('tests/format')
 401 endif