src/meson.build

   1 libds_tizen_files = [
   2 ]
   3
   4 math = meson.get_compiler('c').find_library('m')
   5 wayland_server = dependency('wayland-server', required: true)
   6 rt = meson.get_compiler('c').find_library('rt')
   7 xkbcommon = dependency('xkbcommon', required: true)
   8
   9 if wayland_server.version().version_compare('>= 1.19')
  10   cdata.set('HAVE_WL_SEAT_ERROR_MISSING_CAPABILITY', '1')
  11 endif
  12
  13 base_deps = [
  14   math,
  15   wayland_server,
  16   xkbcommon,
  17   rt,
  18 ]
  19
  20 libds_tizen_deps = [
  21   base_deps,
  22   dependency('libds', required: true),
  23 ]
  24
  25 subdir('util')
  26
  27 lib_libds_tizen = shared_library('ds-tizen', libds_tizen_files,
  28   dependencies: libds_tizen_deps,
  29   include_directories: [ common_inc, include_directories('.') ],
  30   version: meson.project_version(),
  31   install: true
  32 )
  33
  34 dep_libds_tizen = declare_dependency(
  35   link_with: lib_libds_tizen,
  36   dependencies: libds_tizen_deps,
  37   include_directories: [ common_inc, include_directories('.') ],
  38 )
  39
  40 pkgconfig = import('pkgconfig')
  41 pkgconfig.generate(lib_libds_tizen,
  42   version: meson.project_version(),
  43   filebase: 'libds-tizen',
  44   name: 'libds-tizen',
  45   description: 'extension of libds for tizen platform',
  46 )
  47
  48 subdir('allocator')
  49 subdir('tbm-server')
  50 subdir('backend')
  51 subdir('keyrouter')
  52 subdir('input-devicemgr')
  53 subdir('dpms')