src/meson.build

   1 libds_tizen_files = [
   2   'pixel_format.c',
   3   'tbm_server.c',
   4   'dpms.c',
   5 ]
   6
   7 math = meson.get_compiler('c').find_library('m')
   8 wayland_server = dependency('wayland-server', required: true)
   9 pixman = dependency('pixman-1', required: true)
  10 libdrm = dependency('libdrm', required: true)
  11 xkbcommon = dependency('xkbcommon', required: true)
  12 rt = meson.get_compiler('c').find_library('rt')
  13
  14 if wayland_server.version().version_compare('>= 1.19')
  15   cdata.set('HAVE_WL_SEAT_ERROR_MISSING_CAPABILITY', '1')
  16 endif
  17
  18 base_deps = [
  19   math,
  20   wayland_server,
  21   pixman,
  22   libdrm,
  23   xkbcommon,
  24   rt,
  25 ]
  26
  27 libds_tizen_deps = [
  28   base_deps,
  29   dependency('libds', required: true),
  30   dependency('libdrm', required: true),
  31   dependency('libtbm', required: true),
  32   dependency('wayland-tbm-server', required: true),
  33   dependency('tizen-dpms-server', required: true),
  34 ]
  35
  36 subdir('allocator')
  37 subdir('util')
  38
  39 lib_libds_tizen = shared_library('ds-tizen', libds_tizen_files,
  40   dependencies: libds_tizen_deps,
  41   include_directories: [ common_inc, include_directories('.') ],
  42   version: meson.project_version(),
  43   install: true
  44 )
  45
  46 dep_libds_tizen = declare_dependency(
  47   link_with: lib_libds_tizen,
  48   dependencies: libds_tizen_deps,
  49   include_directories: [ common_inc, include_directories('.') ],
  50 )
  51
  52 pkgconfig = import('pkgconfig')
  53 pkgconfig.generate(lib_libds_tizen,
  54   version: meson.project_version(),
  55   filebase: 'libds-tizen',
  56   name: 'libds-tizen',
  57   description: 'extension of libds for tizen platform',
  58 )
  59
  60 subdir('backend')
  61 subdir('keyrouter')
  62 subdir('input-devicemgr')