Cocoa: Fix size hint and resize increment setting.
[profile/ivi/qtbase.git] / src / plugins / platforms / cocoa / qcocoawindow.mm
1 /****************************************************************************
2 **
3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
4 ** Contact: http://www.qt-project.org/
5 **
6 ** This file is part of the plugins of the Qt Toolkit.
7 **
8 ** $QT_BEGIN_LICENSE:LGPL$
9 ** GNU Lesser General Public License Usage
10 ** This file may be used under the terms of the GNU Lesser General Public
11 ** License version 2.1 as published by the Free Software Foundation and
12 ** appearing in the file LICENSE.LGPL included in the packaging of this
13 ** file. Please review the following information to ensure the GNU Lesser
14 ** General Public License version 2.1 requirements will be met:
15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
16 **
17 ** In addition, as a special exception, Nokia gives you certain additional
18 ** rights. These rights are described in the Nokia Qt LGPL Exception
19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
20 **
21 ** GNU General Public License Usage
22 ** Alternatively, this file may be used under the terms of the GNU General
23 ** Public License version 3.0 as published by the Free Software Foundation
24 ** and appearing in the file LICENSE.GPL included in the packaging of this
25 ** file. Please review the following information to ensure the GNU General
26 ** Public License version 3.0 requirements will be met:
27 ** http://www.gnu.org/copyleft/gpl.html.
28 **
29 ** Other Usage
30 ** Alternatively, this file may be used in accordance with the terms and
31 ** conditions contained in a signed written agreement between you and Nokia.
32 **
33 **
34 **
35 **
36 **
37 **
38 ** $QT_END_LICENSE$
39 **
40 ****************************************************************************/
41 #include "qcocoawindow.h"
42 #include "qnswindowdelegate.h"
43 #include "qcocoaautoreleasepool.h"
44 #include "qcocoaeventdispatcher.h"
45 #include "qcocoaglcontext.h"
46 #include "qcocoahelpers.h"
47 #include "qnsview.h"
48 #include <QtCore/private/qcore_mac_p.h>
49 #include <qwindow.h>
50 #include <qpa/qwindowsysteminterface.h>
51 #include <qpa/qplatformscreen.h>
52
53 #include <Cocoa/Cocoa.h>
54 #include <Carbon/Carbon.h>
55
56 #include <QDebug>
57
58 @implementation QNSWindow
59
60 - (BOOL)canBecomeKeyWindow
61 {
62     // The default implementation returns NO for title-bar less windows,
63     // override and return yes here to make sure popup windows such as
64     // the combobox popup can become the key window.
65     return YES;
66 }
67
68 - (BOOL)canBecomeMainWindow
69 {
70     BOOL canBecomeMain = YES; // By default, windows can become the main window
71
72     // Windows with a transient parent (such as combobox popup windows)
73     // cannot become the main window:
74     if (m_cocoaPlatformWindow->window()->transientParent())
75         canBecomeMain = NO;
76
77     return canBecomeMain;
78 }
79
80
81 @end
82
83 @implementation QNSPanel
84
85 - (BOOL)canBecomeKeyWindow
86 {
87     // Most panels can be come the key window. Exceptions are:
88     if (m_cocoaPlatformWindow->window()->windowType() == Qt::ToolTip)
89         return NO;
90     if (m_cocoaPlatformWindow->window()->windowType() == Qt::SplashScreen)
91         return NO;
92     return YES;
93 }
94
95 @end
96
97 QCocoaWindow::QCocoaWindow(QWindow *tlw)
98     : QPlatformWindow(tlw)
99     , m_nsWindow(0)
100     , m_synchedWindowState(Qt::WindowActive)
101     , m_inConstructor(true)
102     , m_glContext(0)
103     , m_menubar(0)
104     , m_hasModalSession(false)
105 {
106 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
107     qDebug() << "QCocoaWindow::QCocoaWindow" << this;
108 #endif
109     QCocoaAutoReleasePool pool;
110
111     m_contentView = [[QNSView alloc] initWithQWindow:tlw platformWindow:this];
112     setGeometry(tlw->geometry());
113
114     recreateWindow(parent());
115
116     m_inConstructor = false;
117 }
118
119 QCocoaWindow::~QCocoaWindow()
120 {
121     clearNSWindow(m_nsWindow);
122     [m_contentView release];
123     [m_nsWindow release];
124 }
125
126 void QCocoaWindow::setGeometry(const QRect &rect)
127 {
128     if (geometry() == rect)
129         return;
130 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
131     qDebug() << "QCocoaWindow::setGeometry" << this << rect;
132 #endif
133     QPlatformWindow::setGeometry(rect);
134     setCocoaGeometry(rect);
135 }
136
137 void QCocoaWindow::setCocoaGeometry(const QRect &rect)
138 {
139     if (m_nsWindow) {
140         NSRect bounds = qt_mac_flipRect(rect, window());
141         [m_nsWindow setContentSize : bounds.size];
142         [m_nsWindow setFrameOrigin : bounds.origin];
143     } else {
144         [m_contentView setFrame : NSMakeRect(rect.x(), rect.y(), rect.width(), rect.height())];
145     }
146 }
147
148 void QCocoaWindow::setVisible(bool visible)
149 {
150     QCocoaAutoReleasePool pool;
151 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
152     qDebug() << "QCocoaWindow::setVisible" << window() << visible;
153 #endif
154     if (visible) {
155         QCocoaWindow *parentCocoaWindow = 0;
156         if (window()->transientParent()) {
157             parentCocoaWindow = static_cast<QCocoaWindow *>(window()->transientParent()->handle());
158
159             // The parent window might have moved while this window was hidden,
160             // update the window geometry if there is a parent.
161             setGeometry(window()->geometry());
162
163             // Register popup windows so that the parent window can
164             // close them when needed.
165             if (window()->windowType() == Qt::Popup) {
166                 // qDebug() << "transientParent and popup" << window()->windowType() << Qt::Popup << (window()->windowType() & Qt::Popup);
167                 parentCocoaWindow->m_activePopupWindow = window();
168             }
169
170         }
171
172         // Make sure the QWindow has a frame ready before we show the NSWindow.
173         QWindowSystemInterface::handleSynchronousExposeEvent(window(), QRect(QPoint(), geometry().size()));
174
175         if (m_nsWindow) {
176             // setWindowState might have been called while the window was hidden and
177             // will not change the NSWindow state in that case. Sync up here:
178             syncWindowState(window()->windowState());
179
180             if (window()->windowState() != Qt::WindowMinimized) {
181                 if ((window()->windowModality() == Qt::WindowModal
182                      || window()->windowType() == Qt::Sheet)
183                         && parentCocoaWindow) {
184                     // show the window as a sheet
185                     [NSApp beginSheet:m_nsWindow modalForWindow:parentCocoaWindow->m_nsWindow modalDelegate:nil didEndSelector:nil contextInfo:nil];
186                 } else if (window()->windowModality() != Qt::NonModal) {
187                     // show the window as application modal
188                     QCocoaEventDispatcher *cocoaEventDispatcher = qobject_cast<QCocoaEventDispatcher *>(QGuiApplication::instance()->eventDispatcher());
189                     Q_ASSERT(cocoaEventDispatcher != 0);
190                     QCocoaEventDispatcherPrivate *cocoaEventDispatcherPrivate = static_cast<QCocoaEventDispatcherPrivate *>(QObjectPrivate::get(cocoaEventDispatcher));
191                     cocoaEventDispatcherPrivate->beginModalSession(window());
192                     m_hasModalSession = true;
193                 } else if ([m_nsWindow canBecomeKeyWindow]) {
194                     [m_nsWindow makeKeyAndOrderFront:nil];
195                 } else {
196                     [m_nsWindow orderFront: nil];
197                 }
198             }
199         }
200     } else {
201         // qDebug() << "close" << this;
202         if (m_nsWindow) {
203             if (m_hasModalSession) {
204                 QCocoaEventDispatcher *cocoaEventDispatcher = qobject_cast<QCocoaEventDispatcher *>(QGuiApplication::instance()->eventDispatcher());
205                 Q_ASSERT(cocoaEventDispatcher != 0);
206                 QCocoaEventDispatcherPrivate *cocoaEventDispatcherPrivate = static_cast<QCocoaEventDispatcherPrivate *>(QObjectPrivate::get(cocoaEventDispatcher));
207                 cocoaEventDispatcherPrivate->endModalSession(window());
208                 m_hasModalSession = false;
209             } else {
210                 if ([m_nsWindow isSheet])
211                     [NSApp endSheet:m_nsWindow];
212             }
213             [m_nsWindow orderOut:m_nsWindow];
214         }
215         if (!QCoreApplication::closingDown())
216             QWindowSystemInterface::handleExposeEvent(window(), QRegion());
217     }
218 }
219
220 Qt::WindowFlags QCocoaWindow::setWindowFlags(Qt::WindowFlags flags)
221 {
222     m_windowFlags = flags;
223     return m_windowFlags;
224 }
225
226 Qt::WindowState QCocoaWindow::setWindowState(Qt::WindowState state)
227 {
228     if ([m_nsWindow isVisible])
229         syncWindowState(state);  // Window state set for hidden windows take effect when show() is called.
230
231     return state;
232 }
233
234 void QCocoaWindow::setWindowTitle(const QString &title)
235 {
236     QCocoaAutoReleasePool pool;
237     if (!m_nsWindow)
238         return;
239
240     CFStringRef windowTitle = QCFString::toCFStringRef(title);
241     [m_nsWindow setTitle: const_cast<NSString *>(reinterpret_cast<const NSString *>(windowTitle))];
242     CFRelease(windowTitle);
243 }
244
245 void QCocoaWindow::raise()
246 {
247     //qDebug() << "raise" << this;
248     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
249     if (!m_nsWindow)
250         return;
251     if ([m_nsWindow isVisible])
252         [m_nsWindow orderFront: m_nsWindow];
253 }
254
255 void QCocoaWindow::lower()
256 {
257     if (!m_nsWindow)
258         return;
259     if ([m_nsWindow isVisible])
260         [m_nsWindow orderBack: m_nsWindow];
261 }
262
263 void QCocoaWindow::propagateSizeHints()
264 {
265     QCocoaAutoReleasePool pool;
266     if (!m_nsWindow)
267         return;
268
269 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
270     qDebug() << "QCocoaWindow::propagateSizeHints" << this;
271     qDebug() << "     min/max " << window()->minimumSize() << window()->maximumSize();
272     qDebug() << "size increment" << window()->sizeIncrement();
273     qDebug() << "     basesize" << window()->baseSize();
274     qDebug() << "     geometry" << geometry();
275 #endif
276
277     // Set the minimum content size.
278     const QSize minimumSize = window()->minimumSize();
279     if (!minimumSize.isValid()) // minimumSize is (-1, -1) when not set. Make that (0, 0) for Cocoa.
280         [m_nsWindow setContentMinSize : NSMakeSize(0.0, 0.0)];
281     [m_nsWindow setContentMinSize : NSMakeSize(minimumSize.width(), minimumSize.height())];
282
283     // Set the maximum content size.
284     const QSize maximumSize = window()->maximumSize();
285     [m_nsWindow setContentMaxSize : NSMakeSize(maximumSize.width(), maximumSize.height())];
286
287     // sizeIncrement is observed to take values of (-1, -1) and (0, 0) for windows that should be
288     // resizable and that have no specific size increment set. Cocoa expects (1.0, 1.0) in this case.
289     if (!window()->sizeIncrement().isEmpty())
290         [m_nsWindow setResizeIncrements : qt_mac_toNSSize(window()->sizeIncrement())];
291     else
292         [m_nsWindow setResizeIncrements : NSMakeSize(1.0, 1.0)];
293
294     QRect rect = geometry();
295     QSize baseSize = window()->baseSize();
296     if (!baseSize.isNull() && baseSize.isValid()) {
297         [m_nsWindow setFrame:NSMakeRect(rect.x(), rect.y(), baseSize.width(), baseSize.height()) display:YES];
298     }
299 }
300
301 void QCocoaWindow::setOpacity(qreal level)
302 {
303     if (m_nsWindow)
304         [m_nsWindow setAlphaValue:level];
305 }
306
307 bool QCocoaWindow::setKeyboardGrabEnabled(bool grab)
308 {
309     if (!m_nsWindow)
310         return false;
311
312     if (grab && ![m_nsWindow isKeyWindow])
313         [m_nsWindow makeKeyWindow];
314     else if (!grab && [m_nsWindow isKeyWindow])
315         [m_nsWindow resignKeyWindow];
316     return true;
317 }
318
319 bool QCocoaWindow::setMouseGrabEnabled(bool grab)
320 {
321     if (!m_nsWindow)
322         return false;
323
324     if (grab && ![m_nsWindow isKeyWindow])
325         [m_nsWindow makeKeyWindow];
326     else if (!grab && [m_nsWindow isKeyWindow])
327         [m_nsWindow resignKeyWindow];
328     return true;
329 }
330
331 WId QCocoaWindow::winId() const
332 {
333     return WId(m_contentView);
334 }
335
336 void QCocoaWindow::setParent(const QPlatformWindow *parentWindow)
337 {
338     // recreate the window for compatibility
339     recreateWindow(parentWindow);
340     setCocoaGeometry(geometry());
341 }
342
343 NSView *QCocoaWindow::contentView() const
344 {
345     return m_contentView;
346 }
347
348 void QCocoaWindow::windowWillMove()
349 {
350     // Close any open popups on window move
351     if (m_activePopupWindow) {
352         QWindowSystemInterface::handleSynchronousCloseEvent(m_activePopupWindow);
353         m_activePopupWindow = 0;
354     }
355 }
356
357 void QCocoaWindow::windowDidMove()
358 {
359     [m_contentView updateGeometry];
360 }
361
362 void QCocoaWindow::windowDidResize()
363 {
364     if (!m_nsWindow)
365         return;
366
367     NSRect rect = [[m_nsWindow contentView]frame];
368     // Call setFrameSize which will trigger a frameDidChangeNotification on QNSView.
369     [[m_nsWindow contentView] setFrameSize:rect.size];
370 }
371
372 void QCocoaWindow::windowWillClose()
373 {
374     QWindowSystemInterface::handleSynchronousCloseEvent(window());
375 }
376
377 bool QCocoaWindow::windowIsPopupType() const
378 {
379     Qt::WindowType type = window()->windowType();
380     if (type == Qt::Tool)
381         return false; // Qt::Tool has the Popup bit set but isn't, at least on Mac.
382
383     return ((type & Qt::Popup) == Qt::Popup);
384 }
385
386 void QCocoaWindow::setCurrentContext(QCocoaGLContext *context)
387 {
388     m_glContext = context;
389 }
390
391 QCocoaGLContext *QCocoaWindow::currentContext() const
392 {
393     return m_glContext;
394 }
395
396 void QCocoaWindow::recreateWindow(const QPlatformWindow *parentWindow)
397 {
398     // Remove current window (if any)
399     if (m_nsWindow) {
400         clearNSWindow(m_nsWindow);
401         [m_nsWindow close];
402         [m_nsWindow release];
403         m_nsWindow = 0;
404     }
405
406     if (!parentWindow) {
407         // Create a new NSWindow if this is a top-level window.
408         m_nsWindow = createNSWindow();
409         setNSWindow(m_nsWindow);
410
411         if (window()->transientParent()) {
412             // keep this window on the same level as its transient parent (which may be a modal dialog, for example)
413             QCocoaWindow *parentCocoaWindow = static_cast<QCocoaWindow *>(window()->transientParent()->handle());
414             [m_nsWindow setLevel:[parentCocoaWindow->m_nsWindow level]];
415         }
416     } else {
417         // Child windows have no NSWindow, link the NSViews instead.
418         const QCocoaWindow *parentCococaWindow = static_cast<const QCocoaWindow *>(parentWindow);
419         [parentCococaWindow->m_contentView addSubview : m_contentView];
420     }
421 }
422
423 NSWindow * QCocoaWindow::createNSWindow()
424 {
425     QCocoaAutoReleasePool pool;
426
427     NSRect frame = qt_mac_flipRect(window()->geometry(), window());
428
429     Qt::WindowType type = window()->windowType();
430     Qt::WindowFlags flags = window()->windowFlags();
431
432     NSUInteger styleMask;
433     NSWindow *createdWindow = 0;
434     NSInteger windowLevel = -1;
435
436     if (type == Qt::Tool) {
437         windowLevel = NSFloatingWindowLevel;
438     } else if ((type & Qt::Popup) == Qt::Popup) {
439         // styleMask = NSBorderlessWindowMask;
440         windowLevel = NSPopUpMenuWindowLevel;
441
442         // Popup should be in at least the same level as its parent.
443         const QWindow * const transientParent = window()->transientParent();
444         const QCocoaWindow * const transientParentWindow = transientParent ? static_cast<QCocoaWindow *>(transientParent->handle()) : 0;
445         if (transientParentWindow)
446             windowLevel = qMax([transientParentWindow->m_nsWindow level], windowLevel);
447     }
448
449     // StayOnTop window should appear above Tool windows.
450     if (flags & Qt::WindowStaysOnTopHint)
451         windowLevel = NSPopUpMenuWindowLevel;
452     // Tooltips should appear above StayOnTop windows.
453     if (type == Qt::ToolTip)
454         windowLevel = NSScreenSaverWindowLevel;
455     // All other types are Normal level.
456     if (windowLevel == -1)
457         windowLevel = NSNormalWindowLevel;
458
459     // Use NSPanel for popup-type windows. (Popup, Tool, ToolTip, SplashScreen)
460     if ((type & Qt::Popup) == Qt::Popup) {
461         if (windowIsPopupType()) {
462             styleMask = NSBorderlessWindowMask;
463         } else {
464             styleMask = (NSUtilityWindowMask | NSResizableWindowMask | NSClosableWindowMask |
465                          NSMiniaturizableWindowMask | NSTitledWindowMask);
466         }
467
468         QNSPanel *window;
469         window  = [[QNSPanel alloc] initWithContentRect:frame
470                                          styleMask: styleMask
471                                          backing:NSBackingStoreBuffered
472                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
473                                                     // before the window is shown and needs a proper window.).
474         [window setHasShadow:YES];
475
476 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
477         if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
478             // Make popup winows show on the same desktop as the parent full-screen window.
479             [window setCollectionBehavior:NSWindowCollectionBehaviorFullScreenAuxiliary];
480         }
481 #endif
482         window->m_cocoaPlatformWindow = this;
483         createdWindow = window;
484     } else {
485         styleMask = (NSResizableWindowMask | NSClosableWindowMask | NSMiniaturizableWindowMask | NSTitledWindowMask);
486         QNSWindow *window;
487         window  = [[QNSWindow alloc] initWithContentRect:frame
488                                          styleMask: styleMask
489                                          backing:NSBackingStoreBuffered
490                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
491                                                     // before the window is shown and needs a proper window.).
492         window->m_cocoaPlatformWindow = this;
493
494 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
495     if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
496         // All windows with the WindowMaximizeButtonHint set also get a full-screen button.
497         if (flags & Qt::WindowMaximizeButtonHint)
498             [window setCollectionBehavior:NSWindowCollectionBehaviorFullScreenPrimary];
499     }
500 #endif
501
502         createdWindow = window;
503     }
504
505     [createdWindow setLevel:windowLevel];
506
507     return createdWindow;
508 }
509
510 void QCocoaWindow::setNSWindow(NSWindow *window)
511 {
512     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
513     [window setDelegate:delegate];
514     [window setAcceptsMouseMovedEvents:YES];
515
516     // Prevent Cocoa from releasing the window on close. Qt
517     // handles the close event asynchronously and we want to
518     // make sure that m_nsWindow stays valid until the
519     // QCocoaWindow is deleted by Qt.
520     [window setReleasedWhenClosed : NO];
521
522
523     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
524                                           selector:@selector(windowNotification:)
525                                           name:nil // Get all notifications
526                                           object:m_nsWindow];
527
528     // ### Accept touch events by default.
529     // Beware that enabling touch events has a negative impact on the overall performance.
530     // We probably need a QWindowSystemInterface API to enable/disable touch events.
531     [m_contentView setAcceptsTouchEvents:YES];
532
533     [window setContentView:m_contentView];
534 }
535
536 void QCocoaWindow::clearNSWindow(NSWindow *window)
537 {
538     [window setDelegate:nil];
539     [[NSNotificationCenter defaultCenter] removeObserver:m_contentView];
540 }
541
542 // Returns the current global screen geometry for the nswindow associated with this window.
543 QRect QCocoaWindow::windowGeometry() const
544 {
545     if (!m_nsWindow)
546         return geometry();
547
548     NSRect rect = [m_nsWindow frame];
549     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
550     int flippedY = onScreen->geometry().height() - rect.origin.y - rect.size.height;  // account for nswindow inverted y.
551     QRect qRect = QRect(rect.origin.x, flippedY, rect.size.width, rect.size.height);
552     return qRect;
553 }
554
555 // Returns a pointer to the parent QCocoaWindow for this window, or 0 if there is none.
556 QCocoaWindow *QCocoaWindow::parentCocoaWindow() const
557 {
558     if (window() && window()->transientParent()) {
559         return static_cast<QCocoaWindow*>(window()->transientParent()->handle());
560     }
561     return 0;
562 }
563
564 // Syncs the NSWindow minimize/maximize/fullscreen state with the current QWindow state
565 void QCocoaWindow::syncWindowState(Qt::WindowState newState)
566 {
567     if (!m_nsWindow)
568         return;
569
570     if ((m_synchedWindowState & Qt::WindowMaximized) != (newState & Qt::WindowMaximized)) {
571         [m_nsWindow performZoom : m_nsWindow]; // toggles
572     }
573
574     if ((m_synchedWindowState & Qt::WindowMinimized) != (newState & Qt::WindowMinimized)) {
575         if (newState & Qt::WindowMinimized) {
576             [m_nsWindow performMiniaturize : m_nsWindow];
577         } else {
578             [m_nsWindow deminiaturize : m_nsWindow];
579         }
580     }
581
582     if ((m_synchedWindowState & Qt::WindowFullScreen) != (newState & Qt::WindowFullScreen)) {
583 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
584         if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
585             [m_nsWindow toggleFullScreen : m_nsWindow];
586         } else {
587             // TODO: "normal" fullscreen
588         }
589 #endif
590     }
591
592     // New state is now the current synched state
593     m_synchedWindowState = newState;
594 }
595
596 bool QCocoaWindow::setWindowModified(bool modified)
597 {
598     if (!m_nsWindow)
599         return false;
600     [m_nsWindow setDocumentEdited:(modified?YES:NO)];
601     return true;
602 }
603
604 void QCocoaWindow::setMenubar(QCocoaMenuBar *mb)
605 {
606     m_menubar = mb;
607 }
608
609 QCocoaMenuBar *QCocoaWindow::menubar() const
610 {
611     return m_menubar;
612 }