src/plugins/platforms/cocoa/qcocoawindow.mm

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/legal
   5 **
   6 ** This file is part of the plugins of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** Commercial License Usage
  10 ** Licensees holding valid commercial Qt licenses may use this file in
  11 ** accordance with the commercial license agreement provided with the
  12 ** Software or, alternatively, in accordance with the terms contained in
  13 ** a written agreement between you and Digia.  For licensing terms and
  14 ** conditions see http://qt.digia.com/licensing.  For further information
  15 ** use the contact form at http://qt.digia.com/contact-us.
  16 **
  17 ** GNU Lesser General Public License Usage
  18 ** Alternatively, this file may be used under the terms of the GNU Lesser
  19 ** General Public License version 2.1 as published by the Free Software
  20 ** Foundation and appearing in the file LICENSE.LGPL included in the
  21 ** packaging of this file.  Please review the following information to
  22 ** ensure the GNU Lesser General Public License version 2.1 requirements
  23 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  24 **
  25 ** In addition, as a special exception, Digia gives you certain additional
  26 ** rights.  These rights are described in the Digia Qt LGPL Exception
  27 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  28 **
  29 ** GNU General Public License Usage
  30 ** Alternatively, this file may be used under the terms of the GNU
  31 ** General Public License version 3.0 as published by the Free Software
  32 ** Foundation and appearing in the file LICENSE.GPL included in the
  33 ** packaging of this file.  Please review the following information to
  34 ** ensure the GNU General Public License version 3.0 requirements will be
  35 ** met: http://www.gnu.org/copyleft/gpl.html.
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 #include "qcocoawindow.h"
  42 #include "qnswindowdelegate.h"
  43 #include "qcocoaautoreleasepool.h"
  44 #include "qcocoaeventdispatcher.h"
  45 #include "qcocoaglcontext.h"
  46 #include "qcocoahelpers.h"
  47 #include "qnsview.h"
  48 #include <QtCore/qfileinfo.h>
  49 #include <QtCore/private/qcore_mac_p.h>
  50 #include <qwindow.h>
  51 #include <qpa/qwindowsysteminterface.h>
  52 #include <qpa/qplatformscreen.h>
  53
  54 #include <Cocoa/Cocoa.h>
  55 #include <Carbon/Carbon.h>
  56
  57 #include <QDebug>
  58
  59 static bool isMouseEvent(NSEvent *ev)
  60 {
  61     switch ([ev type]) {
  62     case NSLeftMouseDown:
  63     case NSLeftMouseUp:
  64     case NSRightMouseDown:
  65     case NSRightMouseUp:
  66     case NSMouseMoved:
  67     case NSLeftMouseDragged:
  68     case NSRightMouseDragged:
  69         return true;
  70     default:
  71         return false;
  72     }
  73 }
  74
  75 @interface NSWindow (CocoaWindowCategory)
  76 - (void) clearPlatformWindow;
  77 - (NSRect) legacyConvertRectFromScreen:(NSRect) rect;
  78 @end
  79
  80 @implementation NSWindow (CocoaWindowCategory)
  81 - (void) clearPlatformWindow
  82 {
  83 }
  84
  85 - (NSRect) legacyConvertRectFromScreen:(NSRect) rect
  86 {
  87 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
  88     if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
  89         return [self convertRectFromScreen: rect];
  90     }
  91 #endif
  92     NSRect r = rect;
  93     r.origin = [self convertScreenToBase:rect.origin];
  94     return r;
  95 }
  96 @end
  97
  98 @implementation QNSWindow
  99
 100 - (BOOL)canBecomeKeyWindow
 101 {
 102     // The default implementation returns NO for title-bar less windows,
 103     // override and return yes here to make sure popup windows such as
 104     // the combobox popup can become the key window.
 105     return YES;
 106 }
 107
 108 - (BOOL)canBecomeMainWindow
 109 {
 110     BOOL canBecomeMain = YES; // By default, windows can become the main window
 111
 112     // Windows with a transient parent (such as combobox popup windows)
 113     // cannot become the main window:
 114     if (m_cocoaPlatformWindow->window()->transientParent())
 115         canBecomeMain = NO;
 116
 117     return canBecomeMain;
 118 }
 119
 120 - (void) sendEvent: (NSEvent*) theEvent
 121 {
 122     [super sendEvent: theEvent];
 123
 124     if (!m_cocoaPlatformWindow)
 125         return;
 126
 127     if (m_cocoaPlatformWindow->frameStrutEventsEnabled() && isMouseEvent(theEvent)) {
 128         NSPoint loc = [theEvent locationInWindow];
 129         NSRect windowFrame = [self legacyConvertRectFromScreen:[self frame]];
 130         NSRect contentFrame = [[self contentView] frame];
 131         if (NSMouseInRect(loc, windowFrame, NO) &&
 132             !NSMouseInRect(loc, contentFrame, NO))
 133         {
 134             QNSView *contentView = (QNSView *) m_cocoaPlatformWindow->contentView();
 135             [contentView handleFrameStrutMouseEvent: theEvent];
 136         }
 137     }
 138 }
 139
 140 - (void)clearPlatformWindow
 141 {
 142     m_cocoaPlatformWindow = 0;
 143 }
 144
 145 @end
 146
 147 @implementation QNSPanel
 148
 149 - (BOOL)canBecomeKeyWindow
 150 {
 151     // Most panels can be come the key window. Exceptions are:
 152     if (m_cocoaPlatformWindow->window()->windowType() == Qt::ToolTip)
 153         return NO;
 154     if (m_cocoaPlatformWindow->window()->windowType() == Qt::SplashScreen)
 155         return NO;
 156     return YES;
 157 }
 158
 159 - (void) sendEvent: (NSEvent*) theEvent
 160 {
 161     [super sendEvent: theEvent];
 162
 163     if (!m_cocoaPlatformWindow)
 164         return;
 165
 166     if (m_cocoaPlatformWindow->frameStrutEventsEnabled() && isMouseEvent(theEvent)) {
 167         NSPoint loc = [theEvent locationInWindow];
 168         NSRect windowFrame = [self legacyConvertRectFromScreen:[self frame]];
 169         NSRect contentFrame = [[self contentView] frame];
 170         if (NSMouseInRect(loc, windowFrame, NO) &&
 171             !NSMouseInRect(loc, contentFrame, NO))
 172         {
 173             QNSView *contentView = (QNSView *) m_cocoaPlatformWindow->contentView();
 174             [contentView handleFrameStrutMouseEvent: theEvent];
 175         }
 176     }
 177 }
 178
 179 - (void)clearPlatformWindow
 180 {
 181     m_cocoaPlatformWindow = 0;
 182 }
 183
 184 @end
 185
 186 QCocoaWindow::QCocoaWindow(QWindow *tlw)
 187     : QPlatformWindow(tlw)
 188     , m_nsWindow(0)
 189     , m_synchedWindowState(Qt::WindowActive)
 190     , m_windowModality(Qt::NonModal)
 191     , m_inConstructor(true)
 192     , m_glContext(0)
 193     , m_menubar(0)
 194     , m_hasModalSession(false)
 195     , m_frameStrutEventsEnabled(false)
 196 {
 197 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 198     qDebug() << "QCocoaWindow::QCocoaWindow" << this;
 199 #endif
 200     QCocoaAutoReleasePool pool;
 201
 202     m_contentView = [[QNSView alloc] initWithQWindow:tlw platformWindow:this];
 203     setGeometry(tlw->geometry());
 204
 205     recreateWindow(parent());
 206
 207     m_inConstructor = false;
 208 }
 209
 210 QCocoaWindow::~QCocoaWindow()
 211 {
 212 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 213     qDebug() << "QCocoaWindow::~QCocoaWindow" << this;
 214 #endif
 215
 216     QCocoaAutoReleasePool pool;
 217     clearNSWindow(m_nsWindow);
 218     [m_contentView release];
 219     [m_nsWindow release];
 220 }
 221
 222 void QCocoaWindow::setGeometry(const QRect &rect)
 223 {
 224     if (geometry() == rect)
 225         return;
 226 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 227     qDebug() << "QCocoaWindow::setGeometry" << this << rect;
 228 #endif
 229     QPlatformWindow::setGeometry(rect);
 230     setCocoaGeometry(rect);
 231 }
 232
 233 void QCocoaWindow::setCocoaGeometry(const QRect &rect)
 234 {
 235     QCocoaAutoReleasePool pool;
 236     if (m_nsWindow) {
 237         NSRect bounds = qt_mac_flipRect(rect, window());
 238         [m_nsWindow setContentSize : bounds.size];
 239         [m_nsWindow setFrameOrigin : bounds.origin];
 240     } else {
 241         [m_contentView setFrame : NSMakeRect(rect.x(), rect.y(), rect.width(), rect.height())];
 242     }
 243 }
 244
 245 void QCocoaWindow::setVisible(bool visible)
 246 {
 247     QCocoaAutoReleasePool pool;
 248 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 249     qDebug() << "QCocoaWindow::setVisible" << window() << visible;
 250 #endif
 251     if (visible) {
 252         // We need to recreate if the modality has changed as the style mask will need updating
 253         if (m_windowModality != window()->windowModality())
 254             recreateWindow(parent());
 255         QCocoaWindow *parentCocoaWindow = 0;
 256         if (window()->transientParent()) {
 257             parentCocoaWindow = static_cast<QCocoaWindow *>(window()->transientParent()->handle());
 258
 259             // The parent window might have moved while this window was hidden,
 260             // update the window geometry if there is a parent.
 261             setGeometry(window()->geometry());
 262
 263             // Register popup windows so that the parent window can
 264             // close them when needed.
 265             if (window()->windowType() == Qt::Popup) {
 266                 // qDebug() << "transientParent and popup" << window()->windowType() << Qt::Popup << (window()->windowType() & Qt::Popup);
 267                 parentCocoaWindow->m_activePopupWindow = window();
 268             }
 269
 270         }
 271
 272         // Make sure the QWindow has a frame ready before we show the NSWindow.
 273         QWindowSystemInterface::handleExposeEvent(window(), QRect(QPoint(), geometry().size()));
 274         QWindowSystemInterface::flushWindowSystemEvents();
 275
 276         if (m_nsWindow) {
 277             // setWindowState might have been called while the window was hidden and
 278             // will not change the NSWindow state in that case. Sync up here:
 279             syncWindowState(window()->windowState());
 280
 281             if (window()->windowState() != Qt::WindowMinimized) {
 282                 if ((window()->windowModality() == Qt::WindowModal
 283                      || window()->windowType() == Qt::Sheet)
 284                         && parentCocoaWindow) {
 285                     // show the window as a sheet
 286                     [NSApp beginSheet:m_nsWindow modalForWindow:parentCocoaWindow->m_nsWindow modalDelegate:nil didEndSelector:nil contextInfo:nil];
 287                 } else if (window()->windowModality() != Qt::NonModal) {
 288                     // show the window as application modal
 289                     QCocoaEventDispatcher *cocoaEventDispatcher = qobject_cast<QCocoaEventDispatcher *>(QGuiApplication::instance()->eventDispatcher());
 290                     Q_ASSERT(cocoaEventDispatcher != 0);
 291                     QCocoaEventDispatcherPrivate *cocoaEventDispatcherPrivate = static_cast<QCocoaEventDispatcherPrivate *>(QObjectPrivate::get(cocoaEventDispatcher));
 292                     cocoaEventDispatcherPrivate->beginModalSession(window());
 293                     m_hasModalSession = true;
 294                 } else if ([m_nsWindow canBecomeKeyWindow]) {
 295                     [m_nsWindow makeKeyAndOrderFront:nil];
 296                 } else {
 297                     [m_nsWindow orderFront: nil];
 298                 }
 299
 300                 // We want the events to properly reach the popup
 301                 if (window()->windowType() == Qt::Popup)
 302                     [(NSPanel *)m_nsWindow setWorksWhenModal:YES];
 303             }
 304         }
 305     } else {
 306         // qDebug() << "close" << this;
 307         if (m_nsWindow) {
 308             if (m_hasModalSession) {
 309                 QCocoaEventDispatcher *cocoaEventDispatcher = qobject_cast<QCocoaEventDispatcher *>(QGuiApplication::instance()->eventDispatcher());
 310                 Q_ASSERT(cocoaEventDispatcher != 0);
 311                 QCocoaEventDispatcherPrivate *cocoaEventDispatcherPrivate = static_cast<QCocoaEventDispatcherPrivate *>(QObjectPrivate::get(cocoaEventDispatcher));
 312                 cocoaEventDispatcherPrivate->endModalSession(window());
 313                 m_hasModalSession = false;
 314             } else {
 315                 if ([m_nsWindow isSheet])
 316                     [NSApp endSheet:m_nsWindow];
 317             }
 318             [m_nsWindow orderOut:m_nsWindow];
 319         }
 320         if (!QCoreApplication::closingDown())
 321             QWindowSystemInterface::handleExposeEvent(window(), QRegion());
 322     }
 323 }
 324
 325 NSInteger QCocoaWindow::windowLevel(Qt::WindowFlags flags)
 326 {
 327     Qt::WindowType type = static_cast<Qt::WindowType>(int(flags & Qt::WindowType_Mask));
 328
 329     NSInteger windowLevel = NSNormalWindowLevel;
 330
 331     if (type == Qt::Tool)
 332         windowLevel = NSFloatingWindowLevel;
 333     else if ((type & Qt::Popup) == Qt::Popup)
 334         windowLevel = NSPopUpMenuWindowLevel;
 335
 336     // StayOnTop window should appear above Tool windows.
 337     if (flags & Qt::WindowStaysOnTopHint)
 338         windowLevel = NSPopUpMenuWindowLevel;
 339     // Tooltips should appear above StayOnTop windows.
 340     if (type == Qt::ToolTip)
 341         windowLevel = NSScreenSaverWindowLevel;
 342
 343     // A window should be in at least the same level as its parent.
 344     const QWindow * const transientParent = window()->transientParent();
 345     const QCocoaWindow * const transientParentWindow = transientParent ? static_cast<QCocoaWindow *>(transientParent->handle()) : 0;
 346     if (transientParentWindow)
 347         windowLevel = qMax([transientParentWindow->m_nsWindow level], windowLevel);
 348
 349     return windowLevel;
 350 }
 351
 352 NSUInteger QCocoaWindow::windowStyleMask(Qt::WindowFlags flags)
 353 {
 354     Qt::WindowType type = static_cast<Qt::WindowType>(int(flags & Qt::WindowType_Mask));
 355     NSInteger styleMask = NSBorderlessWindowMask;
 356
 357     if ((type & Qt::Popup) == Qt::Popup) {
 358         if (!windowIsPopupType(type))
 359             styleMask = (NSUtilityWindowMask | NSResizableWindowMask | NSClosableWindowMask |
 360                          NSMiniaturizableWindowMask | NSTitledWindowMask);
 361     } else {
 362         // Filter flags for supported properties
 363         flags &= Qt::WindowType_Mask | Qt::FramelessWindowHint | Qt::WindowTitleHint |
 364                  Qt::WindowMinMaxButtonsHint | Qt::WindowCloseButtonHint;
 365         if (flags == Qt::Window) {
 366             styleMask = (NSResizableWindowMask | NSClosableWindowMask | NSMiniaturizableWindowMask | NSTitledWindowMask);
 367         } else if ((flags & Qt::Dialog) && (window()->windowModality() != Qt::NonModal)) {
 368             styleMask = NSTitledWindowMask;
 369         } else if (!(flags & Qt::FramelessWindowHint)) {
 370             if (flags & Qt::WindowMaximizeButtonHint)
 371                 styleMask |= NSResizableWindowMask;
 372             if (flags & Qt::WindowTitleHint)
 373                 styleMask |= NSTitledWindowMask;
 374             if (flags & Qt::WindowCloseButtonHint)
 375                 styleMask |= NSClosableWindowMask;
 376             if (flags & Qt::WindowMinimizeButtonHint)
 377                 styleMask |= NSMiniaturizableWindowMask;
 378         }
 379     }
 380
 381     return styleMask;
 382 }
 383
 384 void QCocoaWindow::setWindowShadow(Qt::WindowFlags flags)
 385 {
 386     bool keepShadow = !(flags & Qt::NoDropShadowWindowHint);
 387     [m_nsWindow setHasShadow:(keepShadow ? YES : NO)];
 388 }
 389
 390 void QCocoaWindow::setWindowFlags(Qt::WindowFlags flags)
 391 {
 392     if (m_nsWindow) {
 393         NSUInteger styleMask = windowStyleMask(flags);
 394         NSInteger level = this->windowLevel(flags);
 395         [m_nsWindow setStyleMask:styleMask];
 396         [m_nsWindow setLevel:level];
 397         setWindowShadow(flags);
 398     }
 399
 400     m_windowFlags = flags;
 401 }
 402
 403 Qt::WindowState QCocoaWindow::setWindowState(Qt::WindowState state)
 404 {
 405     if ([m_nsWindow isVisible])
 406         syncWindowState(state);  // Window state set for hidden windows take effect when show() is called.
 407
 408     return state;
 409 }
 410
 411 void QCocoaWindow::setWindowTitle(const QString &title)
 412 {
 413     QCocoaAutoReleasePool pool;
 414     if (!m_nsWindow)
 415         return;
 416
 417     CFStringRef windowTitle = QCFString::toCFStringRef(title);
 418     [m_nsWindow setTitle: const_cast<NSString *>(reinterpret_cast<const NSString *>(windowTitle))];
 419     CFRelease(windowTitle);
 420 }
 421
 422 void QCocoaWindow::setWindowFilePath(const QString &filePath)
 423 {
 424     QCocoaAutoReleasePool pool;
 425     if (!m_nsWindow)
 426         return;
 427
 428     QFileInfo fi(filePath);
 429     [m_nsWindow setRepresentedFilename: fi.exists() ? QCFString::toNSString(filePath) : @""];
 430 }
 431
 432 void QCocoaWindow::setWindowIcon(const QIcon &icon)
 433 {
 434     QCocoaAutoReleasePool pool;
 435
 436     NSButton *iconButton = [m_nsWindow standardWindowButton:NSWindowDocumentIconButton];
 437     if (iconButton == nil) {
 438         NSString *title = QCFString::toNSString(window()->windowTitle());
 439         [m_nsWindow setRepresentedURL:[NSURL fileURLWithPath:title]];
 440         iconButton = [m_nsWindow standardWindowButton:NSWindowDocumentIconButton];
 441     }
 442     if (icon.isNull()) {
 443         [iconButton setImage:nil];
 444     } else {
 445         QPixmap pixmap = icon.pixmap(QSize(22, 22));
 446         NSImage *image = static_cast<NSImage *>(qt_mac_create_nsimage(pixmap));
 447         [iconButton setImage:image];
 448         [image release];
 449     }
 450 }
 451
 452 void QCocoaWindow::raise()
 453 {
 454     //qDebug() << "raise" << this;
 455     // ### handle spaces (see Qt 4 raise_sys in qwidget_mac.mm)
 456     if (!m_nsWindow)
 457         return;
 458     if ([m_nsWindow isVisible])
 459         [m_nsWindow orderFront: m_nsWindow];
 460 }
 461
 462 void QCocoaWindow::lower()
 463 {
 464     if (!m_nsWindow)
 465         return;
 466     if ([m_nsWindow isVisible])
 467         [m_nsWindow orderBack: m_nsWindow];
 468 }
 469
 470 void QCocoaWindow::propagateSizeHints()
 471 {
 472     QCocoaAutoReleasePool pool;
 473     if (!m_nsWindow)
 474         return;
 475
 476 #ifdef QT_COCOA_ENABLE_WINDOW_DEBUG
 477     qDebug() << "QCocoaWindow::propagateSizeHints" << this;
 478     qDebug() << "     min/max " << window()->minimumSize() << window()->maximumSize();
 479     qDebug() << "size increment" << window()->sizeIncrement();
 480     qDebug() << "     basesize" << window()->baseSize();
 481     qDebug() << "     geometry" << geometry();
 482 #endif
 483
 484     // Set the minimum content size.
 485     const QSize minimumSize = window()->minimumSize();
 486     if (!minimumSize.isValid()) // minimumSize is (-1, -1) when not set. Make that (0, 0) for Cocoa.
 487         [m_nsWindow setContentMinSize : NSMakeSize(0.0, 0.0)];
 488     [m_nsWindow setContentMinSize : NSMakeSize(minimumSize.width(), minimumSize.height())];
 489
 490     // Set the maximum content size.
 491     const QSize maximumSize = window()->maximumSize();
 492     [m_nsWindow setContentMaxSize : NSMakeSize(maximumSize.width(), maximumSize.height())];
 493
 494     // sizeIncrement is observed to take values of (-1, -1) and (0, 0) for windows that should be
 495     // resizable and that have no specific size increment set. Cocoa expects (1.0, 1.0) in this case.
 496     if (!window()->sizeIncrement().isEmpty())
 497         [m_nsWindow setResizeIncrements : qt_mac_toNSSize(window()->sizeIncrement())];
 498     else
 499         [m_nsWindow setResizeIncrements : NSMakeSize(1.0, 1.0)];
 500
 501     QRect rect = geometry();
 502     QSize baseSize = window()->baseSize();
 503     if (!baseSize.isNull() && baseSize.isValid()) {
 504         [m_nsWindow setFrame:NSMakeRect(rect.x(), rect.y(), baseSize.width(), baseSize.height()) display:YES];
 505     }
 506 }
 507
 508 void QCocoaWindow::setOpacity(qreal level)
 509 {
 510     if (m_nsWindow)
 511         [m_nsWindow setAlphaValue:level];
 512 }
 513
 514 bool QCocoaWindow::setKeyboardGrabEnabled(bool grab)
 515 {
 516     if (!m_nsWindow)
 517         return false;
 518
 519     if (grab && ![m_nsWindow isKeyWindow])
 520         [m_nsWindow makeKeyWindow];
 521     else if (!grab && [m_nsWindow isKeyWindow])
 522         [m_nsWindow resignKeyWindow];
 523     return true;
 524 }
 525
 526 bool QCocoaWindow::setMouseGrabEnabled(bool grab)
 527 {
 528     if (!m_nsWindow)
 529         return false;
 530
 531     if (grab && ![m_nsWindow isKeyWindow])
 532         [m_nsWindow makeKeyWindow];
 533     else if (!grab && [m_nsWindow isKeyWindow])
 534         [m_nsWindow resignKeyWindow];
 535     return true;
 536 }
 537
 538 WId QCocoaWindow::winId() const
 539 {
 540     return WId(m_contentView);
 541 }
 542
 543 void QCocoaWindow::setParent(const QPlatformWindow *parentWindow)
 544 {
 545     // recreate the window for compatibility
 546     recreateWindow(parentWindow);
 547     setCocoaGeometry(geometry());
 548 }
 549
 550 NSView *QCocoaWindow::contentView() const
 551 {
 552     return m_contentView;
 553 }
 554
 555 void QCocoaWindow::windowWillMove()
 556 {
 557     // Close any open popups on window move
 558     if (m_activePopupWindow) {
 559         QWindowSystemInterface::handleCloseEvent(m_activePopupWindow);
 560         QWindowSystemInterface::flushWindowSystemEvents();
 561         m_activePopupWindow = 0;
 562     }
 563 }
 564
 565 void QCocoaWindow::windowDidMove()
 566 {
 567     [m_contentView updateGeometry];
 568 }
 569
 570 void QCocoaWindow::windowDidResize()
 571 {
 572     if (!m_nsWindow)
 573         return;
 574
 575     NSRect rect = [[m_nsWindow contentView]frame];
 576     // Call setFrameSize which will trigger a frameDidChangeNotification on QNSView.
 577     [[m_nsWindow contentView] setFrameSize:rect.size];
 578 }
 579
 580 void QCocoaWindow::windowWillClose()
 581 {
 582     QWindowSystemInterface::handleCloseEvent(window());
 583     QWindowSystemInterface::flushWindowSystemEvents();
 584 }
 585
 586 bool QCocoaWindow::windowIsPopupType(Qt::WindowType type) const
 587 {
 588     if (type == Qt::Widget)
 589         type = window()->windowType();
 590     if (type == Qt::Tool)
 591         return false; // Qt::Tool has the Popup bit set but isn't, at least on Mac.
 592
 593     return ((type & Qt::Popup) == Qt::Popup);
 594 }
 595
 596 void QCocoaWindow::setCurrentContext(QCocoaGLContext *context)
 597 {
 598     m_glContext = context;
 599 }
 600
 601 QCocoaGLContext *QCocoaWindow::currentContext() const
 602 {
 603     return m_glContext;
 604 }
 605
 606 void QCocoaWindow::recreateWindow(const QPlatformWindow *parentWindow)
 607 {
 608     // Remove current window (if any)
 609     if (m_nsWindow) {
 610         clearNSWindow(m_nsWindow);
 611         [m_nsWindow close];
 612         [m_nsWindow release];
 613         m_nsWindow = 0;
 614     }
 615
 616     if (!parentWindow) {
 617         // Create a new NSWindow if this is a top-level window.
 618         m_nsWindow = createNSWindow();
 619         setNSWindow(m_nsWindow);
 620
 621         // QPlatformWindow subclasses must sync up with QWindow on creation:
 622         propagateSizeHints();
 623         setWindowFlags(window()->windowFlags());
 624         setWindowTitle(window()->windowTitle());
 625         setWindowState(window()->windowState());
 626     } else {
 627         // Child windows have no NSWindow, link the NSViews instead.
 628         const QCocoaWindow *parentCococaWindow = static_cast<const QCocoaWindow *>(parentWindow);
 629         [parentCococaWindow->m_contentView addSubview : m_contentView];
 630     }
 631 }
 632
 633 NSWindow * QCocoaWindow::createNSWindow()
 634 {
 635     QCocoaAutoReleasePool pool;
 636
 637     NSRect frame = qt_mac_flipRect(window()->geometry(), window());
 638
 639     Qt::WindowType type = window()->windowType();
 640     Qt::WindowFlags flags = window()->windowFlags();
 641
 642     NSUInteger styleMask = windowStyleMask(flags);
 643     NSWindow *createdWindow = 0;
 644
 645     // Use NSPanel for popup-type windows. (Popup, Tool, ToolTip, SplashScreen)
 646     if ((type & Qt::Popup) == Qt::Popup) {
 647         QNSPanel *window;
 648         window  = [[QNSPanel alloc] initWithContentRect:frame
 649                                          styleMask: styleMask
 650                                          backing:NSBackingStoreBuffered
 651                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 652                                                     // before the window is shown and needs a proper window.).
 653         [window setHasShadow:YES];
 654
 655 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
 656         if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
 657             // Make popup winows show on the same desktop as the parent full-screen window.
 658             [window setCollectionBehavior:NSWindowCollectionBehaviorFullScreenAuxiliary];
 659         }
 660 #endif
 661         window->m_cocoaPlatformWindow = this;
 662         createdWindow = window;
 663     } else {
 664         QNSWindow *window;
 665         window  = [[QNSWindow alloc] initWithContentRect:frame
 666                                          styleMask: styleMask
 667                                          backing:NSBackingStoreBuffered
 668                                          defer:NO]; // Deferring window creation breaks OpenGL (the GL context is set up
 669                                                     // before the window is shown and needs a proper window.).
 670         window->m_cocoaPlatformWindow = this;
 671         setWindowShadow(flags);
 672
 673 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
 674     if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
 675         // All windows with the WindowMaximizeButtonHint set also get a full-screen button.
 676         if (flags & Qt::WindowMaximizeButtonHint)
 677             [window setCollectionBehavior:NSWindowCollectionBehaviorFullScreenPrimary];
 678     }
 679 #endif
 680
 681         createdWindow = window;
 682     }
 683
 684     NSInteger level = windowLevel(flags);
 685     [createdWindow setLevel:level];
 686     m_windowModality = window()->windowModality();
 687     return createdWindow;
 688 }
 689
 690 void QCocoaWindow::setNSWindow(NSWindow *window)
 691 {
 692     QNSWindowDelegate *delegate = [[QNSWindowDelegate alloc] initWithQCocoaWindow:this];
 693     [window setDelegate:delegate];
 694     [window setAcceptsMouseMovedEvents:YES];
 695
 696     // Prevent Cocoa from releasing the window on close. Qt
 697     // handles the close event asynchronously and we want to
 698     // make sure that m_nsWindow stays valid until the
 699     // QCocoaWindow is deleted by Qt.
 700     [window setReleasedWhenClosed : NO];
 701
 702
 703     [[NSNotificationCenter defaultCenter] addObserver:m_contentView
 704                                           selector:@selector(windowNotification:)
 705                                           name:nil // Get all notifications
 706                                           object:m_nsWindow];
 707
 708     // ### Accept touch events by default.
 709     // Beware that enabling touch events has a negative impact on the overall performance.
 710     // We probably need a QWindowSystemInterface API to enable/disable touch events.
 711     [m_contentView setAcceptsTouchEvents:YES];
 712
 713     [window setContentView:m_contentView];
 714 }
 715
 716 void QCocoaWindow::clearNSWindow(NSWindow *window)
 717 {
 718     [window setDelegate:nil];
 719     [window clearPlatformWindow];
 720     [[NSNotificationCenter defaultCenter] removeObserver:m_contentView];
 721 }
 722
 723 // Returns the current global screen geometry for the nswindow associated with this window.
 724 QRect QCocoaWindow::windowGeometry() const
 725 {
 726     if (!m_nsWindow)
 727         return geometry();
 728
 729     NSRect rect = [m_nsWindow frame];
 730     QPlatformScreen *onScreen = QPlatformScreen::platformScreenForWindow(window());
 731     int flippedY = onScreen->geometry().height() - rect.origin.y - rect.size.height;  // account for nswindow inverted y.
 732     QRect qRect = QRect(rect.origin.x, flippedY, rect.size.width, rect.size.height);
 733     return qRect;
 734 }
 735
 736 // Returns a pointer to the parent QCocoaWindow for this window, or 0 if there is none.
 737 QCocoaWindow *QCocoaWindow::parentCocoaWindow() const
 738 {
 739     if (window() && window()->transientParent()) {
 740         return static_cast<QCocoaWindow*>(window()->transientParent()->handle());
 741     }
 742     return 0;
 743 }
 744
 745 // Syncs the NSWindow minimize/maximize/fullscreen state with the current QWindow state
 746 void QCocoaWindow::syncWindowState(Qt::WindowState newState)
 747 {
 748     if (!m_nsWindow)
 749         return;
 750
 751     // if content view width or height is 0 then the window animations will crash so
 752     // do nothing except set the new state
 753     NSRect contentRect = [contentView() frame];
 754     if (contentRect.size.width <= 0 || contentRect.size.height <= 0) {
 755         qWarning() << Q_FUNC_INFO << "invalid window content view size, check your window geometry";
 756         m_synchedWindowState = newState;
 757         return;
 758     }
 759
 760     if ((m_synchedWindowState & Qt::WindowMaximized) != (newState & Qt::WindowMaximized)) {
 761         [m_nsWindow performZoom : m_nsWindow]; // toggles
 762     }
 763
 764     if ((m_synchedWindowState & Qt::WindowMinimized) != (newState & Qt::WindowMinimized)) {
 765         if (newState & Qt::WindowMinimized) {
 766             [m_nsWindow performMiniaturize : m_nsWindow];
 767         } else {
 768             [m_nsWindow deminiaturize : m_nsWindow];
 769         }
 770     }
 771
 772     if ((m_synchedWindowState & Qt::WindowFullScreen) != (newState & Qt::WindowFullScreen)) {
 773 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
 774         if (QSysInfo::QSysInfo::MacintoshVersion >= QSysInfo::MV_10_7) {
 775             [m_nsWindow toggleFullScreen : m_nsWindow];
 776         } else {
 777             // TODO: "normal" fullscreen
 778         }
 779 #endif
 780     }
 781
 782     // New state is now the current synched state
 783     m_synchedWindowState = newState;
 784 }
 785
 786 bool QCocoaWindow::setWindowModified(bool modified)
 787 {
 788     if (!m_nsWindow)
 789         return false;
 790     [m_nsWindow setDocumentEdited:(modified?YES:NO)];
 791     return true;
 792 }
 793
 794 void QCocoaWindow::setMenubar(QCocoaMenuBar *mb)
 795 {
 796     m_menubar = mb;
 797 }
 798
 799 QCocoaMenuBar *QCocoaWindow::menubar() const
 800 {
 801     return m_menubar;
 802 }
 803
 804 QMargins QCocoaWindow::frameMargins() const
 805 {
 806     NSRect frameW = [m_nsWindow frame];
 807     NSRect frameC = [m_nsWindow contentRectForFrameRect:frameW];
 808
 809     return QMargins(frameW.origin.x - frameC.origin.x,
 810         (frameW.origin.y + frameW.size.height) - (frameC.origin.y + frameC.size.height),
 811         (frameW.origin.x + frameW.size.width) - (frameC.origin.x + frameC.size.width),
 812         frameC.origin.y - frameW.origin.y);
 813 }
 814
 815 void QCocoaWindow::setFrameStrutEventsEnabled(bool enabled)
 816 {
 817     m_frameStrutEventsEnabled = enabled;
 818 }