src/core/CL/cl_kernels/minmax_layer.cl

   1 /*
   2  * Copyright (c) 2017 ARM Limited.
   3  *
   4  * SPDX-License-Identifier: MIT
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a copy
   7  * of this software and associated documentation files (the "Software"), to
   8  * deal in the Software without restriction, including without limitation the
   9  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  10  * sell copies of the Software, and to permit persons to whom the Software is
  11  * furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in all
  14  * copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  21  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  22  * SOFTWARE.
  23  */
  24 #include "helpers.h"
  25
  26 #if defined(WIDTH) && defined(HEIGHT) && defined(DEPTH)
  27 /** This function identifies the min and maximum value of an input 3D tensor.
  28  *
  29  * @note The width, height and depth of the input tensor must be provided at compile time using -DWIDTH, -DHEIGHT and -DDEPTH (e.g. -DWIDTH=320, -DHEIGHT=240, -DDEPTH=3)
  30  *
  31  * @param[in] src_ptr                           Pointer to the source tensor. Supported data types: F32
  32  * @param[in] src_stride_x                      Stride of the source image in X dimension (in bytes)
  33  * @param[in] src_step_x                        src_stride_x * number of elements along X processed per workitem(in bytes)
  34  * @param[in] src_stride_y                      Stride of the source image in Y dimension (in bytes)
  35  * @param[in] src_step_y                        src_stride_y * number of elements along Y processed per workitem(in bytes)
  36  * @param[in] src_stride_z                      Stride of the source image in Z dimension (in bytes)
  37  * @param[in] src_step_z                        src_stride_z * number of elements along Z processed per workitem(in bytes)
  38  * @param[in] src_offset_first_element_in_bytes The offset of the first element in the source image
  39  * @param[in] dst_ptr                           Pointer to the min/max vector. Minimum value in position 0, maximum value in position 1. Supported data types: F32.
  40  * @param[in] dst_stride_x                      Stride of the min/max vector in X dimension (in bytes)
  41  * @param[in] dst_step_x                        dst_stride_x * number of elements along X processed per workitem(in bytes)
  42  * @param[in] dst_offset_first_element_in_bytes The offset of the first element in the min/max vector
  43  */
  44 __kernel void minmax_layer(
  45     TENSOR3D_DECLARATION(src),
  46     VECTOR_DECLARATION(dst))
  47 {
  48     Tensor3D src = CONVERT_TO_TENSOR3D_STRUCT(src);
  49     Vector   dst = CONVERT_TO_VECTOR_STRUCT(dst);
  50
  51     float4 min_value     = (float4)FLT_MAX;
  52     float4 max_value     = (float4) - FLT_MAX;
  53     float2 min_max_value = (float2)(FLT_MAX, -FLT_MAX);
  54
  55     for(int z = 0; z < DEPTH; ++z)
  56     {
  57         for(int y = 0; y < HEIGHT; ++y)
  58         {
  59             int             x        = 0;
  60             __global float *src_addr = (__global float *)(src.ptr + y * src_stride_y + z * src_stride_z);
  61
  62             for(; x <= (int)(WIDTH - 8); x += 8)
  63             {
  64                 float8 value = *(src_addr + x);
  65
  66                 min_value = select(value.s0123, min_value, min_value < value.s0123);
  67                 min_value = select(value.s4567, min_value, min_value < value.s4567);
  68
  69                 max_value = select(value.s0123, max_value, max_value > value.s0123);
  70                 max_value = select(value.s4567, max_value, max_value > value.s4567);
  71             }
  72
  73             for(; x < WIDTH; ++x)
  74             {
  75                 float value = *(src_addr + x);
  76
  77                 min_max_value.s0 = min(min_max_value.s0, value);
  78                 min_max_value.s1 = max(min_max_value.s1, value);
  79             }
  80         }
  81     }
  82
  83     // Perform min/max reduction
  84     min_value.s01 = min(min_value.s01, min_value.s23);
  85     min_value.s0  = min(min_value.s0, min_value.s1);
  86     max_value.s01 = max(max_value.s01, max_value.s23);
  87     max_value.s0  = max(max_value.s0, max_value.s1);
  88
  89     min_max_value.s0 = min(min_max_value.s0, min_value.s0);
  90     min_max_value.s1 = max(min_max_value.s1, max_value.s0);
  91
  92     if(min_max_value.s0 == min_max_value.s1)
  93     {
  94         min_max_value.s0 = 0.0f;
  95         min_max_value.s1 = 1.0f;
  96     }
  97
  98     // Store min and max
  99     vstore2(min_max_value, 0, (__global float *)dst.ptr);
 100 }
 101 #endif // defined(WIDTH) && defined(HEIGHT) && defined(DEPTH)