src/imports/testlib/SignalSpy.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2010 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the test suite of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43
  44 Item {
  45     id: spy
  46     visible: false
  47
  48     // Public API.
  49
  50     property variant target: null
  51     property string signalName: ""
  52     property int count: 0
  53
  54     function clear() {
  55         count = 0
  56         qtest_expectedCount = 0
  57     }
  58
  59     function wait(timeout) {
  60         if (timeout === undefined)
  61             timeout = 5000
  62         var expected = ++qtest_expectedCount
  63         var i = 0
  64         while (i < timeout && count < expected) {
  65             qtest_results.wait(50)
  66             i += 50
  67         }
  68         var success = (count >= expected)
  69         if (!qtest_results.verify(success, "wait for signal " + signalName, QtTest.qtest_caller_file(), QtTest.qtest_caller_line()))
  70             throw new Error("QtQuickTest::fail")
  71     }
  72
  73     // Internal implementation detail follows.
  74
  75     TestResult { id: qtest_results }
  76
  77     onTargetChanged: {
  78         qtest_update()
  79     }
  80     onSignalNameChanged: {
  81         qtest_update()
  82     }
  83
  84     property variant qtest_prevTarget: null
  85     property string qtest_prevSignalName: ""
  86     property int qtest_expectedCount: 0
  87
  88     function qtest_update() {
  89         if (qtest_prevTarget != null) {
  90             qtest_prevTarget[qtest_prevSignalName].disconnect(spy, "qtest_activated")
  91             qtest_prevTarget = null
  92             qtest_prevSignalName = ""
  93         }
  94         if (target != null && signalName != "") {
  95             var func = target[signalName]
  96             if (func === undefined) {
  97                 console.log("Signal '" + signalName + "' not found")
  98             } else {
  99                 qtest_prevTarget = target
 100                 qtest_prevSignalName = signalName
 101                 func.connect(spy.qtest_activated)
 102             }
 103         }
 104     }
 105
 106     function qtest_activated() {
 107         ++count
 108     }
 109 }