src/imports/testlib/SignalSpy.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the test suite of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtTest 1.0
  44
  45 Item {
  46     id: spy
  47     visible: false
  48
  49     TestUtil {
  50         id: util
  51     }
  52     // Public API.
  53     property var target: null
  54     property string signalName: ""
  55     readonly property alias count: spy.qtest_count
  56     readonly property alias valid:spy.qtest_valid
  57     readonly property alias signalArguments:spy.qtest_signalArguments
  58
  59     function clear() {
  60         qtest_count = 0
  61         qtest_expectedCount = 0
  62         qtest_signalArguments = []
  63     }
  64
  65     function wait(timeout) {
  66         if (timeout === undefined)
  67             timeout = 5000
  68         var expected = ++qtest_expectedCount
  69         var i = 0
  70         while (i < timeout && qtest_count < expected) {
  71             qtest_results.wait(50)
  72             i += 50
  73         }
  74         var success = (qtest_count >= expected)
  75         if (!qtest_results.verify(success, "wait for signal " + signalName, util.callerFile(), util.callerLine()))
  76             throw new Error("QtQuickTest::fail")
  77     }
  78
  79     // Internal implementation detail follows.
  80
  81     TestResult { id: qtest_results }
  82
  83     onTargetChanged: {
  84         qtest_update()
  85     }
  86     onSignalNameChanged: {
  87         qtest_update()
  88     }
  89
  90     property var qtest_prevTarget: null
  91     property string qtest_prevSignalName: ""
  92     property int qtest_expectedCount: 0
  93     property var qtest_signalArguments:[]
  94     property int qtest_count: 0
  95     property bool qtest_valid:false
  96
  97     function qtest_update() {
  98         if (qtest_prevTarget != null) {
  99             var prevFunc = qtest_prevTarget[qtest_prevSignalName]
 100             if (prevFunc)
 101                 prevFunc.disconnect(spy.qtest_activated)
 102             qtest_prevTarget = null
 103             qtest_prevSignalName = ""
 104         }
 105         if (target != null && signalName != "") {
 106             var func = target[signalName]
 107             if (func === undefined) {
 108                 spy.qtest_valid = false
 109                 console.log("Signal '" + signalName + "' not found")
 110             } else {
 111                 qtest_prevTarget = target
 112                 qtest_prevSignalName = signalName
 113                 func.connect(spy.qtest_activated)
 114                 spy.qtest_valid = true
 115                 spy.qtest_signalArguments = []
 116             }
 117         } else {
 118             spy.qtest_valid = false
 119         }
 120     }
 121
 122     function qtest_activated() {
 123         ++qtest_count
 124         spy.qtest_signalArguments[spy.qtest_signalArguments.length] = arguments
 125     }
 126 }