src/meson.build

   1 # Copyright © 2017 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21 inc_mesa = include_directories('mesa')
  22 inc_mapi = include_directories('mapi')
  23 inc_src = include_directories('.')
  24 inc_gallium = include_directories('gallium/include')
  25 inc_gallium_aux = include_directories('gallium/auxiliary')
  26 inc_amd_common = include_directories('amd/common')
  27 inc_tool = include_directories('tool')
  28 inc_virtio_gpu = include_directories('virtio/virtio-gpu')
  29 inc_frontends = include_directories('gallium/frontends')
  30 pps_datasources = []
  31 pps_includes = []
  32
  33 if with_llvm
  34   inc_amd_common_llvm = include_directories('amd/llvm')
  35 else
  36   inc_amd_common_llvm = []
  37 endif
  38
  39 libglsl_util = static_library(
  40   'glsl_util',
  41   files(
  42     'mesa/main/extensions_table.c',
  43     'mesa/program/prog_parameter.c',
  44     'mesa/program/symbol_table.c',
  45     'mesa/program/dummy_errors.c',
  46   ),
  47   include_directories : [inc_include, inc_src, inc_mapi, inc_mesa, inc_gallium, inc_gallium_aux],
  48   dependencies : dep_valgrind,
  49   gnu_symbol_visibility : 'hidden',
  50   build_by_default : false,
  51 )
  52
  53 sha1_h = custom_target(
  54   'git_sha1.h',
  55   output : 'git_sha1.h',
  56   command : [prog_python, git_sha1_gen_py, '--output', '@OUTPUT@'],
  57   build_by_default : true,
  58   build_always_stale : true, # commit sha1 can change without having touched these files
  59 )
  60
  61 subdir('gtest')
  62 if cc.get_argument_syntax() == 'msvc'
  63   subdir('getopt')
  64 else
  65   idep_getopt = null_dep
  66 endif
  67 subdir('android_stub')
  68 subdir('c11/impl')
  69 subdir('util')
  70 subdir('mapi')
  71 # TODO: opengl
  72 subdir('compiler')
  73 if with_tools.contains('drm-shim')
  74   subdir('drm-shim')
  75 endif
  76 if with_imgui
  77   subdir('imgui')
  78 endif
  79 if with_platform_wayland
  80   subdir('egl/wayland/wayland-drm')
  81 endif
  82 if with_any_vk or with_gallium_zink
  83   subdir('vulkan')
  84 endif
  85 if with_any_intel
  86   subdir('intel')
  87 endif
  88 if with_gallium_radeonsi or with_amd_vk or with_gallium_r300 or with_gallium_r600
  89   subdir('amd')
  90 endif
  91 if with_any_broadcom
  92   subdir('broadcom')
  93 endif
  94 if with_gallium_etnaviv
  95   subdir('etnaviv')
  96 endif
  97 if with_gallium_freedreno or with_freedreno_vk or with_tools.contains('freedreno')
  98   subdir('freedreno')
  99 endif
 100 if with_imagination_vk
 101   subdir('imagination')
 102 endif
 103 if with_gallium_panfrost or with_gallium_lima or with_panfrost_vk or with_tools.contains('panfrost')
 104   subdir('panfrost')
 105 endif
 106 if with_gallium_virgl or with_virtio_vk
 107   subdir('virtio')
 108 endif
 109 if with_microsoft_clc or with_gallium_d3d12 or with_spirv_to_dxil or with_microsoft_vk
 110   subdir('microsoft')
 111 endif
 112 if with_gallium_nouveau
 113   subdir('nouveau')
 114 endif
 115 if with_gallium_asahi or with_tools.contains('asahi')
 116   subdir('asahi')
 117 endif
 118 subdir('loader')
 119 if with_platform_haiku
 120   subdir('hgl')
 121 endif
 122 if with_gbm
 123   subdir('gbm')
 124 else
 125   inc_gbm = []
 126 endif
 127 if with_gallium
 128   subdir('mesa')
 129   subdir('gallium')
 130   if with_glx == 'dri'
 131      subdir('glx')
 132   endif
 133   # This has to be here since it requires libgallium, and subdir cannot
 134   # contain ..
 135   if with_tests
 136     subdir('mesa/main/tests')
 137   endif
 138   if with_tests and with_shared_glapi
 139     subdir('mesa/state_tracker/tests')
 140   endif
 141 endif
 142 if with_egl
 143   subdir('egl')
 144 endif
 145
 146 # This must be after at least mesa, glx, and gallium, since libgl will be
 147 # defined in one of those subdirs depending on the glx provider.
 148 if with_glx != 'disabled' and not with_glvnd
 149   pkg.generate(
 150     name : 'gl',
 151     description : 'Mesa OpenGL Library',
 152     version : meson.project_version(),
 153     libraries : libgl,
 154     libraries_private : gl_priv_libs,
 155     requires_private : gl_priv_reqs,
 156     variables : ['glx_tls=yes'],
 157   )
 158 endif
 159
 160 subdir('tool')