src/plugins/platforms/cocoa/qcocoawindow.mm

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the plugins of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 #include "qcocoawindow.h"
  42 #include "qnswindowdelegate.h"
  43 #include "qcocoaautoreleasepool.h"
  44 #include "qcocoaglcontext.h"
  45 #include "qcocoahelpers.h"
  46 #include "qnsview.h"
  47 #include <QtCore/private/qcore_mac_p.h>
  48 #include <qwindow.h>
  49 #include <QWindowSystemInterface>
  50 #include <QPlatformScreen>
  51
  52 #include <Cocoa/Cocoa.h>
  53 #include <Carbon/Carbon.h>
  54
  55 #include <QDebug>
  56
  57 @implementation QNSWindow
  58
  59 - (BOOL)canBecomeKeyWindow
  60 {
  61     // The default implementation returns NO for title-bar less windows,
  62     // override and return yes here to make sure popup windows such as
  63     // the combobox popup can become the key window.
  64     return YES;
  65 }
  66
  67 - (BOOL)canBecomeMainWindow
  68 {
  69     BOOL canBecomeMain = YES; // By default, windows can become the main window
  70
  71     // Windows with a transient parent (such as combobox popup windows)
  72     // cannot become the main window:
  73     if (m_cocoaPlatformWindow->window()->transientParent())
  74         canBecomeMain = NO;
  75
  76     return canBecomeMain;
  77 }
  78
  79
  80 @end
  81
  82 @implementation QNSPanel
  83
  84 - (BOOL)canBecomeKeyWindow
  85 {
  86     // Most panels can be come the key window. Exceptions are:
  87     if (m_cocoaPlatformWindow->window()->windowType() == Qt::ToolTip)
  88         return NO;
  89     if (m_cocoaPlatformWindow->window()->windowType() == Qt::SplashScreen)
  90         return NO;
  91     return YES;
  92 }
  93
  94 @end
  95
  96 QCocoaWindow::QCocoaWindow(QWindow *tlw)
  97     : QPlatformWindow(tlw)
  98     , m_nsWindow(0)
  99     , m_glContext(0)
 100     , m_inConstructor(true)
 101 {
 102     QCocoaAutoReleasePool pool;
 103
 104     m_contentView = [[QNSView alloc] initWithQWindow:tlw platformWindow:this];
 105     setGeometry(tlw->geometry());
 106
 107     recreateWindow(parent());
 108
 109     m_inConstructor = false;
 110 }
 111
 112 QCocoaWindow::~QCocoaWindow()
 113 {
 114     [m_contentView release];
 115     clearNSWindow(m_nsWindow);
 116     [m_nsWindow release];
 117 }
 118
 119 void QCocoaWindow::setGeometry(const QRect &rect)
 120 {
 121     if (geometry() == rect)
 122         return;
 123 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 124     qDebug() << "QCocoaWindow::setGeometry" << this << rect;
 125 #endif
 126     QPlatformWindow::setGeometry(rect);
 127     setCocoaGeometry(rect);
 128 }
 129
 130 void QCocoaWindow::setCocoaGeometry(const QRect &rect)
 131 {
 132     if (m_nsWindow) {
 133         NSRect bounds = qt_mac_flipRect(rect, window());
 134         [m_nsWindow setContentSize : bounds.size];
 135         [m_nsWindow setFrameOrigin : bounds.origin];
 136     } else {
 137         [m_contentView setFrame : NSMakeRect(rect.x(), rect.y(), rect.width(), rect.height())];
 138     }
 139 }
 140
 141 void QCocoaWindow::setVisible(bool visible)
 142 {
 143     QCocoaAutoReleasePool pool;
 144 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 145     qDebug() << "QCocoaWindow::setVisible" << window() << visible;
 146 #endif
 147     if (visible) {
 148         if (window()->transientParent()) {
 149             // The parent window might have moved while this window was hidden,
 150             // update the window geometry if there is a parent.
 151             setGeometry(window()->geometry());
 152
 153             // Register popup windows so that the parent window can
 154             // close them when needed.
 155             if (window()->windowType() == Qt::Popup) {
 156                 // qDebug() << "transientParent and popup" << window()->windowType() << Qt::Popup << (window()->windowType() & Qt::Popup);
 157
 158                 QCocoaWindow *parentCocoaWindow = static_cast<QCocoaWindow *>(window()->transientParent()->handle());
 159                 parentCocoaWindow->m_activePopupWindow = window();
 160             }
 161
 162         }
 163
 164         // Make sure the QWindow has a frame ready before we show the NSWindow.
 165         QWindowSystemInterface::handleSynchronousExposeEvent(window(), QRect(QPoint(), geometry().size()));
 166
 167         if (m_nsWindow) {
 168             if ([m_nsWindow canBecomeKeyWindow])
 169                 [m_nsWindow makeKeyAndOrderFront:nil];
 170             else
 171                 [m_nsWindow orderFront: nil];
 172         }
 173     } else {
 174         // qDebug() << "close" << this;
 175         if (m_nsWindow)
 176             [m_nsWindow orderOut:m_nsWindow];
 177     }
 178 }
 179
 180 Qt::WindowFlags QCocoaWindow::setWindowFlags(Qt::WindowFlags flags)
 181 {
 182     m_windowFlags = flags;
 183     return m_windowFlags;
 184 }
 185
 186 void QCocoaWindow::setWindowTitle(const QString &title)
 187 {
 188     QCocoaAutoReleasePool pool;
 189     if (!m_nsWindow)
 190         return;
 191
 192     CFStringRef windowTitle = QCFString::toCFStringRef(title);
 193     [m_nsWindow setTitle: const_cast<NSString *>(reinterpret_cast<const NSString *>(windowTitle))];
 194     CFRelease(windowTitle);
 195 }
 196
 197 void QCocoaWindow::raise()
 198 {
 199     //qDebug() << "raise" << this;
 200     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
 201     if (m_nsWindow)
 202         [m_nsWindow orderFront: m_nsWindow];
 203 }
 204
 205 void QCocoaWindow::lower()
 206 {
 207     if (m_nsWindow)
 208         [m_nsWindow orderBack: m_nsWindow];
 209 }
 210
 211 void QCocoaWindow::propagateSizeHints()
 212 {
 213     QCocoaAutoReleasePool pool;
 214     if (!m_nsWindow)
 215         return;
 216
 217     [m_nsWindow setMinSize : qt_mac_toNSSize(window()->minimumSize())];
 218     [m_nsWindow setMaxSize : qt_mac_toNSSize(window()->maximumSize())];
 219
 220 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 221     qDebug() << "QCocoaWindow::propagateSizeHints" << this;
 222     qDebug() << "     min/max " << window()->minimumSize() << window()->maximumSize();
 223     qDebug() << "     basesize" << window()->baseSize();
 224     qDebug() << "     geometry" << geometry();
 225 #endif
 226
 227     if (!window()->sizeIncrement().isNull())
 228         [m_nsWindow setResizeIncrements : qt_mac_toNSSize(window()->sizeIncrement())];
 229
 230     QSize baseSize = window()->baseSize();
 231     if (!baseSize.isNull() && baseSize.isValid()) {
 232         [m_nsWindow setFrameSize : NSMakeSize(baseSize.width(), baseSize.height()) display : YES];
 233     }
 234 }
 235
 236 bool QCocoaWindow::setKeyboardGrabEnabled(bool grab)
 237 {
 238     if (!m_nsWindow)
 239         return false;
 240
 241     if (grab && ![m_nsWindow isKeyWindow])
 242         [m_nsWindow makeKeyWindow];
 243     else if (!grab && [m_nsWindow isKeyWindow])
 244         [m_nsWindow resignKeyWindow];
 245     return true;
 246 }
 247
 248 bool QCocoaWindow::setMouseGrabEnabled(bool grab)
 249 {
 250     if (!m_nsWindow)
 251         return false;
 252
 253     if (grab && ![m_nsWindow isKeyWindow])
 254         [m_nsWindow makeKeyWindow];
 255     else if (!grab && [m_nsWindow isKeyWindow])
 256         [m_nsWindow resignKeyWindow];
 257     return true;
 258 }
 259
 260 WId QCocoaWindow::winId() const
 261 {
 262     return WId(m_contentView);
 263 }
 264
 265 void QCocoaWindow::setParent(const QPlatformWindow *parentWindow)
 266 {
 267     // recreate the window for compatibility
 268     recreateWindow(parentWindow);
 269     setCocoaGeometry(geometry());
 270 }
 271
 272 NSView *QCocoaWindow::contentView() const
 273 {
 274     return m_contentView;
 275 }
 276
 277 void QCocoaWindow::windowWillMove()
 278 {
 279     // Close any open popups on window move
 280     if (m_activePopupWindow) {
 281         QWindowSystemInterface::handleSynchronousCloseEvent(m_activePopupWindow);
 282         m_activePopupWindow = 0;
 283     }
 284 }
 285
 286 void QCocoaWindow::windowDidMove()
 287 {
 288     [m_contentView updateGeometry];
 289 }
 290
 291 void QCocoaWindow::windowDidResize()
 292 {
 293     if (!m_nsWindow)
 294         return;
 295
 296     NSRect rect = [[m_nsWindow contentView]frame];
 297     // Call setFrameSize which will trigger a frameDidChangeNotification on QNSView.
 298     [[m_nsWindow contentView] setFrameSize:rect.size];
 299 }
 300
 301 void QCocoaWindow::windowWillClose()
 302 {
 303     QWindowSystemInterface::handleSynchronousCloseEvent(window());
 304 }
 305
 306 void QCocoaWindow::setCurrentContext(QCocoaGLContext *context)
 307 {
 308     m_glContext = context;
 309 }
 310
 311 QCocoaGLContext *QCocoaWindow::currentContext() const
 312 {
 313     return m_glContext;
 314 }
 315
 316 void QCocoaWindow::recreateWindow(const QPlatformWindow *parentWindow)
 317 {
 318     // Remove current window (if any)
 319     if (m_nsWindow) {
 320         clearNSWindow(m_nsWindow);
 321         [m_nsWindow close];
 322         [m_nsWindow release];
 323         m_nsWindow = 0;
 324     }
 325
 326     if (!parentWindow) {
 327         // Create a new NSWindow if this is a top-level window.
 328         m_nsWindow = createNSWindow();
 329         setNSWindow(m_nsWindow);
 330     } else {
 331         // Child windows have no NSWindow, link the NSViews instead.
 332         const QCocoaWindow *parentCococaWindow = static_cast<const QCocoaWindow *>(parentWindow);
 333         [parentCococaWindow->m_contentView addSubview : m_contentView];
 334     }
 335 }
 336
 337 NSWindow * QCocoaWindow::createNSWindow()
 338 {
 339     QCocoaAutoReleasePool pool;
 340
 341     NSRect frame = qt_mac_flipRect(window()->geometry(), window());
 342
 343     Qt::WindowType type = window()->windowType();
 344     Qt::WindowFlags flags = window()->windowFlags();
 345
 346     NSUInteger styleMask;
 347     NSWindow *createdWindow = 0;
 348
 349     // Use NSPanel for popup-type windows. (Popup, Tool, ToolTip, SplashScreen)
 350     if ((type & Qt::Popup) == Qt::Popup) {
 351         if (type == Qt::Popup || type == Qt::ToolTip || type == Qt::SplashScreen) {
 352             styleMask = NSBorderlessWindowMask;
 353         } else {
 354             styleMask = (NSUtilityWindowMask | NSResizableWindowMask | NSClosableWindowMask |
 355                          NSMiniaturizableWindowMask | NSTitledWindowMask);
 356         }
 357
 358         QNSPanel *window;
 359         window  = [[QNSPanel alloc] initWithContentRect:frame
 360                                          styleMask: styleMask
 361                                          backing:NSBackingStoreBuffered
 362                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 363                                                     // before the window is shown and needs a proper window.).
 364         [window setHasShadow:YES];
 365         window->m_cocoaPlatformWindow = this;
 366         createdWindow = window;
 367     } else {
 368         styleMask = (NSResizableWindowMask | NSClosableWindowMask | NSMiniaturizableWindowMask | NSTitledWindowMask);
 369         QNSWindow *window;
 370         window  = [[QNSWindow alloc] initWithContentRect:frame
 371                                          styleMask: styleMask
 372                                          backing:NSBackingStoreBuffered
 373                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 374                                                     // before the window is shown and needs a proper window.).
 375         window->m_cocoaPlatformWindow = this;
 376         createdWindow = window;
 377     }
 378     return createdWindow;
 379 }
 380
 381 void QCocoaWindow::setNSWindow(NSWindow *window)
 382 {
 383     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
 384     [window setDelegate:delegate];
 385     [window setAcceptsMouseMovedEvents:YES];
 386
 387     // Prevent Cocoa from releasing the window on close. Qt
 388     // handles the close event asynchronously and we want to
 389     // make sure that m_nsWindow stays valid until the
 390     // QCocoaWindow is deleted by Qt.
 391     [window setReleasedWhenClosed : NO];
 392
 393     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 394                                           selector:@selector(windowDidBecomeKey)
 395                                           name:NSWindowDidBecomeKeyNotification
 396                                           object:m_nsWindow];
 397
 398     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 399                                           selector:@selector(windowDidResignKey)
 400                                           name:NSWindowDidResignKeyNotification
 401                                           object:m_nsWindow];
 402
 403     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 404                                           selector:@selector(windowDidBecomeMain)
 405                                           name:NSWindowDidBecomeMainNotification
 406                                           object:m_nsWindow];
 407
 408     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 409                                           selector:@selector(windowDidResignMain)
 410                                           name:NSWindowDidResignMainNotification
 411                                           object:m_nsWindow];
 412
 413
 414     // ### Accept touch events by default.
 415     // Beware that enabling touch events has a negative impact on the overall performance.
 416     // We probably need a QWindowSystemInterface API to enable/disable touch events.
 417     [m_contentView setAcceptsTouchEvents:YES];
 418
 419     [window setContentView:m_contentView];
 420 }
 421
 422 void QCocoaWindow::clearNSWindow(NSWindow *window)
 423 {
 424     [[NSNotificationCenter defaultCenter] removeObserver:m_contentView];
 425 }
 426
 427 // Returns the current global screen geometry for the nswindow associated with this window.
 428 QRect QCocoaWindow::windowGeometry() const
 429 {
 430     if (!m_nsWindow)
 431         return geometry();
 432
 433     NSRect rect = [m_nsWindow frame];
 434     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
 435     int flippedY = onScreen->geometry().height() - rect.origin.y - rect.size.height;  // account for nswindow inverted y.
 436     QRect qRect = QRect(rect.origin.x, flippedY, rect.size.width, rect.size.height);
 437     return qRect;
 438 }
 439
 440 // Returns a pointer to the parent QCocoaWindow for this window, or 0 if there is none.
 441 QCocoaWindow *QCocoaWindow::parentCocoaWindow() const
 442 {
 443     if (window() && window()->transientParent()) {
 444         return static_cast<QCocoaWindow*>(window()->transientParent()->handle());
 445     }
 446     return 0;
 447 }
 448