src/plugins/platforms/cocoa/qcocoawindow.mm

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the plugins of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 #include "qcocoawindow.h"
  42 #include "qnswindowdelegate.h"
  43 #include "qcocoaautoreleasepool.h"
  44 #include "qcocoaglcontext.h"
  45 #include "qnsview.h"
  46 #include <QtCore/private/qcore_mac_p.h>
  47
  48 #include <QWindowSystemInterface>
  49
  50 #include <QDebug>
  51
  52 QCocoaWindow::QCocoaWindow(QWindow *tlw)
  53     : QPlatformWindow(tlw)
  54     , m_glContext(0)
  55 {
  56     QCocoaAutoReleasePool pool;
  57     const QRect geo = tlw->geometry();
  58     NSRect frame = NSMakeRect(geo.x(), geo.y(), geo.width(), geo.height());
  59
  60     m_nsWindow  = [[NSWindow alloc] initWithContentRect:frame
  61                                             styleMask:NSTitledWindowMask|NSClosableWindowMask|NSMiniaturizableWindowMask|NSResizableWindowMask
  62                                             backing:NSBackingStoreBuffered
  63                                             defer:YES];
  64
  65     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
  66     [m_nsWindow setDelegate:delegate];
  67
  68     [m_nsWindow setAcceptsMouseMovedEvents:YES];
  69
  70     m_contentView = [[QNSView alloc] initWithQWindow:tlw];
  71
  72     if (tlw->surfaceType() == QWindow::OpenGLSurface) {
  73         NSRect glFrame = NSMakeRect(0, 0, geo.width(), geo.height());
  74         m_windowSurfaceView = [[NSOpenGLView alloc] initWithFrame : glFrame pixelFormat : QCocoaGLContext::createNSOpenGLPixelFormat() ];
  75         [m_contentView setAutoresizesSubviews : YES];
  76         [m_windowSurfaceView setAutoresizingMask : (NSViewWidthSizable | NSViewHeightSizable)];
  77         [m_contentView addSubview : m_windowSurfaceView];
  78     } else {
  79         m_windowSurfaceView = m_contentView;
  80     }
  81
  82     [m_nsWindow setContentView:m_contentView];
  83 }
  84
  85 QCocoaWindow::~QCocoaWindow()
  86 {
  87 }
  88
  89 void QCocoaWindow::setGeometry(const QRect &rect)
  90 {
  91     QPlatformWindow::setGeometry(rect);
  92
  93     NSRect bounds = NSMakeRect(rect.x(), rect.y(), rect.width(), rect.height());
  94     [[m_nsWindow contentView]setFrameSize:bounds.size];
  95 }
  96
  97 void QCocoaWindow::setVisible(bool visible)
  98 {
  99     if (visible) {
 100         [m_nsWindow makeKeyAndOrderFront:nil];
 101     } else {
 102         [m_nsWindow orderOut:nil];
 103     }
 104 }
 105
 106 void QCocoaWindow::setWindowTitle(const QString &title)
 107 {
 108     CFStringRef windowTitle = QCFString::toCFStringRef(title);
 109     [m_nsWindow setTitle: reinterpret_cast<const NSString *>(windowTitle)];
 110     CFRelease(windowTitle);
 111 }
 112
 113 void QCocoaWindow::raise()
 114 {
 115     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
 116     [m_nsWindow orderFront];
 117 }
 118
 119 void QCocoaWindow::lower()
 120 {
 121     [m_nsWindow orderBack];
 122 }
 123
 124 WId QCocoaWindow::winId() const
 125 {
 126     return WId(m_nsWindow);
 127 }
 128
 129 NSView *QCocoaWindow::contentView() const
 130 {
 131     return [m_nsWindow contentView];
 132 }
 133
 134 void QCocoaWindow::windowDidResize()
 135 {
 136     //jlind: XXX This isn't ideal. Eventdispatcher does not run when resizing...
 137     NSRect rect = [[m_nsWindow contentView]frame];
 138     QRect geo(rect.origin.x,rect.origin.y,rect.size.width,rect.size.height);
 139     QWindowSystemInterface::handleGeometryChange(window(),geo);
 140 }
 141
 142 QPlatformGLContext *QCocoaWindow::glContext() const
 143 {
 144     if (!m_glContext) {
 145         m_glContext = new QCocoaGLContext(m_windowSurfaceView);
 146     }
 147     return m_glContext;
 148 }