src/plugins/platforms/cocoa/qcocoawindow.mm

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the plugins of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 #include "qcocoawindow.h"
  42 #include "qnswindowdelegate.h"
  43 #include "qcocoaautoreleasepool.h"
  44 #include "qcocoaglcontext.h"
  45 #include "qcocoahelpers.h"
  46 #include "qnsview.h"
  47 #include <QtCore/private/qcore_mac_p.h>
  48 #include <qwindow.h>
  49 #include <QWindowSystemInterface>
  50 #include <QPlatformScreen>
  51
  52 #include <Cocoa/Cocoa.h>
  53 #include <Carbon/Carbon.h>
  54
  55 #include <QDebug>
  56
  57 @implementation QNSWindow
  58
  59 - (BOOL)canBecomeKeyWindow
  60 {
  61     // The default implementation returns NO for title-bar less windows,
  62     // override and return yes here to make sure popup windows such as
  63     // the combobox popup can become the key window.
  64     return YES;
  65 }
  66
  67 - (BOOL)canBecomeMainWindow
  68 {
  69     BOOL canBecomeMain = YES; // By default, windows can become the main window
  70
  71     // Windows with a transient parent (such as combobox popup windows)
  72     // cannot become the main window:
  73     if (m_cocoaPlatformWindow->window()->transientParent())
  74         canBecomeMain = NO;
  75
  76     return canBecomeMain;
  77 }
  78
  79
  80 @end
  81
  82 @implementation QNSPanel
  83
  84 - (BOOL)canBecomeKeyWindow
  85 {
  86     // Most panels can be come the key window. Exceptions are:
  87     if (m_cocoaPlatformWindow->window()->windowType() == Qt::ToolTip)
  88         return NO;
  89     if (m_cocoaPlatformWindow->window()->windowType() == Qt::SplashScreen)
  90         return NO;
  91     return YES;
  92 }
  93
  94 @end
  95
  96 QCocoaWindow::QCocoaWindow(QWindow *tlw)
  97     : QPlatformWindow(tlw)
  98     , m_nsWindow(0)
  99     , m_glContext(0)
 100     , m_inConstructor(true)
 101 {
 102     QCocoaAutoReleasePool pool;
 103
 104     m_contentView = [[QNSView alloc] initWithQWindow:tlw platformWindow:this];
 105     setGeometry(tlw->geometry());
 106
 107     recreateWindow(parent());
 108
 109     m_inConstructor = false;
 110 }
 111
 112 QCocoaWindow::~QCocoaWindow()
 113 {
 114     clearNSWindow(m_nsWindow);
 115     [m_contentView release];
 116     [m_nsWindow release];
 117 }
 118
 119 void QCocoaWindow::setGeometry(const QRect &rect)
 120 {
 121     if (geometry() == rect)
 122         return;
 123 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 124     qDebug() << "QCocoaWindow::setGeometry" << this << rect;
 125 #endif
 126     QPlatformWindow::setGeometry(rect);
 127     setCocoaGeometry(rect);
 128 }
 129
 130 void QCocoaWindow::setCocoaGeometry(const QRect &rect)
 131 {
 132     if (m_nsWindow) {
 133         NSRect bounds = qt_mac_flipRect(rect, window());
 134         [m_nsWindow setContentSize : bounds.size];
 135         [m_nsWindow setFrameOrigin : bounds.origin];
 136     } else {
 137         [m_contentView setFrame : NSMakeRect(rect.x(), rect.y(), rect.width(), rect.height())];
 138     }
 139 }
 140
 141 void QCocoaWindow::setVisible(bool visible)
 142 {
 143     QCocoaAutoReleasePool pool;
 144 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 145     qDebug() << "QCocoaWindow::setVisible" << window() << visible;
 146 #endif
 147     if (visible) {
 148         if (window()->transientParent()) {
 149             // The parent window might have moved while this window was hidden,
 150             // update the window geometry if there is a parent.
 151             setGeometry(window()->geometry());
 152
 153             // Register popup windows so that the parent window can
 154             // close them when needed.
 155             if (window()->windowType() == Qt::Popup) {
 156                 // qDebug() << "transientParent and popup" << window()->windowType() << Qt::Popup << (window()->windowType() & Qt::Popup);
 157
 158                 QCocoaWindow *parentCocoaWindow = static_cast<QCocoaWindow *>(window()->transientParent()->handle());
 159                 parentCocoaWindow->m_activePopupWindow = window();
 160             }
 161
 162         }
 163
 164         // Make sure the QWindow has a frame ready before we show the NSWindow.
 165         QWindowSystemInterface::handleSynchronousExposeEvent(window(), QRect(QPoint(), geometry().size()));
 166
 167         if (m_nsWindow) {
 168             if ([m_nsWindow canBecomeKeyWindow])
 169                 [m_nsWindow makeKeyAndOrderFront:nil];
 170             else
 171                 [m_nsWindow orderFront: nil];
 172         }
 173     } else {
 174         // qDebug() << "close" << this;
 175         if (m_nsWindow)
 176             [m_nsWindow orderOut:m_nsWindow];
 177     }
 178 }
 179
 180 Qt::WindowFlags QCocoaWindow::setWindowFlags(Qt::WindowFlags flags)
 181 {
 182     m_windowFlags = flags;
 183     return m_windowFlags;
 184 }
 185
 186 void QCocoaWindow::setWindowTitle(const QString &title)
 187 {
 188     QCocoaAutoReleasePool pool;
 189     if (!m_nsWindow)
 190         return;
 191
 192     CFStringRef windowTitle = QCFString::toCFStringRef(title);
 193     [m_nsWindow setTitle: const_cast<NSString *>(reinterpret_cast<const NSString *>(windowTitle))];
 194     CFRelease(windowTitle);
 195 }
 196
 197 void QCocoaWindow::raise()
 198 {
 199     //qDebug() << "raise" << this;
 200     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
 201     if (!m_nsWindow)
 202         return;
 203     if ([m_nsWindow isVisible])
 204         [m_nsWindow orderFront: m_nsWindow];
 205 }
 206
 207 void QCocoaWindow::lower()
 208 {
 209     if (!m_nsWindow)
 210         return;
 211     if ([m_nsWindow isVisible])
 212         [m_nsWindow orderBack: m_nsWindow];
 213 }
 214
 215 void QCocoaWindow::propagateSizeHints()
 216 {
 217     QCocoaAutoReleasePool pool;
 218     if (!m_nsWindow)
 219         return;
 220
 221     [m_nsWindow setMinSize : qt_mac_toNSSize(window()->minimumSize())];
 222     [m_nsWindow setMaxSize : qt_mac_toNSSize(window()->maximumSize())];
 223
 224 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 225     qDebug() << "QCocoaWindow::propagateSizeHints" << this;
 226     qDebug() << "     min/max " << window()->minimumSize() << window()->maximumSize();
 227     qDebug() << "     basesize" << window()->baseSize();
 228     qDebug() << "     geometry" << geometry();
 229 #endif
 230
 231     if (!window()->sizeIncrement().isNull())
 232         [m_nsWindow setResizeIncrements : qt_mac_toNSSize(window()->sizeIncrement())];
 233
 234     QSize baseSize = window()->baseSize();
 235     if (!baseSize.isNull() && baseSize.isValid()) {
 236         [m_nsWindow setFrameSize : NSMakeSize(baseSize.width(), baseSize.height()) display : YES];
 237     }
 238 }
 239
 240 void QCocoaWindow::setOpacity(qreal level)
 241 {
 242     if (m_nsWindow)
 243         [m_nsWindow setAlphaValue:level];
 244 }
 245
 246 bool QCocoaWindow::setKeyboardGrabEnabled(bool grab)
 247 {
 248     if (!m_nsWindow)
 249         return false;
 250
 251     if (grab && ![m_nsWindow isKeyWindow])
 252         [m_nsWindow makeKeyWindow];
 253     else if (!grab && [m_nsWindow isKeyWindow])
 254         [m_nsWindow resignKeyWindow];
 255     return true;
 256 }
 257
 258 bool QCocoaWindow::setMouseGrabEnabled(bool grab)
 259 {
 260     if (!m_nsWindow)
 261         return false;
 262
 263     if (grab && ![m_nsWindow isKeyWindow])
 264         [m_nsWindow makeKeyWindow];
 265     else if (!grab && [m_nsWindow isKeyWindow])
 266         [m_nsWindow resignKeyWindow];
 267     return true;
 268 }
 269
 270 WId QCocoaWindow::winId() const
 271 {
 272     return WId(m_contentView);
 273 }
 274
 275 void QCocoaWindow::setParent(const QPlatformWindow *parentWindow)
 276 {
 277     // recreate the window for compatibility
 278     recreateWindow(parentWindow);
 279     setCocoaGeometry(geometry());
 280 }
 281
 282 NSView *QCocoaWindow::contentView() const
 283 {
 284     return m_contentView;
 285 }
 286
 287 void QCocoaWindow::windowWillMove()
 288 {
 289     // Close any open popups on window move
 290     if (m_activePopupWindow) {
 291         QWindowSystemInterface::handleSynchronousCloseEvent(m_activePopupWindow);
 292         m_activePopupWindow = 0;
 293     }
 294 }
 295
 296 void QCocoaWindow::windowDidMove()
 297 {
 298     [m_contentView updateGeometry];
 299 }
 300
 301 void QCocoaWindow::windowDidResize()
 302 {
 303     if (!m_nsWindow)
 304         return;
 305
 306     NSRect rect = [[m_nsWindow contentView]frame];
 307     // Call setFrameSize which will trigger a frameDidChangeNotification on QNSView.
 308     [[m_nsWindow contentView] setFrameSize:rect.size];
 309 }
 310
 311 void QCocoaWindow::windowWillClose()
 312 {
 313     QWindowSystemInterface::handleSynchronousCloseEvent(window());
 314 }
 315
 316 bool QCocoaWindow::windowIsPopupType() const
 317 {
 318     Qt::WindowType type = window()->windowType();
 319     if (type == Qt::Tool)
 320         return false; // Qt::Tool has the Popup bit set but isn't, at least on Mac.
 321
 322     return ((type & Qt::Popup) == Qt::Popup);
 323 }
 324
 325 void QCocoaWindow::setCurrentContext(QCocoaGLContext *context)
 326 {
 327     m_glContext = context;
 328 }
 329
 330 QCocoaGLContext *QCocoaWindow::currentContext() const
 331 {
 332     return m_glContext;
 333 }
 334
 335 void QCocoaWindow::recreateWindow(const QPlatformWindow *parentWindow)
 336 {
 337     // Remove current window (if any)
 338     if (m_nsWindow) {
 339         clearNSWindow(m_nsWindow);
 340         [m_nsWindow close];
 341         [m_nsWindow release];
 342         m_nsWindow = 0;
 343     }
 344
 345     if (!parentWindow) {
 346         // Create a new NSWindow if this is a top-level window.
 347         m_nsWindow = createNSWindow();
 348         setNSWindow(m_nsWindow);
 349     } else {
 350         // Child windows have no NSWindow, link the NSViews instead.
 351         const QCocoaWindow *parentCococaWindow = static_cast<const QCocoaWindow *>(parentWindow);
 352         [parentCococaWindow->m_contentView addSubview : m_contentView];
 353     }
 354 }
 355
 356 NSWindow * QCocoaWindow::createNSWindow()
 357 {
 358     QCocoaAutoReleasePool pool;
 359
 360     NSRect frame = qt_mac_flipRect(window()->geometry(), window());
 361
 362     Qt::WindowType type = window()->windowType();
 363     Qt::WindowFlags flags = window()->windowFlags();
 364
 365     NSUInteger styleMask;
 366     NSWindow *createdWindow = 0;
 367
 368     // Use NSPanel for popup-type windows. (Popup, Tool, ToolTip, SplashScreen)
 369     if ((type & Qt::Popup) == Qt::Popup) {
 370         if (windowIsPopupType()) {
 371             styleMask = NSBorderlessWindowMask;
 372         } else {
 373             styleMask = (NSUtilityWindowMask | NSResizableWindowMask | NSClosableWindowMask |
 374                          NSMiniaturizableWindowMask | NSTitledWindowMask);
 375         }
 376
 377         QNSPanel *window;
 378         window  = [[QNSPanel alloc] initWithContentRect:frame
 379                                          styleMask: styleMask
 380                                          backing:NSBackingStoreBuffered
 381                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 382                                                     // before the window is shown and needs a proper window.).
 383         [window setHasShadow:YES];
 384         window->m_cocoaPlatformWindow = this;
 385         createdWindow = window;
 386     } else {
 387         styleMask = (NSResizableWindowMask | NSClosableWindowMask | NSMiniaturizableWindowMask | NSTitledWindowMask);
 388         QNSWindow *window;
 389         window  = [[QNSWindow alloc] initWithContentRect:frame
 390                                          styleMask: styleMask
 391                                          backing:NSBackingStoreBuffered
 392                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 393                                                     // before the window is shown and needs a proper window.).
 394         window->m_cocoaPlatformWindow = this;
 395
 396 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
 397     if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
 398         // All windows with the WindowMaximizeButtonHint set also get a full-screen button.
 399         if (flags & Qt::WindowMaximizeButtonHint)
 400             [window setCollectionBehavior:NSWindowCollectionBehaviorFullScreenPrimary];
 401     }
 402 #endif
 403
 404         createdWindow = window;
 405     }
 406     return createdWindow;
 407 }
 408
 409 void QCocoaWindow::setNSWindow(NSWindow *window)
 410 {
 411     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
 412     [window setDelegate:delegate];
 413     [window setAcceptsMouseMovedEvents:YES];
 414
 415     // Prevent Cocoa from releasing the window on close. Qt
 416     // handles the close event asynchronously and we want to
 417     // make sure that m_nsWindow stays valid until the
 418     // QCocoaWindow is deleted by Qt.
 419     [window setReleasedWhenClosed : NO];
 420
 421     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 422                                           selector:@selector(windowDidBecomeKey)
 423                                           name:NSWindowDidBecomeKeyNotification
 424                                           object:m_nsWindow];
 425
 426     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 427                                           selector:@selector(windowDidResignKey)
 428                                           name:NSWindowDidResignKeyNotification
 429                                           object:m_nsWindow];
 430
 431     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 432                                           selector:@selector(windowDidBecomeMain)
 433                                           name:NSWindowDidBecomeMainNotification
 434                                           object:m_nsWindow];
 435
 436     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 437                                           selector:@selector(windowDidResignMain)
 438                                           name:NSWindowDidResignMainNotification
 439                                           object:m_nsWindow];
 440
 441
 442     // ### Accept touch events by default.
 443     // Beware that enabling touch events has a negative impact on the overall performance.
 444     // We probably need a QWindowSystemInterface API to enable/disable touch events.
 445     [m_contentView setAcceptsTouchEvents:YES];
 446
 447     [window setContentView:m_contentView];
 448 }
 449
 450 void QCocoaWindow::clearNSWindow(NSWindow *window)
 451 {
 452     [window setDelegate:nil];
 453     [[NSNotificationCenter defaultCenter] removeObserver:m_contentView];
 454     [m_contentView removeFromSuperviewWithoutNeedingDisplay];
 455 }
 456
 457 // Returns the current global screen geometry for the nswindow associated with this window.
 458 QRect QCocoaWindow::windowGeometry() const
 459 {
 460     if (!m_nsWindow)
 461         return geometry();
 462
 463     NSRect rect = [m_nsWindow frame];
 464     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
 465     int flippedY = onScreen->geometry().height() - rect.origin.y - rect.size.height;  // account for nswindow inverted y.
 466     QRect qRect = QRect(rect.origin.x, flippedY, rect.size.width, rect.size.height);
 467     return qRect;
 468 }
 469
 470 // Returns a pointer to the parent QCocoaWindow for this window, or 0 if there is none.
 471 QCocoaWindow *QCocoaWindow::parentCocoaWindow() const
 472 {
 473     if (window() && window()->transientParent()) {
 474         return static_cast<QCocoaWindow*>(window()->transientParent()->handle());
 475     }
 476     return 0;
 477 }
 478