src/imports/testlib/TestCase.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the test suite of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtTest 1.0
  44 import "testlogger.js" as TestLogger
  45
  46 Item {
  47     id: testCase
  48     visible: false
  49     TestUtil {
  50         id:util
  51     }
  52
  53     // Name of the test case to prefix the function name in messages.
  54     property string name
  55
  56     // Set to true to start the test running.
  57     property bool when: true
  58
  59     // Set to true once the test has completed.
  60     property bool completed: false
  61
  62     // Set to true when the test is running but not yet complete.
  63     property bool running: false
  64
  65     // Set to true if the test doesn't have to run (because some
  66     // other test failed which this one depends on).
  67     property bool optional: false
  68
  69     // Property that is set to true when the main window is shown.
  70     // We need to set the property value in an odd way to handle
  71     // both qmlviewer and the QtQuickTest module test wrapper.
  72     property bool windowShown: util.wrapper ? qtest.windowShown : false
  73
  74     // Internal private state.  Identifiers prefixed with qtest are reserved.
  75     property bool qtest_prevWhen: true
  76     property int qtest_testId: -1
  77     property bool qtest_componentCompleted : false
  78     property variant qtest_testCaseResult
  79     property variant qtest_results: qtest_results_normal
  80     TestResult { id: qtest_results_normal }
  81     property variant qtest_events: qtest_events_normal
  82     TestEvent { id: qtest_events_normal }
  83
  84     function fail(msg) {
  85         if (msg === undefined)
  86             msg = "";
  87         qtest_results.fail(msg, util.callerFile(), util.callerLine())
  88         throw new Error("QtQuickTest::fail")
  89     }
  90
  91     function qtest_fail(msg, frame) {
  92         if (msg === undefined)
  93             msg = "";
  94         qtest_results.fail(msg, util.callerFile(frame), util.callerLine(frame))
  95         throw new Error("QtQuickTest::fail")
  96     }
  97
  98     function verify(cond, msg) {
  99         if (msg === undefined)
 100             msg = "";
 101         if (!qtest_results.verify(cond, msg, util.callerFile(), util.callerLine()))
 102             throw new Error("QtQuickTest::fail")
 103     }
 104
 105     // Determine what is o.
 106     // Discussions and reference: http://philrathe.com/articles/equiv
 107     // Test suites: http://philrathe.com/tests/equiv
 108     // Author: Philippe Rathé <prathe@gmail.com>
 109     function qtest_typeof(o) {
 110         if (typeof o === "undefined") {
 111             return "undefined";
 112
 113         // consider: typeof null === object
 114         } else if (o === null) {
 115             return "null";
 116
 117         } else if (o.constructor === String) {
 118             return "string";
 119
 120         } else if (o.constructor === Boolean) {
 121             return "boolean";
 122
 123         } else if (o.constructor === Number) {
 124
 125             if (isNaN(o)) {
 126                 return "nan";
 127             } else {
 128                 return "number";
 129             }
 130         // consider: typeof [] === object
 131         } else if (o instanceof Array) {
 132             return "array";
 133
 134         // consider: typeof new Date() === object
 135         } else if (o instanceof Date) {
 136             return "date";
 137
 138         // consider: /./ instanceof Object;
 139         //           /./ instanceof RegExp;
 140         //          typeof /./ === "function"; // => false in IE and Opera,
 141         //                                          true in FF and Safari
 142         } else if (o instanceof RegExp) {
 143             return "regexp";
 144
 145         } else if (typeof o === "object") {
 146             if ("mapFromItem" in o && "mapToItem" in o) {
 147                 return "declarativeitem";  // @todo improve detection of declarative items
 148             } else if ("x" in o && "y" in o && "z" in o) {
 149                 return "vector3d"; // Qt3D vector
 150             }
 151             return "object";
 152         } else if (o instanceof Function) {
 153             return "function";
 154         } else {
 155             return undefined;
 156         }
 157     }
 158
 159     // Test for equality
 160     // Large parts contain sources from QUnit or http://philrathe.com
 161     // Discussions and reference: http://philrathe.com/articles/equiv
 162     // Test suites: http://philrathe.com/tests/equiv
 163     // Author: Philippe Rathé <prathe@gmail.com>
 164     function qtest_compareInternal(act, exp) {
 165         var success = false;
 166         if (act === exp) {
 167             success = true; // catch the most you can
 168         } else if (act === null || exp === null || typeof act === "undefined" || typeof exp === "undefined") {
 169             success = false; // don't lose time with error prone cases
 170         } else {
 171             var typeExp = qtest_typeof(exp), typeAct = qtest_typeof(act)
 172             if (typeExp !== typeAct) {
 173                 // allow object vs string comparison (e.g. for colors)
 174                 // else break on different types
 175                 if ((typeExp === "string" && (typeAct === "object") || typeAct == "declarativeitem")
 176                  || ((typeExp === "object" || typeExp == "declarativeitem") && typeAct === "string")) {
 177                     success = (act == exp)
 178                 }
 179             } else if (typeExp === "string" || typeExp === "boolean" ||
 180                        typeExp === "null" || typeExp === "undefined") {
 181                 if (exp instanceof act.constructor || act instanceof exp.constructor) {
 182                     // to catch short annotaion VS 'new' annotation of act declaration
 183                     // e.g. var i = 1;
 184                     //      var j = new Number(1);
 185                     success = (act == exp)
 186                 } else {
 187                     success = (act === exp)
 188                 }
 189             } else if (typeExp === "nan") {
 190                 success = isNaN(act);
 191             } else if (typeExp === "number") {
 192                 // Use act fuzzy compare if the two values are floats
 193                 if (Math.abs(act - exp) <= 0.00001) {
 194                     success = true
 195                 }
 196             } else if (typeExp === "array") {
 197                 success = qtest_compareInternalArrays(act, exp)
 198             } else if (typeExp === "object") {
 199                 success = qtest_compareInternalObjects(act, exp)
 200             } else if (typeExp === "declarativeitem") {
 201                 success = qtest_compareInternalObjects(act, exp) // @todo improve comparison of declarative items
 202             } else if (typeExp === "vector3d") {
 203                 success = (Math.abs(act.x - exp.x) <= 0.00001 &&
 204                            Math.abs(act.y - exp.y) <= 0.00001 &&
 205                            Math.abs(act.z - exp.z) <= 0.00001)
 206             } else if (typeExp === "date") {
 207                 success = (act.valueOf() === exp.valueOf())
 208             } else if (typeExp === "regexp") {
 209                 success = (act.source === exp.source && // the regex itself
 210                            act.global === exp.global && // and its modifers (gmi) ...
 211                            act.ignoreCase === exp.ignoreCase &&
 212                            act.multiline === exp.multiline)
 213             }
 214         }
 215         return success
 216     }
 217
 218     function qtest_compareInternalObjects(act, exp) {
 219         var i;
 220         var eq = true; // unless we can proove it
 221         var aProperties = [], bProperties = []; // collection of strings
 222
 223         // comparing constructors is more strict than using instanceof
 224         if (act.constructor !== exp.constructor) {
 225             return false;
 226         }
 227
 228         for (i in act) { // be strict: don't ensures hasOwnProperty and go deep
 229             aProperties.push(i); // collect act's properties
 230             if (!qtest_compareInternal(act[i], exp[i])) {
 231                 eq = false;
 232                 break;
 233             }
 234         }
 235
 236         for (i in exp) {
 237             bProperties.push(i); // collect exp's properties
 238         }
 239
 240         // Ensures identical properties name
 241         return eq && qtest_compareInternal(aProperties.sort(), bProperties.sort());
 242
 243     }
 244
 245     function qtest_compareInternalArrays(actual, expected) {
 246         if (actual.length != expected.length) {
 247             return false
 248         }
 249
 250         for (var i = 0, len = actual.length; i < len; i++) {
 251             if (!qtest_compareInternal(actual[i], expected[i])) {
 252                 return false
 253             }
 254         }
 255
 256         return true
 257     }
 258
 259     function qtest_formatValue(value) {
 260         if (qtest_typeof(value) == "object") {
 261             if ("x" in value && "y" in value && "z" in value) {
 262                 return "Qt.vector3d(" + value.x + ", " +
 263                        value.y + ", " + value.z + ")"
 264             }
 265             try {
 266                 return JSON.stringify(value)
 267             } catch (ex) {
 268                 // stringify might fail (e.g. due to circular references)
 269             }
 270         }
 271         return value
 272     }
 273
 274     function compare(actual, expected, msg) {
 275         var act = testCase.qtest_formatValue(actual)
 276         var exp = testCase.qtest_formatValue(expected)
 277
 278         var success = qtest_compareInternal(actual, expected)
 279         if (msg === undefined) {
 280             if (success)
 281                 msg = "COMPARE()"
 282             else
 283                 msg = "Compared values are not the same"
 284         }
 285         if (!qtest_results.compare(success, msg, act, exp, util.callerFile(), util.callerLine())) {
 286             throw new Error("QtQuickTest::fail")
 287         }
 288     }
 289
 290     function tryCompare(obj, prop, value, timeout) {
 291         if (!timeout)
 292             timeout = 5000
 293         if (!qtest_compareInternal(obj[prop], value))
 294             wait(0)
 295         var i = 0
 296         while (i < timeout && !qtest_compareInternal(obj[prop], value)) {
 297             wait(50)
 298             i += 50
 299         }
 300         var actual = obj[prop]
 301         var act = testCase.qtest_formatValue(actual)
 302         var exp = testCase.qtest_formatValue(value)
 303         var success = qtest_compareInternal(actual, value)
 304         if (!qtest_results.compare(success, "property " + prop, act, exp, util.callerFile(), util.callerLine()))
 305             throw new Error("QtQuickTest::fail")
 306     }
 307
 308     function skip(msg) {
 309         if (msg === undefined)
 310             msg = ""
 311         qtest_results.skip(msg, util.callerFile(), util.callerLine())
 312         throw new Error("QtQuickTest::skip")
 313     }
 314
 315     function skipAll(msg) {
 316         msg = "The skipAll function is no longer available. Please update this test by changing skipAll to skip."
 317         qtest_results.fail(msg, util.callerFile(), util.callerLine())
 318         throw new Error("QtQuickTest::skip")
 319     }
 320
 321     function expectFail(tag, msg) {
 322         if (tag === undefined) {
 323             warn("tag argument missing from expectFail()")
 324             tag = ""
 325         }
 326         if (msg === undefined) {
 327             warn("message argument missing from expectFail()")
 328             msg = ""
 329         }
 330         if (!qtest_results.expectFail(tag, msg, util.callerFile(), util.callerLine()))
 331             throw new Error("QtQuickTest::expectFail")
 332     }
 333
 334     function expectFailContinue(tag, msg) {
 335         if (tag === undefined) {
 336             warn("tag argument missing from expectFailContinue()")
 337             tag = ""
 338         }
 339         if (msg === undefined) {
 340             warn("message argument missing from expectFailContinue()")
 341             msg = ""
 342         }
 343         if (!qtest_results.expectFailContinue(tag, msg, util.callerFile(), util.callerLine()))
 344             throw new Error("QtQuickTest::expectFail")
 345     }
 346
 347     function warn(msg) {
 348         if (msg === undefined)
 349             msg = ""
 350         qtest_results.warn(msg, util.callerFile(), util.callerLine());
 351     }
 352
 353     function ignoreWarning(msg) {
 354         if (msg === undefined)
 355             msg = ""
 356         qtest_results.ignoreWarning(msg)
 357     }
 358
 359     function wait(ms) {
 360         qtest_results.wait(ms)
 361     }
 362
 363     function sleep(ms) {
 364         qtest_results.sleep(ms)
 365     }
 366
 367     function keyPress(key, modifiers, delay) {
 368         if (modifiers === undefined)
 369             modifiers = Qt.NoModifier
 370         if (delay == undefined)
 371             delay = -1
 372         if (!qtest_events.keyPress(key, modifiers, delay))
 373             qtest_fail("window not shown", 2)
 374     }
 375
 376     function keyRelease(key, modifiers, delay) {
 377         if (modifiers === undefined)
 378             modifiers = Qt.NoModifier
 379         if (delay == undefined)
 380             delay = -1
 381         if (!qtest_events.keyRelease(key, modifiers, delay))
 382             qtest_fail("window not shown", 2)
 383     }
 384
 385     function keyClick(key, modifiers, delay) {
 386         if (modifiers === undefined)
 387             modifiers = Qt.NoModifier
 388         if (delay == undefined)
 389             delay = -1
 390         if (!qtest_events.keyClick(key, modifiers, delay))
 391             qtest_fail("window not shown", 2)
 392     }
 393
 394     function mousePress(item, x, y, button, modifiers, delay) {
 395         if (button === undefined)
 396             button = Qt.LeftButton
 397         if (modifiers === undefined)
 398             modifiers = Qt.NoModifier
 399         if (delay == undefined)
 400             delay = -1
 401         if (!qtest_events.mousePress(item, x, y, button, modifiers, delay))
 402             qtest_fail("window not shown", 2)
 403     }
 404
 405     function mouseRelease(item, x, y, button, modifiers, delay) {
 406         if (button === undefined)
 407             button = Qt.LeftButton
 408         if (modifiers === undefined)
 409             modifiers = Qt.NoModifier
 410         if (delay == undefined)
 411             delay = -1
 412         if (!qtest_events.mouseRelease(item, x, y, button, modifiers, delay))
 413             qtest_fail("window not shown", 2)
 414     }
 415
 416     function mouseClick(item, x, y, button, modifiers, delay) {
 417         if (button === undefined)
 418             button = Qt.LeftButton
 419         if (modifiers === undefined)
 420             modifiers = Qt.NoModifier
 421         if (delay == undefined)
 422             delay = -1
 423         if (!qtest_events.mouseClick(item, x, y, button, modifiers, delay))
 424             qtest_fail("window not shown", 2)
 425     }
 426
 427     function mouseDoubleClick(item, x, y, button, modifiers, delay) {
 428         if (button === undefined)
 429             button = Qt.LeftButton
 430         if (modifiers === undefined)
 431             modifiers = Qt.NoModifier
 432         if (delay == undefined)
 433             delay = -1
 434         if (!qtest_events.mouseDoubleClick(item, x, y, button, modifiers, delay))
 435             qtest_fail("window not shown", 2)
 436     }
 437
 438     function mouseMove(item, x, y, delay, buttons) {
 439         if (delay == undefined)
 440             delay = -1
 441         if (buttons == undefined)
 442             buttons = Qt.NoButton
 443         if (!qtest_events.mouseMove(item, x, y, delay, buttons))
 444             qtest_fail("window not shown", 2)
 445     }
 446
 447     function mouseWheel(item, x, y, delta, buttons, modifiers, delay, orientation) {
 448         if (delay == undefined)
 449             delay = -1
 450         if (buttons == undefined)
 451             buttons = Qt.NoButton
 452         if (modifiers === undefined)
 453             modifiers = Qt.NoModifier
 454         if (delta == undefined)
 455             delta = 0
 456         if (orientation == undefined)
 457             orientation = Qt.Vertical
 458         if (!qtest_events.mouseWheel(item, x, y, buttons, modifiers, delta, delay, orientation))
 459             qtest_fail("window not shown", 2)
 460    }
 461
 462
 463     // Functions that can be overridden in subclasses for init/cleanup duties.
 464     function initTestCase() {}
 465     function cleanupTestCase() {}
 466     function init() {}
 467     function cleanup() {}
 468
 469     function qtest_runInternal(prop, arg) {
 470         try {
 471             qtest_testCaseResult = testCase[prop](arg)
 472         } catch (e) {
 473             qtest_testCaseResult = []
 474             if (e.message.indexOf("QtQuickTest::") != 0) {
 475                 // Test threw an unrecognized exception - fail.
 476                 qtest_results.fail("Uncaught exception: " + e.message,
 477                              e.fileName, e.lineNumber)
 478             }
 479         }
 480         return !qtest_results.dataFailed
 481     }
 482
 483     function qtest_runFunction(prop, arg) {
 484         qtest_runInternal("init")
 485         if (!qtest_results.skipped) {
 486             qtest_runInternal(prop, arg)
 487             qtest_results.finishTestData()
 488             qtest_runInternal("cleanup")
 489         }
 490     }
 491
 492     function qtest_runBenchmarkFunction(prop, arg) {
 493         qtest_results.startMeasurement()
 494         do {
 495             qtest_results.beginDataRun()
 496             do {
 497                 // Run the initialization function.
 498                 qtest_runInternal("init")
 499                 if (qtest_results.skipped)
 500                     break
 501
 502                 // Execute the benchmark function.
 503                 if (prop.indexOf("benchmark_once_") != 0)
 504                     qtest_results.startBenchmark(TestResult.RepeatUntilValidMeasurement, qtest_results.dataTag)
 505                 else
 506                     qtest_results.startBenchmark(TestResult.RunOnce, qtest_results.dataTag)
 507                 while (!qtest_results.isBenchmarkDone()) {
 508                     var success = qtest_runInternal(prop, arg)
 509                     qtest_results.finishTestData()
 510                     if (!success)
 511                         break
 512                     qtest_results.nextBenchmark()
 513                 }
 514                 qtest_results.stopBenchmark()
 515
 516                 // Run the cleanup function.
 517                 qtest_runInternal("cleanup")
 518             } while (!qtest_results.measurementAccepted())
 519             qtest_results.endDataRun()
 520         } while (qtest_results.needsMoreMeasurements())
 521     }
 522
 523     function qtest_run() {
 524         if (util.printAvailableFunctions) {
 525             completed = true
 526             return
 527         }
 528
 529         if (TestLogger.log_start_test()) {
 530             qtest_results.reset()
 531             qtest_results.testCaseName = name
 532             qtest_results.startLogging()
 533         } else {
 534             qtest_results.testCaseName = name
 535         }
 536         running = true
 537
 538         // Check the run list to see if this class is mentioned.
 539         var functionsToRun = qtest_results.functionsToRun
 540         if (functionsToRun.length > 0) {
 541             var found = false
 542             var list = []
 543             if (name.length > 0) {
 544                 var prefix = name + "::"
 545                 for (var index in functionsToRun) {
 546                     if (functionsToRun[index].indexOf(prefix) == 0) {
 547                         list.push(functionsToRun[index])
 548                         found = true
 549                     }
 550                 }
 551             }
 552             if (!found) {
 553                 completed = true
 554                 if (!TestLogger.log_complete_test(qtest_testId)) {
 555                     qtest_results.stopLogging()
 556                     Qt.quit()
 557                 }
 558                 qtest_results.testCaseName = ""
 559                 return
 560             }
 561             functionsToRun = list
 562         }
 563
 564         // Run the initTestCase function.
 565         qtest_results.functionName = "initTestCase"
 566         var runTests = true
 567         if (!qtest_runInternal("initTestCase"))
 568             runTests = false
 569         qtest_results.finishTestFunction()
 570
 571         // Run the test methods.
 572         var testList = []
 573         if (runTests) {
 574             for (var prop in testCase) {
 575                 if (prop.indexOf("test_") != 0 && prop.indexOf("benchmark_") != 0)
 576                     continue
 577                 var tail = prop.lastIndexOf("_data");
 578                 if (tail != -1 && tail == (prop.length - 5))
 579                     continue
 580                 testList.push(prop)
 581             }
 582             testList.sort()
 583         }
 584         var checkNames = (functionsToRun.length > 0)
 585         for (var index in testList) {
 586             var prop = testList[index]
 587             var datafunc = prop + "_data"
 588             var isBenchmark = (prop.indexOf("benchmark_") == 0)
 589             if (checkNames) {
 590                 var index = functionsToRun.indexOf(name + "::" + prop)
 591                 if (index < 0)
 592                     continue
 593                 functionsToRun.splice(index, 1)
 594             }
 595             qtest_results.functionName = prop
 596             if (datafunc in testCase) {
 597                 if (qtest_runInternal(datafunc)) {
 598                     var table = qtest_testCaseResult
 599                     var haveData = false
 600                     qtest_results.initTestTable()
 601                     for (var index in table) {
 602                         haveData = true
 603                         var row = table[index]
 604                         if (!row.tag)
 605                             row.tag = "row " + index    // Must have something
 606                         qtest_results.dataTag = row.tag
 607                         if (isBenchmark)
 608                             qtest_runBenchmarkFunction(prop, row)
 609                         else
 610                             qtest_runFunction(prop, row)
 611                         qtest_results.dataTag = ""
 612                     }
 613                     if (!haveData)
 614                         qtest_results.warn("no data supplied for " + prop + "() by " + datafunc + "()"
 615                                            , util.callerFile(), util.callerLine());
 616                     qtest_results.clearTestTable()
 617                 }
 618             } else if (isBenchmark) {
 619                 qtest_runBenchmarkFunction(prop, null, isBenchmark)
 620             } else {
 621                 qtest_runFunction(prop, null, isBenchmark)
 622             }
 623             qtest_results.finishTestFunction()
 624             qtest_results.skipped = false
 625         }
 626
 627         // Run the cleanupTestCase function.
 628         qtest_results.skipped = false
 629         qtest_results.functionName = "cleanupTestCase"
 630         qtest_runInternal("cleanupTestCase")
 631
 632         // Complain about missing functions that we were supposed to run.
 633         if (functionsToRun.length > 0)
 634             qtest_results.fail("Could not find functions: " + functionsToRun, "", 0)
 635
 636         // Clean up and exit.
 637         running = false
 638         completed = true
 639         qtest_results.finishTestFunction()
 640         qtest_results.functionName = ""
 641
 642         // Stop if there are no more tests to be run.
 643         if (!TestLogger.log_complete_test(qtest_testId)) {
 644             qtest_results.stopLogging()
 645             Qt.quit()
 646         }
 647         qtest_results.testCaseName = ""
 648     }
 649
 650     onWhenChanged: {
 651         if (when != qtest_prevWhen) {
 652             qtest_prevWhen = when
 653             if (when && !completed && !running && qtest_componentCompleted)
 654                 qtest_run()
 655         }
 656     }
 657
 658     onOptionalChanged: {
 659         if (!completed) {
 660             if (optional)
 661                 TestLogger.log_optional_test(qtest_testId)
 662             else
 663                 TestLogger.log_mandatory_test(qtest_testId)
 664         }
 665     }
 666
 667     // The test framework will set util.windowShown when the
 668     // window is actually shown.  If we are running with qmlviewer,
 669     // then this won't happen.  So we use a timer instead.
 670     Timer {
 671         id: qtest_windowShowTimer
 672         interval: 100
 673         repeat: false
 674         onTriggered: { windowShown = true }
 675     }
 676
 677     Component.onCompleted: {
 678         qtest.hasTestCase = true;
 679         qtest_componentCompleted = true;
 680
 681         if (util.printAvailableFunctions) {
 682             var testList = []
 683             for (var prop in testCase) {
 684                 if (prop.indexOf("test_") != 0 && prop.indexOf("benchmark_") != 0)
 685                     continue
 686                 var tail = prop.lastIndexOf("_data");
 687                 if (tail != -1 && tail == (prop.length - 5))
 688                     continue
 689                 // Note: cannot run functions in TestCase elements
 690                 // that lack a name.
 691                 if (name.length > 0)
 692                     testList.push(name + "::" + prop + "()")
 693             }
 694             testList.sort()
 695             for (var index in testList)
 696                 console.log(testList[index])
 697             return
 698         }
 699         qtest_testId = TestLogger.log_register_test(name)
 700         if (optional)
 701             TestLogger.log_optional_test(qtest_testId)
 702         qtest_prevWhen = when
 703         var isQmlViewer = util.wrapper ? false : true
 704         if (isQmlViewer)
 705             qtest_windowShowTimer.running = true
 706         if (when && !completed && !running)
 707             qtest_run()
 708     }
 709 }