src/core/CL/cl_kernels/erode.cl

   1 /*
   2  * Copyright (c) 2016, 2017 ARM Limited.
   3  *
   4  * SPDX-License-Identifier: MIT
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a copy
   7  * of this software and associated documentation files (the "Software"), to
   8  * deal in the Software without restriction, including without limitation the
   9  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  10  * sell copies of the Software, and to permit persons to whom the Software is
  11  * furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in all
  14  * copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  21  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  22  * SOFTWARE.
  23  */
  24 #include "helpers.h"
  25
  26 /** This function erodes an input image image.
  27  *
  28  * @param[in]  src_ptr                           Pointer to the source image. Supported data types: U8
  29  * @param[in]  src_stride_x                      Stride of the source image in X dimension (in bytes)
  30  * @param[in]  src_step_x                        src_stride_x * number of elements along X processed per workitem(in bytes)
  31  * @param[in]  src_stride_y                      Stride of the source image in Y dimension (in bytes)
  32  * @param[in]  src_step_y                        src_stride_y * number of elements along Y processed per workitem(in bytes)
  33  * @param[in]  src_offset_first_element_in_bytes The offset of the first element in the source image
  34  * @param[out] dst_ptr                           Pointer to the destination image. Supported data types: U8
  35  * @param[in]  dst_stride_x                      Stride of the destination image in X dimension (in bytes)
  36  * @param[in]  dst_step_x                        dst_stride_x * number of elements along X processed per workitem(in bytes)
  37  * @param[in]  dst_stride_y                      Stride of the destination image in Y dimension (in bytes)
  38  * @param[in]  dst_step_y                        dst_stride_y * number of elements along Y processed per workitem(in bytes)
  39  * @param[in]  dst_offset_first_element_in_bytes The offset of the first element in the destination image
  40  */
  41 __kernel void erode(
  42     IMAGE_DECLARATION(src),
  43     IMAGE_DECLARATION(dst))
  44 {
  45     Image src = CONVERT_TO_IMAGE_STRUCT(src);
  46     Image dst = CONVERT_TO_IMAGE_STRUCT(dst);
  47
  48     uchar16 top    = vload16(0, offset(&src, -1, -1));
  49     uchar16 middle = vload16(0, offset(&src, -1, 0));
  50     uchar16 bottom = vload16(0, offset(&src, -1, 1));
  51
  52     uchar16 tmp = min(top, min(middle, bottom));
  53     uchar8  out = min(tmp.s01234567, min(tmp.s12345678, tmp.s23456789));
  54
  55     vstore8(out, 0, dst.ptr);
  56 }