src/shaders/render/exa_wm_yuv_rgb.g8a

   1 /*
   2  * Copyright © 2013 Intel Corporation
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a
   5  * copy of this software and associated documentation files (the "Software"),
   6  * to deal in the Software without restriction, including without limitation
   7  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   8  * and/or sell copies of the Software, and to permit persons to whom the
   9  * Software is furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice (including the next
  12  * paragraph) shall be included in all copies or substantial portions of the
  13  * Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  18  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  21  * IN THE SOFTWARE.
  22  *
  23  * Authors:
  24  *    Keith Packard <keithp@keithp.com>
  25  *    Eric Anholt <eric@anholt.net>
  26  *    Zhao Yakui <yakui.zhao@intel.com>
  27  *
  28  */
  29
  30 include(`exa_wm.g4i')
  31
  32 define(`YCbCr_base',    `src_sample_base')
  33
  34 define(`Cr',            `src_sample_b')
  35 define(`Cr_01',         `src_sample_b_01')
  36 define(`Cr_23',         `src_sample_b_23')
  37
  38 define(`Y',             `src_sample_r')
  39 define(`Y_01',          `src_sample_r_01')
  40 define(`Y_23',          `src_sample_r_23')
  41
  42 define(`Cb',            `src_sample_g')
  43 define(`Cb_01',         `src_sample_g_01')
  44 define(`Cb_23',         `src_sample_g_23')
  45
  46 define(`Crn',           `mask_sample_g')
  47 define(`Crn_01',        `mask_sample_g_01')
  48 define(`Crn_23',        `mask_sample_g_23')
  49
  50 define(`Yn',            `mask_sample_r')
  51 define(`Yn_01',         `mask_sample_r_01')
  52 define(`Yn_23',         `mask_sample_r_23')
  53
  54 define(`Cbn',           `mask_sample_b')
  55 define(`Cbn_01',        `mask_sample_b_01')
  56 define(`Cbn_23',        `mask_sample_b_23')
  57
  58     /* color space conversion function:
  59      * R = Clamp ( 1.164(Y-16/255) + 1.596(Cr-128/255), 0, 1)
  60      * G = Clamp ( 1.164(Y-16/255) - 0.813(Cr-128/255) - 0.392(Cb-128/255), 0, 1)
  61      * B = Clamp ( 1.164(Y-16/255) + 2.017(Cb-128/255), 0, 1)
  62      */
  63
  64     /* Normalize Y, Cb and Cr:
  65      *
  66      * Yn = (Y - 16/255) * 1.164
  67      * Crn = Cr - 128 / 255
  68      * Cbn = Cb - 128 / 255
  69      */
  70 add (16)    Yn<1>F              Y<8;8,1>F       -0.0627451F { compr align1 };
  71 mul (16)    Yn<1>F              Yn<8;8,1>F      1.164F      { compr align1 };
  72
  73 add (16)    Crn<1>F             Cr<8;8,1>F      -0.501961F  { compr align1 };
  74
  75 add (16)    Cbn<1>F             Cb<8;8,1>F      -0.501961F  { compr align1 };
  76
  77     /*
  78      * R = Y + Cr * 1.596
  79      */
  80 mov (8)    acc0<1>F             Yn_01.0<8;8,1>F             { align1 };
  81 mac.sat(8) src_sample_r_01<1>F  Crn_01<8;8,1>F  1.596F      { align1 };
  82 mov (8)    acc0<1>F             Yn_23.0<8;8,1>F             { align1 };
  83 mac.sat(8) src_sample_r_23<1>F  Crn_23<8;8,1>F  1.596F      { align1 };
  84
  85     /*
  86      * G = Crn * -0.813 + Cbn * -0.392 + Y
  87      */
  88 mov (8)    acc0<1>F             Yn_01.0<8;8,1>F             { align1 };
  89 mac (8)    acc0<1>F             Crn_01.0<8;8,1>F        -0.813F     { align1 };
  90 mac.sat(8) src_sample_g_01<1>F  Cbn_01.0<8;8,1>F        -0.392F     { align1 };
  91 mov (8)    acc0<1>F             Yn_23.0<8;8,1>F             { align1 };
  92 mac (8)    acc0<1>F             Crn_23.0<8;8,1>F        -0.813F     { align1 };
  93 mac.sat(8) src_sample_g_23<1>F  Cbn_23.0<8;8,1>F        -0.392F     { align1 };
  94
  95     /*
  96      * B = Cbn * 2.017 + Y
  97      */
  98 mov (8)    acc0<1>F             Yn_01.0<8;8,1>F             { align1 };
  99 mac.sat(8) src_sample_b_01<1>F  Cbn_01.0<8;8,1>F     2.017F         { align1 };
 100
 101 mov (8)    acc0<1>F             Yn_23.0<8;8,1>F             { align1 };
 102 mac.sat(8) src_sample_b_23<1>F  Cbn_23.0<8;8,1>F     2.017F         { align1 };
 103     /*
 104      * A = 1.0
 105      */
 106 mov (16)    src_sample_a<1>F    1.0F        { compr align1 };