src/shaders/vme/intra_frame.asm

   1 /*
   2  * Copyright © <2010>, Intel Corporation.
   3  *
   4  * This program is licensed under the terms and conditions of the
   5  * Eclipse Public License (EPL), version 1.0.  The full text of the EPL is at
   6  * http://www.opensource.org/licenses/eclipse-1.0.php.
   7  *
   8  */
   9 // Modual name: IntraFrame.asm
  10 //
  11 // Make intra predition estimation for Intra frame
  12 //
  13
  14 //
  15 //  Now, begin source code....
  16 //
  17
  18 /*
  19  * __START
  20  */
  21 __INTRA_START:
  22 mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  23 mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  24 mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  25
  26 shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  27 add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  28 add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  29 mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  30 mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  31
  32 shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  33 add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  34 mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  35 mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  36
  37 shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  38 mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  39
  40 mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  41 add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  42 mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  43
  44 /*
  45  * Media Read Message -- fetch neighbor edge pixels
  46  */
  47 /* ROW */
  48 __INTRA_LOOP:
  49 mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};
  50 send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  51
  52 /* COL */
  53 mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};
  54 send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  55
  56 /*
  57  * VME message
  58  */
  59 /* m0 */
  60 mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  61
  62 /* m1 */
  63 mov  (1) intra_flag<1>:UW       0x0:UW {align1}                     ;
  64 cmp.nz.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  65 (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE + LUMA_INTRA_4x4_DISABLE {align1};
  66
  67 cmp.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB 0:UW {align1};                                                   /* X != 0 */
  68 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_AE {align1};         /* A */
  69
  70 cmp.nz.f0.0 (1) null<1>:UW orig_y_ub<0,1,0>:UB 0:UW {align1};                                                   /* Y != 0 */
  71 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_B {align1};          /* B */
  72
  73 mul.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB orig_y_ub<0,1,0>:UB {align1};                                    /* X * Y != 0 */
  74 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_D {align1};          /* D */
  75
  76 add  (1) tmp_x_w<1>:W orig_x_ub<0,1,0>:UB 1:UW {align1};                                                        /* X + 1 */
  77 add  (1) tmp_x_w<1>:W w_in_mb_uw<0,1,0>:UW -tmp_x_w<0,1,0>:W {align1};                                          /* width - (X + 1) */
  78 mul.nz.f0.0 (1) null<1>:UD tmp_x_w<0,1,0>:W orig_y_ub<0,1,0>:UB {align1};                                       /* (width - (X + 1)) * Y != 0 */
  79 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_C {align1};          /* C */
  80
  81 mov  (8) vme_msg_1<1>:UD        vme_m1.0<8,8,1>:UD {align1};
  82
  83 /* m2 */
  84 mov (8) vme_msg_2<1>:UD         0x0:UD {align1};
  85
  86 /* m3 */
  87 mov  (8) vme_msg_3<1>:UD         INEP_ROW.0<8,8,1>:UD {align1};
  88
  89 /* m4 */
  90 mov  (8) vme_msg_4<1>:UD         0x0 {align1};
  91 mov (16) vme_msg_4.0<1>:UB       INEP_COL0.3<32,8,4>:UB {align1};
  92 mov  (1) vme_msg_4.16<1>:UD      INTRA_PREDICTORE_MODE {align1};
  93
  94 send (8)
  95         vme_msg_ind
  96         vme_wb
  97         null
  98         vme(
  99                 BIND_IDX_VME,
 100                 0,
 101                 0,
 102                 VME_MESSAGE_TYPE_INTRA
 103         )
 104         mlen vme_msg_length
 105         rlen vme_intra_wb_length
 106         {align1};
 107
 108 /*
 109  * Oword Block Write message
 110  */
 111 mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
 112
 113 mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
 114 mov  (1) msg_reg1.4<1>:UD       vme_wb.16<0,1,0>:UD     {align1};
 115 mov  (1) msg_reg1.8<1>:UD       vme_wb.20<0,1,0>:UD     {align1};
 116 mov  (1) msg_reg1.12<1>:UD      vme_wb.24<0,1,0>:UD     {align1};
 117 /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
 118 send (16)
 119         msg_ind
 120         obw_wb
 121         null
 122         data_port(
 123                 OBW_CACHE_TYPE,
 124                 OBW_MESSAGE_TYPE,
 125                 OBW_CONTROL_0,
 126                 OBW_BIND_IDX,
 127                 OBW_WRITE_COMMIT_CATEGORY,
 128                 OBW_HEADER_PRESENT
 129         )
 130         mlen 2
 131         rlen obw_wb_length
 132         {align1};
 133
 134 add     (1)     read0_header.0<1>:D     read0_header.0<0,1,0>:D         16:W {align1};     /* X offset: X += 16 */
 135 add     (1)     read1_header.0<1>:D     read1_header.0<0,1,0>:D         16:W {align1};     /* X offset: X += 16 */
 136 add     (1)     vme_m0.8<1>:UW          vme_m0.8<0,1,0>:UW              16:UW {align1};    /* Y = Y, X += 16 */
 137
 138 add     (1)     orig_x_ub<1>:ub         orig_x_ub<0,1,0>:ub             1:uw {align1} ;
 139 cmp.e.f0.0      (1)     null<1>:uw      w_in_mb_uw<0,1,0>:uw            orig_x_ub<0,1,0>:ub {align1};
 140 (f0.0)mov       (1)     orig_x_ub<1>:ub 0:uw {align1} ;
 141 (f0.0)add       (1)     orig_y_ub<1>:ub orig_y_ub<0,1,0>:ub             1:uw {align1} ;
 142 (f0.0)mov       (1)     read0_header.0<1>:D     -8:W {align1};     /* X offset */
 143 (f0.0)add       (1)     read0_header.4<1>:D     read0_header.4<0,1,0>:D 16:W {align1};     /* Y offset */
 144 (f0.0)mov       (1)     read1_header.0<1>:D     -4:W {align1};     /* X offset */
 145 (f0.0)add       (1)     read1_header.4<1>:D     read1_header.4<0,1,0>:D 16:W {align1};     /* Y offset */
 146 /* X = 0, Y += 16 */
 147 (f0.0)mov       (1)     vme_m0.8<1>:UW          0:UW {align1};
 148 (f0.0)add       (1)     vme_m0.10<1>:UW         vme_m0.10<0,1,0>:UW 16:UW {align1};
 149
 150 add             (1)     obw_m0.8<1>:UD          obw_m0.8<0,1,0>:UD          1:uw {align1};     /* the new offset */
 151
 152 add.z.f0.0      (1)     num_macroblocks<1>:w    num_macroblocks<0,1,0>:w        -1:w {align1} ;
 153 (-f0.0)jmpi     (1)     __INTRA_LOOP ;
 154
 155 __EXIT:
 156 /*
 157  * kill thread
 158  */
 159 mov  (8) msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
 160 send (16) msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};