src/lib/ecore_audio/meson.build

   1 ecore_audio_deps = [ecore]
   2 ecore_audio_pub_deps = [eina, eo]
   3
   4 pub_eo_files = [
   5   'ecore_audio.eo',
   6   'ecore_audio_in.eo',
   7   'ecore_audio_out.eo',
   8   'ecore_audio_in_sndfile.eo',
   9   'ecore_audio_out_sndfile.eo',
  10   'ecore_audio_out_pulse.eo',
  11   'ecore_audio_in_tone.eo',
  12   'ecore_audio_out_wasapi.eo'
  13 ]
  14
  15 foreach eo_file : pub_eo_files
  16   pub_eo_file_target += custom_target('eolian_gen_' + eo_file,
  17     input : eo_file,
  18     output : [eo_file + '.h'],
  19     depfile : eo_file + '.d',
  20     install : true,
  21     install_dir : dir_package_include,
  22     command : eolian_gen + [ '-I', meson.current_source_dir(), eolian_include_directories,
  23                            '-o', 'h:' + join_paths(meson.current_build_dir(), eo_file + '.h'),
  24                            '-o', 'c:' + join_paths(meson.current_build_dir(), eo_file + '.c'),
  25                            '-o', 'd:' + join_paths(meson.current_build_dir(), eo_file + '.d'),
  26                            '-gchd', '@INPUT@'])
  27 endforeach
  28
  29 pub_eo_types_files = []
  30
  31 ecore_audio_header_src = [
  32   'Ecore_Audio.h',
  33   'ecore_audio_obj.h',
  34   'ecore_audio_obj_in.h',
  35   'ecore_audio_obj_out.h',
  36   'ecore_audio_obj_in_tone.h',
  37   'ecore_audio_protected.h',
  38   'ecore_audio_obj_out_pulse.h',
  39   'ecore_audio_obj_in_sndfile.h',
  40   'ecore_audio_obj_out_sndfile.h',
  41   'ecore_audio_obj_out_wasapi.h'
  42 ]
  43
  44 ecore_audio_src = [
  45   'ecore_audio.c',
  46   'ecore_audio_obj.c',
  47   'ecore_audio_obj_in.c',
  48   'ecore_audio_obj_out.c',
  49   'ecore_audio_obj_in_tone.c',
  50   'ecore_audio_private.h'
  51 ]
  52
  53 ecore_audio_src += [
  54   'ecore_audio_obj_in_sndfile.c',
  55   'ecore_audio_obj_out_sndfile.c',
  56   'ecore_audio_sndfile_vio.c'
  57 ]
  58
  59 ecore_audio_deps += dependency('sndfile')
  60 config_h.set('HAVE_SNDFILE', '1')
  61
  62 if get_option('pulseaudio')
  63   ecore_audio_deps += dependency('libpulse')
  64
  65   ecore_audio_src += [
  66     'ecore_audio_pulse_ml.c',
  67     'ecore_audio_obj_out_pulse.c'
  68   ]
  69
  70   config_h.set('HAVE_PULSE', '1')
  71 endif
  72
  73 if sys_windows == true
  74   ecore_audio_src += [
  75     'ecore_audio_obj_out_wasapi.c'
  76   ]
  77   ecore_audio_deps += [cc.find_library('ksuser', required: true), cc.find_library('winmm', required: true)]
  78 endif
  79
  80 ecore_audio_lib = library('ecore_audio',
  81     ecore_audio_src, pub_eo_file_target,
  82     dependencies: ecore_audio_pub_deps + [m] + ecore_audio_deps,
  83     include_directories : config_dir,
  84     install: true,
  85     version : meson.project_version()
  86 )
  87
  88 ecore_audio = declare_dependency(
  89   include_directories: [include_directories('.')],
  90   link_with: ecore_audio_lib,
  91   sources : pub_eo_file_target + priv_eo_file_target,
  92   dependencies: ecore_audio_pub_deps,
  93 )
  94
  95 install_data(pub_eo_files + pub_eo_types_files,
  96   install_dir: eolian_ecore_dir
  97 )
  98
  99 install_headers(ecore_audio_header_src,
 100   install_dir : dir_package_include,
 101 )