src/imports/testlib/SignalSpy.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2010 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the test suite of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtTest 1.0
  44
  45 Item {
  46     id: spy
  47     visible: false
  48
  49     // Public API.
  50
  51     property variant target: null
  52     property string signalName: ""
  53     property int count: 0
  54
  55     function clear() {
  56         count = 0
  57         qtest_expectedCount = 0
  58     }
  59
  60     function wait(timeout) {
  61         if (timeout === undefined)
  62             timeout = 5000
  63         var expected = ++qtest_expectedCount
  64         var i = 0
  65         while (i < timeout && count < expected) {
  66             qtest_results.wait(50)
  67             i += 50
  68         }
  69         var success = (count >= expected)
  70         if (!qtest_results.verify(success, "wait for signal " + signalName, QtTest.qtest_caller_file(), QtTest.qtest_caller_line()))
  71             throw new Error("QtQuickTest::fail")
  72     }
  73
  74     // Internal implementation detail follows.
  75
  76     TestResult { id: qtest_results }
  77
  78     onTargetChanged: {
  79         qtest_update()
  80     }
  81     onSignalNameChanged: {
  82         qtest_update()
  83     }
  84
  85     property variant qtest_prevTarget: null
  86     property string qtest_prevSignalName: ""
  87     property int qtest_expectedCount: 0
  88
  89     function qtest_update() {
  90         if (qtest_prevTarget != null) {
  91             qtest_prevTarget[qtest_prevSignalName].disconnect(spy, "qtest_activated")
  92             qtest_prevTarget = null
  93             qtest_prevSignalName = ""
  94         }
  95         if (target != null && signalName != "") {
  96             var func = target[signalName]
  97             if (func === undefined) {
  98                 console.log("Signal '" + signalName + "' not found")
  99             } else {
 100                 qtest_prevTarget = target
 101                 qtest_prevSignalName = signalName
 102                 func.connect(spy.qtest_activated)
 103             }
 104         }
 105     }
 106
 107     function qtest_activated() {
 108         ++count
 109     }
 110 }