src/plugins/platforms/qnx/qnx.pro

   1 TARGET = qnx
   2 include(../../qpluginbase.pri)
   3
   4 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/platforms
   5 QT += opengl opengl-private platformsupport platformsupport-private widgets-private
   6
   7 # Uncomment this to build with support for IMF once it becomes available in the BBNDK
   8 #CONFIG += qqnx_imf
   9
  10 # Uncomment these to enable debugging output for various aspects of the plugin
  11 #DEFINES += QQNXBUFFER_DEBUG
  12 #DEFINES += QQNXCLIPBOARD_DEBUG
  13 #DEFINES += QQNXEVENTTHREAD_DEBUG
  14 #DEFINES += QQNXGLBACKINGSTORE_DEBUG
  15 #DEFINES += QQNXGLCONTEXT_DEBUG
  16 #DEFINES += QQNXINPUTCONTEXT_DEBUG
  17 #DEFINES += QQNXINPUTCONTEXT_IMF_EVENT_DEBUG
  18 #DEFINES += QQNXINTEGRATION_DEBUG
  19 #DEFINES += QQNXNAVIGATOREVENTHANDLER_DEBUG
  20 #DEFINES += QQNXNAVIGATOREVENTNOTIFIER_DEBUG
  21 #DEFINES += QQNXRASTERBACKINGSTORE_DEBUG
  22 #DEFINES += QQNXROOTWINDOW_DEBUG
  23 #DEFINES += QQNXSCREEN_DEBUG
  24 #DEFINES += QQNXSCREENEVENT_DEBUG
  25 #DEFINES += QQNXVIRTUALKEYBOARD_DEBUG
  26 #DEFINES += QQNXWINDOW_DEBUG
  27
  28 SOURCES =   main.cpp \
  29             qqnxbuffer.cpp \
  30             qqnxeventthread.cpp \
  31             qqnxglcontext.cpp \
  32             qqnxglbackingstore.cpp \
  33             qqnxintegration.cpp \
  34             qqnxnavigatoreventhandler.cpp \
  35             qqnxnavigatoreventnotifier.cpp \
  36             qqnxscreen.cpp \
  37             qqnxwindow.cpp \
  38             qqnxrasterbackingstore.cpp \
  39             qqnxvirtualkeyboard.cpp \
  40             qqnxclipboard.cpp \
  41             qqnxrootwindow.cpp \
  42             qqnxscreeneventhandler.cpp \
  43             qqnxabstractvirtualkeyboard.cpp \
  44             qqnxnativeinterface.cpp
  45
  46 HEADERS =   main.h \
  47             qqnxbuffer.h \
  48             qqnxeventthread.h \
  49             qqnxkeytranslator.h \
  50             qqnxintegration.h \
  51             qqnxnavigatoreventhandler.h \
  52             qqnxnavigatoreventnotifier.h \
  53             qqnxglcontext.h \
  54             qqnxglbackingstore.h \
  55             qqnxscreen.h \
  56             qqnxwindow.h \
  57             qqnxrasterbackingstore.h \
  58             qqnxvirtualkeyboard.h \
  59             qqnxclipboard.h \
  60             qqnxrootwindow.h \
  61             qqnxscreeneventhandler.h \
  62             qqnxabstractvirtualkeyboard.h \
  63             qqnxnativeinterface.h
  64
  65 CONFIG(blackberry) {
  66     SOURCES += qqnxservices.cpp
  67     HEADERS += qqnxservices.h
  68 }
  69
  70 CONFIG(qqnx_imf) {
  71     DEFINES += QQNX_IMF
  72     HEADERS += qqnxinputcontext_imf.h
  73     SOURCES += qqnxinputcontext_imf.cpp
  74 } else {
  75     HEADERS += qqnxinputcontext_noimf.h
  76     SOURCES += qqnxinputcontext_noimf.cpp
  77 }
  78
  79 OTHER_FILES += qnx.json
  80
  81 QMAKE_CXXFLAGS += -I./private
  82
  83 LIBS += -lpps -lscreen -lEGL -lclipboard
  84
  85 CONFIG(blackberry) {
  86     LIBS += -lbps
  87 }
  88
  89 include (../../../platformsupport/eglconvenience/eglconvenience.pri)
  90 include (../../../platformsupport/fontdatabases/fontdatabases.pri)
  91
  92 target.path += $$[QT_INSTALL_PLUGINS]/platforms
  93 INSTALLS += target