src/imports/testlib/SignalSpy.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the test suite of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtTest 1.0
  44
  45 Item {
  46     id: spy
  47     visible: false
  48
  49     TestUtil {
  50         id: util
  51     }
  52
  53     // Public API.
  54
  55     property variant target: null
  56     property string signalName: ""
  57     property int count: 0
  58
  59     function clear() {
  60         count = 0
  61         qtest_expectedCount = 0
  62     }
  63
  64     function wait(timeout) {
  65         if (timeout === undefined)
  66             timeout = 5000
  67         var expected = ++qtest_expectedCount
  68         var i = 0
  69         while (i < timeout && count < expected) {
  70             qtest_results.wait(50)
  71             i += 50
  72         }
  73         var success = (count >= expected)
  74         if (!qtest_results.verify(success, "wait for signal " + signalName, util.callerFile(), util.callerLine()))
  75             throw new Error("QtQuickTest::fail")
  76     }
  77
  78     // Internal implementation detail follows.
  79
  80     TestResult { id: qtest_results }
  81
  82     onTargetChanged: {
  83         qtest_update()
  84     }
  85     onSignalNameChanged: {
  86         qtest_update()
  87     }
  88
  89     property variant qtest_prevTarget: null
  90     property string qtest_prevSignalName: ""
  91     property int qtest_expectedCount: 0
  92
  93     function qtest_update() {
  94         if (qtest_prevTarget != null) {
  95             qtest_prevTarget[qtest_prevSignalName].disconnect(spy, "qtest_activated")
  96             qtest_prevTarget = null
  97             qtest_prevSignalName = ""
  98         }
  99         if (target != null && signalName != "") {
 100             var func = target[signalName]
 101             if (func === undefined) {
 102                 console.log("Signal '" + signalName + "' not found")
 103             } else {
 104                 qtest_prevTarget = target
 105                 qtest_prevSignalName = signalName
 106                 func.connect(spy.qtest_activated)
 107             }
 108         }
 109     }
 110
 111     function qtest_activated() {
 112         ++count
 113     }
 114 }