src/plugins/platforms/cocoa/qcocoawindow.mm

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the plugins of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 #include "qcocoawindow.h"
  42 #include "qnswindowdelegate.h"
  43 #include "qcocoaautoreleasepool.h"
  44 #include "qcocoaglcontext.h"
  45 #include "qcocoahelpers.h"
  46 #include "qnsview.h"
  47 #include <QtCore/private/qcore_mac_p.h>
  48 #include <qwindow.h>
  49 #include <QWindowSystemInterface>
  50 #include <QPlatformScreen>
  51
  52 #include <Cocoa/Cocoa.h>
  53 #include <Carbon/Carbon.h>
  54
  55 #include <QDebug>
  56
  57 QCocoaWindow::QCocoaWindow(QWindow *tlw)
  58     : QPlatformWindow(tlw)
  59     , m_windowAttributes(0)
  60     , m_windowClass(0)
  61     , m_glContext(0)
  62 {
  63     QCocoaAutoReleasePool pool;
  64
  65     determineWindowClass();
  66     m_nsWindow = createWindow();
  67
  68     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
  69     [m_nsWindow setDelegate:delegate];
  70     [m_nsWindow setAcceptsMouseMovedEvents:YES];
  71
  72     // Prevent Cocoa from releasing the window on close. Qt
  73     // handles the close event asynchronously and we want to
  74     // make sure that m_nsWindow stays valid until the
  75     // QCocoaWindow is deleted by Qt.
  76     [m_nsWindow setReleasedWhenClosed : NO];
  77
  78     m_contentView = [[QNSView alloc] initWithQWindow:tlw];
  79
  80     // ### Accept touch events by default.
  81     // Beware that enabling touch events has a negative impact on the overall performance.
  82     // We probably need a QWindowSystemInterface API to enable/disable touch events.
  83     [m_contentView setAcceptsTouchEvents:YES];
  84
  85     setGeometry(tlw->geometry());
  86
  87     [m_nsWindow setContentView:m_contentView];
  88 }
  89
  90 QCocoaWindow::~QCocoaWindow()
  91 {
  92     [m_nsWindow release];
  93 }
  94
  95 void QCocoaWindow::setGeometry(const QRect &rect)
  96 {
  97     QPlatformWindow::setGeometry(rect);
  98
  99     NSRect bounds = globalGeometry(rect);
 100     [[m_nsWindow contentView]setFrameSize:bounds.size];
 101     [m_nsWindow setContentSize : bounds.size];
 102     [m_nsWindow setFrameOrigin : bounds.origin];
 103
 104     if (m_glContext)
 105         m_glContext->update();
 106 }
 107
 108 void QCocoaWindow::setVisible(bool visible)
 109 {
 110     if (visible) {
 111         // The parent window might have moved while this window was hidden,
 112         // update the window geometry if there is a parent.
 113         if (window()->transientParent())
 114             setGeometry(window()->geometry());
 115
 116         // Make sure the QWindow has a frame ready before we show the NSWindow.
 117         QWindowSystemInterface::handleSynchronousExposeEvent(window(), QRect(QPoint(), geometry().size()));
 118
 119         [m_nsWindow makeKeyAndOrderFront:nil];
 120     } else {
 121         [m_nsWindow orderOut:nil];
 122     }
 123 }
 124
 125 void QCocoaWindow::setWindowTitle(const QString &title)
 126 {
 127     CFStringRef windowTitle = QCFString::toCFStringRef(title);
 128     [m_nsWindow setTitle: const_cast<NSString *>(reinterpret_cast<const NSString *>(windowTitle))];
 129     CFRelease(windowTitle);
 130 }
 131
 132 void QCocoaWindow::raise()
 133 {
 134     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
 135     [m_nsWindow orderFront: m_nsWindow];
 136 }
 137
 138 void QCocoaWindow::lower()
 139 {
 140     [m_nsWindow orderFront: m_nsWindow];
 141 }
 142
 143 WId QCocoaWindow::winId() const
 144 {
 145     return WId(m_nsWindow);
 146 }
 147
 148 NSView *QCocoaWindow::contentView() const
 149 {
 150     return [m_nsWindow contentView];
 151 }
 152
 153 void QCocoaWindow::windowDidMove()
 154 {
 155     if (m_glContext)
 156         m_glContext->update();
 157
 158     NSRect rect = [[m_nsWindow contentView]frame];
 159     NSRect windowRect = [m_nsWindow frame];
 160
 161     QRect geo(windowRect.origin.x, qt_mac_flipYCoordinate(windowRect.origin.y + rect.size.height), rect.size.width, rect.size.height);
 162     setGeometry(geo);
 163     QWindowSystemInterface::handleSynchronousGeometryChange(window(), geo);
 164 }
 165
 166 void QCocoaWindow::windowDidResize()
 167 {
 168     if (m_glContext)
 169         m_glContext->update();
 170
 171     NSRect rect = [[m_nsWindow contentView]frame];
 172     NSRect windowRect = [m_nsWindow frame];
 173
 174     QRect geo(windowRect.origin.x, qt_mac_flipYCoordinate(windowRect.origin.y + rect.size.height), rect.size.width, rect.size.height);
 175     setGeometry(geo);
 176     QWindowSystemInterface::handleSynchronousGeometryChange(window(), geo);
 177 }
 178
 179
 180 void QCocoaWindow::windowWillClose()
 181 {
 182     QWindowSystemInterface::handleCloseEvent(window());
 183 }
 184
 185 void QCocoaWindow::setCurrentContext(QCocoaGLContext *context)
 186 {
 187     m_glContext = context;
 188 }
 189
 190 QCocoaGLContext *QCocoaWindow::currentContext() const
 191 {
 192     return m_glContext;
 193 }
 194
 195 /*
 196     Determine the window class based on the window type and
 197     window flags, and widget attr Sets m_windowAttributes
 198     and m_windowClass.
 199 */
 200 void QCocoaWindow::determineWindowClass()
 201 {
 202     Qt::WindowType type = window()->windowType();
 203     Qt::WindowFlags flags = window()->windowFlags();
 204
 205     const bool popup = (type == Qt::Popup);
 206
 207     if (type == Qt::ToolTip || type == Qt::SplashScreen || popup)
 208         flags |= Qt::FramelessWindowHint;
 209
 210     m_windowClass = kSheetWindowClass;
 211
 212     if (popup || type == Qt::SplashScreen)
 213         m_windowClass = kModalWindowClass;
 214     else if (type == Qt::ToolTip)
 215         m_windowClass = kHelpWindowClass;
 216     else if (type == Qt::Tool)
 217         m_windowClass = kFloatingWindowClass;
 218     else
 219         m_windowClass = kDocumentWindowClass;
 220
 221     m_windowAttributes = (kWindowCompositingAttribute | kWindowStandardHandlerAttribute);
 222
 223 //    if(qt_mac_is_macsheet(window())) {
 224 //        m_windowClass = kSheetWindowClass;
 225 //    } else
 226
 227     {
 228         // Shift things around a bit to get the correct window class based on the presence
 229         // (or lack) of the border.
 230
 231         bool customize = flags & Qt::CustomizeWindowHint;
 232         bool framelessWindow = (flags & Qt::FramelessWindowHint || (customize && !(flags & Qt::WindowTitleHint)));
 233         if (framelessWindow) {
 234             if (m_windowClass == kDocumentWindowClass) {
 235                 m_windowAttributes |= kWindowNoTitleBarAttribute;
 236             } else if (m_windowClass == kFloatingWindowClass) {
 237                 m_windowAttributes |= kWindowNoTitleBarAttribute;
 238             } else if (m_windowClass  == kMovableModalWindowClass) {
 239                 m_windowClass = kModalWindowClass;
 240             }
 241         } else {
 242             m_windowAttributes |= NSTitledWindowMask;
 243             if (m_windowClass != kModalWindowClass)
 244                 m_windowAttributes |= NSResizableWindowMask;
 245         }
 246
 247         // Only add extra decorations (well, buttons) for widgets that can have them
 248         // and have an actual border we can put them on.
 249
 250         if(m_windowClass != kModalWindowClass && m_windowClass != kMovableModalWindowClass
 251                 && m_windowClass != kSheetWindowClass && m_windowClass != kPlainWindowClass
 252                 && !framelessWindow && m_windowClass != kDrawerWindowClass
 253                 && m_windowClass != kHelpWindowClass) {
 254             if (flags & Qt::WindowMinimizeButtonHint)
 255                 m_windowAttributes |= NSMiniaturizableWindowMask;
 256             if (flags & Qt::WindowSystemMenuHint || flags & Qt::WindowCloseButtonHint)
 257                 m_windowAttributes |= NSClosableWindowMask;
 258         } else {
 259             // Clear these hints so that we aren't call them on invalid windows
 260             flags &= ~(Qt::WindowMaximizeButtonHint | Qt::WindowMinimizeButtonHint
 261                        | Qt::WindowCloseButtonHint | Qt::WindowSystemMenuHint);
 262         }
 263
 264     }
 265
 266     if((popup || type == Qt::Tool) && !window()->isModal())
 267         m_windowAttributes |= kWindowHideOnSuspendAttribute;
 268     m_windowAttributes |= kWindowLiveResizeAttribute;
 269 }
 270
 271 /*
 272
 273 */
 274 NSWindow * QCocoaWindow::createWindow()
 275 {
 276     // Determine if we need to add in our "custom window" attribute. Cocoa is rather clever
 277     // in deciding if we need the maximize button or not (i.e., it's resizable, so you
 278     // must need a maximize button). So, the only buttons we have control over are the
 279     // close and minimize buttons. If someone wants to customize and NOT have the maximize
 280     // button, then we have to do our hack. We only do it for these cases because otherwise
 281     // the window looks different when activated. This "QtMacCustomizeWindow" attribute is
 282     // intruding on a public space and WILL BREAK in the future.
 283     // One can hope that there is a more public API available by that time.
 284 /*
 285     Qt::WindowFlags flags = widget ? widget->windowFlags() : Qt::WindowFlags(0);
 286     if ((flags & Qt::CustomizeWindowHint)) {
 287         if ((flags & (Qt::WindowCloseButtonHint | Qt::WindowSystemMenuHint
 288                       | Qt::WindowMinimizeButtonHint | Qt::WindowTitleHint))
 289             && !(flags & Qt::WindowMaximizeButtonHint))
 290             wattr |= QtMacCustomizeWindow;
 291     }
 292 */
 293     NSRect frame = globalGeometry(window()->geometry());
 294     QCocoaAutoReleasePool pool;
 295     NSWindow *window;
 296
 297     switch (m_windowClass) {
 298     case kMovableModalWindowClass:
 299     case kModalWindowClass:
 300     case kSheetWindowClass:
 301     case kFloatingWindowClass:
 302     case kOverlayWindowClass:
 303     case kHelpWindowClass: {
 304         NSPanel *panel;
 305
 306         BOOL needFloating = NO;
 307         //BOOL worksWhenModal = (this->window()->windowType() == Qt::Popup);
 308
 309         // Add in the extra flags if necessary.
 310         switch (m_windowClass) {
 311         case kSheetWindowClass:
 312             m_windowAttributes |= NSDocModalWindowMask;
 313             break;
 314         case kFloatingWindowClass:
 315         case kHelpWindowClass:
 316             needFloating = YES;
 317             m_windowAttributes |= NSUtilityWindowMask;
 318             break;
 319         default:
 320             break;
 321         }
 322
 323         panel = [[NSPanel alloc] initWithContentRect:frame
 324                                    styleMask:m_windowAttributes
 325                                    backing:NSBackingStoreBuffered
 326                                    defer:NO]; // see window case below
 327 //  ### crashes
 328 //        [panel setFloatingPanel:needFloating];
 329 //        [panel setWorksWhenModal:worksWhenModal];
 330         window = static_cast<NSWindow *>(panel);
 331         break;
 332     }
 333     default:
 334         window  = [[NSWindow alloc] initWithContentRect:frame
 335                                             styleMask:(NSResizableWindowMask | NSClosableWindowMask | NSMiniaturizableWindowMask | NSTitledWindowMask)
 336                                             backing:NSBackingStoreBuffered
 337                                             defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 338                                                        // before the window is shown and needs a proper window.).
 339         break;
 340     }
 341
 342     //qt_syncCocoaTitleBarButtons(window, widget);
 343     return window;
 344 }
 345
 346 // Calculate the global screen geometry for the given local geometry, which
 347 // might be in the parent window coordinate system.
 348 NSRect QCocoaWindow::globalGeometry(const QRect localGeometry) const
 349 {
 350     QRect finalGeometry = localGeometry;
 351
 352     if (QCocoaWindow *parent = parentCocoaWindow()) {
 353         QRect parentGeometry = parent->windowGeometry();
 354         finalGeometry.adjust(parentGeometry.x(), parentGeometry.y(), parentGeometry.x(), parentGeometry.y());
 355
 356         // Qt child window geometry assumes that the origin is at the
 357         // top-left of the content area of the parent window. The title
 358         // bar is not a part of this content area, but is still included
 359         // in the NSWindow height. Move the child window down to account
 360         // for this if the parent window has a title bar.
 361         const int titlebarHeight = 22;
 362         if (!(window()->windowFlags() & Qt::FramelessWindowHint))
 363             finalGeometry.adjust(0, titlebarHeight, 0, titlebarHeight);
 364     }
 365
 366     // The final "y invert" to get OS X global geometry:
 367     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
 368     int flippedY = onScreen->geometry().height() - finalGeometry.y() - finalGeometry.height();
 369     return NSMakeRect(finalGeometry.x(), flippedY, finalGeometry.width(), finalGeometry.height());
 370 }
 371
 372 // Returns the current global screen geometry for the nswindow associated with this window.
 373 QRect QCocoaWindow::windowGeometry() const
 374 {
 375     NSRect rect = [m_nsWindow frame];
 376     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
 377     int flippedY = onScreen->geometry().height() - rect.origin.y - rect.size.height;  // account for nswindow inverted y.
 378     QRect qRect = QRect(rect.origin.x, flippedY, rect.size.width, rect.size.height);
 379     return qRect;
 380 }
 381
 382 // Returns a pointer to the parent QCocoaWindow for this window, or 0 if there is none.
 383 QCocoaWindow *QCocoaWindow::parentCocoaWindow() const
 384 {
 385     if (window() && window()->transientParent()) {
 386         return static_cast<QCocoaWindow*>(window()->transientParent()->handle());
 387     }
 388     return 0;
 389 }
 390