src/core/CL/cl_kernels/direct_convolution5x5.cl

   1 /*
   2  * Copyright (c) 2016, 2017 ARM Limited.
   3  *
   4  * SPDX-License-Identifier: MIT
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a copy
   7  * of this software and associated documentation files (the "Software"), to
   8  * deal in the Software without restriction, including without limitation the
   9  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  10  * sell copies of the Software, and to permit persons to whom the Software is
  11  * furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in all
  14  * copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  21  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  22  * SOFTWARE.
  23  */
  24 #include "helpers.h"
  25
  26 #undef CONVERT_SAT
  27
  28 #if defined(DATA_TYPE) && defined(STRIDE_X) && defined(WEIGHTS_DEPTH)
  29
  30 #if STRIDE_X == 1
  31 #define CONVOLUTION1x5(acc, src_row_ptr, weights_row_ptr) CONVOLUTION1x5_STRIDE1(acc, src_row_ptr, weights_row_ptr)
  32 #elif STRIDE_X == 2 /* STRIDE_X == 1 */
  33 #define CONVOLUTION1x5(acc, src_row_ptr, weights_row_ptr) CONVOLUTION1x5_STRIDE2(acc, src_row_ptr, weights_row_ptr)
  34 #else /* STRIDE_X not equals 1 or 2 */
  35 #error "STRIDE_X larger than 2 is not supported"
  36 #endif /* STRIDE_X == 2 */
  37
  38 #define CONVOLUTION1x5_STRIDE1(acc, src_row_ptr, weights_row_ptr)                                                               \
  39     ({                                                                                                                          \
  40         VEC_DATA_TYPE(DATA_TYPE, 4)                                                                                             \
  41         weights_values0          = vload4(0, weights_row_ptr);                                                                  \
  42         DATA_TYPE weights_value1 = *(weights_row_ptr + 4);                                                                      \
  43         VEC_DATA_TYPE(DATA_TYPE, 8)                                                                                             \
  44         src0 = vload8(0, src_row_ptr);                                                                                          \
  45         VEC_DATA_TYPE(DATA_TYPE, 4)                                                                                             \
  46         src1 = vload4(0, src_row_ptr + 8);                                                                                      \
  47         \
  48         acc += src0 * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s0;                                                          \
  49         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s1234, src0.s567, src1.s0) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s1; \
  50         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s234, src0.s567, src1.s01) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s2; \
  51         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s345, src0.s67, src1.s012) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s3; \
  52         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s45, src0.s67, src1.s0123) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_value1;     \
  53     })
  54
  55 #define CONVOLUTION1x5_STRIDE2(acc, src_row_ptr, weights_row_ptr)                                                               \
  56     ({                                                                                                                          \
  57         VEC_DATA_TYPE(DATA_TYPE, 4)                                                                                             \
  58         weights_values0          = vload4(0, weights_row_ptr);                                                                  \
  59         DATA_TYPE weights_value1 = *(weights_row_ptr + 4);                                                                      \
  60         VEC_DATA_TYPE(DATA_TYPE, 16)                                                                                            \
  61         src0 = vload16(0, src_row_ptr);                                                                                         \
  62         VEC_DATA_TYPE(DATA_TYPE, 4)                                                                                             \
  63         src1 = vload4(0, src_row_ptr + 16);                                                                                     \
  64         acc += src0.even * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s0;                                                     \
  65         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s1357, src0.s9BDF) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s1;         \
  66         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s2468, src0.sACE, src1.s0) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s2; \
  67         \
  68         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s3579, src0.sBDF, src1.s1) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_values0.s3; \
  69         acc += (VEC_DATA_TYPE(DATA_TYPE, 8))(src0.s468a, src0.sCE, src1.s02) * (VEC_DATA_TYPE(DATA_TYPE, 8))weights_value1;     \
  70     })
  71
  72 /** This kernel performs a direct convolution to convolve the low three dimensions.
  73  *
  74  * @note The data type must be passed at compile time using -DDATA_TYPE: e.g. -DDATA_TYPE=float
  75  * @note The third dimensions of the weights tensors must be passed at compile time using -DWEIGHTS_DEPTH
  76  * @note If biases are used then -DHAS_BIAS has to be passed at compile time
  77  *
  78  * @param[in]  src_ptr                               Pointer to the source tensor. Supported data types: F16/F32
  79  * @param[in]  src_stride_x                          Stride of the source tensor in X dimension (in bytes)
  80  * @param[in]  src_step_x                            src_stride_x * number of elements along X processed per workitem(in bytes)
  81  * @param[in]  src_stride_y                          Stride of the source tensor in Y dimension (in bytes)
  82  * @param[in]  src_step_y                            src_stride_y * number of elements along Y processed per workitem(in bytes)
  83  * @param[in]  src_stride_z                          Stride of the source tensor in Z dimension (in bytes)
  84  * @param[in]  src_step_z                            src_stride_z * number of elements along Z processed per workitem(in bytes)
  85  * @param[in]  src_offset_first_element_in_bytes     The offset of the first element in the source tensor
  86  * @param[out] dst_ptr                               Pointer to the destination tensor. Supported data types: same as @p src_ptr
  87  * @param[in]  dst_stride_x                          Stride of the destination tensor in X dimension (in bytes)
  88  * @param[in]  dst_step_x                            dst_stride_x * number of elements along X processed per workitem(in bytes)
  89  * @param[in]  dst_stride_y                          Stride of the destination tensor in Y dimension (in bytes)
  90  * @param[in]  dst_step_y                            dst_stride_y * number of elements along Z processed per workitem(in bytes)
  91  * @param[in]  dst_stride_z                          Stride of the destination tensor in Z dimension (in bytes)
  92  * @param[in]  dst_step_z                            dst_stride_z * number of elements along Z processed per workitem(in bytes)
  93  * @param[in]  dst_offset_first_element_in_bytes     The offset of the first element in the destination tensor
  94  * @param[in]  weights_ptr                           Pointer to the weights tensor. Supported data types: same as @p src_ptr
  95  * @param[in]  weights_stride_x                      Stride of the weights tensor in X dimension (in bytes)
  96  * @param[in]  weights_step_x                        weights_stride_x * number of elements along X processed per workitem(in bytes)
  97  * @param[in]  weights_stride_y                      Stride of the weights tensor in Y dimension (in bytes)
  98  * @param[in]  weights_step_y                        weights_stride_y * number of elements along y processed per workitem(in bytes)
  99  * @param[in]  weights_stride_z                      Stride of the weights tensor in Z dimension (in bytes)
 100  * @param[in]  weights_step_z                        weights_stride_z * number of elements along Z processed per workitem(in bytes)
 101  * @param[in]  weights_offset_first_element_in_bytes The offset of the first element in the weights tensor
 102  * @param[in]  biases_ptr                            Pointer to the biases tensor. Same as @p src_ptr
 103  * @param[in]  biases_stride_x                       Stride of the biases tensor in X dimension (in bytes)
 104  * @param[in]  biases_step_x                         biases_stride_x * number of elements along X processed per workitem(in bytes)
 105  * @param[in]  biases_offset_first_element_in_bytes  The offset of the first element in the biases tensor
 106  * @param[in]  weights_stride_w                      Stride of the weights tensor in the 4th dimension
 107  */
 108 __kernel void direct_convolution5x5(
 109     TENSOR3D_DECLARATION(src),
 110     TENSOR3D_DECLARATION(dst),
 111     TENSOR3D_DECLARATION(weights),
 112 #ifdef HAS_BIAS
 113     VECTOR_DECLARATION(biases),
 114 #endif /* defined(HAS_BIAS) */
 115     unsigned int weights_stride_w)
 116 {
 117     Image    src     = CONVERT_TO_IMAGE_STRUCT(src);
 118     Tensor3D weights = CONVERT_TO_TENSOR3D_STRUCT_NO_STEP(weights);
 119     Tensor3D dst     = CONVERT_TO_TENSOR3D_STRUCT(dst);
 120
 121     VEC_DATA_TYPE(DATA_TYPE, 8)
 122     pixels0 = 0;
 123
 124     __global uchar *weights_addr = (__global uchar *)tensor3D_offset(&weights, 0, 0, 0);
 125     __global uchar *src_addr     = (__global uchar *)offset(&src, 0, 0);
 126
 127     const int kernel_index = get_global_id(2);
 128     weights_addr += kernel_index * weights_stride_w;
 129
 130     for(volatile int d = 0; d < WEIGHTS_DEPTH; ++d)
 131     {
 132         CONVOLUTION1x5(pixels0, (__global DATA_TYPE *)src_addr, (__global DATA_TYPE *)weights_addr);
 133         CONVOLUTION1x5(pixels0, (__global DATA_TYPE *)(src_addr + 1 * src_stride_y), (__global DATA_TYPE *)(weights_addr + 1 * weights_stride_y));
 134         CONVOLUTION1x5(pixels0, (__global DATA_TYPE *)(src_addr + 2 * src_stride_y), (__global DATA_TYPE *)(weights_addr + 2 * weights_stride_y));
 135         CONVOLUTION1x5(pixels0, (__global DATA_TYPE *)(src_addr + 3 * src_stride_y), (__global DATA_TYPE *)(weights_addr + 3 * weights_stride_y));
 136         CONVOLUTION1x5(pixels0, (__global DATA_TYPE *)(src_addr + 4 * src_stride_y), (__global DATA_TYPE *)(weights_addr + 4 * weights_stride_y));
 137
 138         src_addr += src_stride_z;
 139         weights_addr += weights_stride_z;
 140     }
 141
 142 #ifdef HAS_BIAS
 143     Vector biases = CONVERT_TO_VECTOR_STRUCT_NO_STEP(biases);
 144
 145     pixels0 += (VEC_DATA_TYPE(DATA_TYPE, 8)) * ((__global DATA_TYPE *)(vector_offset(&biases, kernel_index)));
 146 #endif /* defined(HAS_BIAS) */
 147
 148     vstore8(pixels0, 0, (__global DATA_TYPE *)dst.ptr);
 149 }
 150 #endif // defined(DATA_TYPE) && defined(STRIDE_X) && defined(WEIGHTS_DEPTH)
 151
 152 #if defined(WEIGHTS_DEPTH)
 153
 154 #define CONVOLUTION1x5_BIFROST(acc, src0, weights_row00, weights_row01) \
 155     ({                                                                  \
 156         acc.s0 = mad(src0.s0, weights_row00.s0, acc.s0);                \
 157         acc.s1 = mad(src0.s1, weights_row00.s0, acc.s1);                \
 158         acc.s2 = mad(src0.s2, weights_row00.s0, acc.s2);                \
 159         acc.s3 = mad(src0.s3, weights_row00.s0, acc.s3);                \
 160         acc.s0 = mad(src0.s1, weights_row00.s1, acc.s0);                \
 161         acc.s1 = mad(src0.s2, weights_row00.s1, acc.s1);                \
 162         acc.s2 = mad(src0.s3, weights_row00.s1, acc.s2);                \
 163         acc.s3 = mad(src0.s4, weights_row00.s1, acc.s3);                \
 164         acc.s0 = mad(src0.s2, weights_row00.s2, acc.s0);                \
 165         acc.s1 = mad(src0.s3, weights_row00.s2, acc.s1);                \
 166         acc.s2 = mad(src0.s4, weights_row00.s2, acc.s2);                \
 167         acc.s3 = mad(src0.s5, weights_row00.s2, acc.s3);                \
 168         acc.s0 = mad(src0.s3, weights_row00.s3, acc.s0);                \
 169         acc.s1 = mad(src0.s4, weights_row00.s3, acc.s1);                \
 170         acc.s2 = mad(src0.s5, weights_row00.s3, acc.s2);                \
 171         acc.s3 = mad(src0.s6, weights_row00.s3, acc.s3);                \
 172         acc.s0 = mad(src0.s4, weights_row01, acc.s0);                   \
 173         acc.s1 = mad(src0.s5, weights_row01, acc.s1);                   \
 174         acc.s2 = mad(src0.s6, weights_row01, acc.s2);                   \
 175         acc.s3 = mad(src0.s7, weights_row01, acc.s3);                   \
 176     })
 177
 178 /** An optimized direct convolution 5x5 OpenCL kernel for Bifrost architectures when the data type is F32
 179  *
 180  * @note This OpenCL kernel works only with stride_x and stride_y equal to 1
 181  * @note The third dimensions of the weights tensors must be passed at compile time using -DWEIGHTS_DEPTH
 182  * @note If biases are used then -DHAS_BIAS has to be passed at compile time
 183  *
 184  * @param[in]  src_ptr                               Pointer to the source tensor. Supported data types: F32
 185  * @param[in]  src_stride_x                          Stride of the source tensor in X dimension (in bytes)
 186  * @param[in]  src_step_x                            src_stride_x * number of elements along X processed per workitem(in bytes)
 187  * @param[in]  src_stride_y                          Stride of the source tensor in Y dimension (in bytes)
 188  * @param[in]  src_step_y                            src_stride_y * number of elements along Y processed per workitem(in bytes)
 189  * @param[in]  src_stride_z                          Stride of the source tensor in Z dimension (in bytes)
 190  * @param[in]  src_step_z                            src_stride_z * number of elements along Z processed per workitem(in bytes)
 191  * @param[in]  src_offset_first_element_in_bytes     The offset of the first element in the source tensor
 192  * @param[out] dst_ptr                               Pointer to the destination tensor. Supported data types: same as @p src_ptr
 193  * @param[in]  dst_stride_x                          Stride of the destination tensor in X dimension (in bytes)
 194  * @param[in]  dst_step_x                            dst_stride_x * number of elements along X processed per workitem(in bytes)
 195  * @param[in]  dst_stride_y                          Stride of the destination tensor in Y dimension (in bytes)
 196  * @param[in]  dst_step_y                            dst_stride_y * number of elements along Z processed per workitem(in bytes)
 197  * @param[in]  dst_stride_z                          Stride of the destination tensor in Z dimension (in bytes)
 198  * @param[in]  dst_step_z                            dst_stride_z * number of elements along Z processed per workitem(in bytes)
 199  * @param[in]  dst_offset_first_element_in_bytes     The offset of the first element in the destination tensor
 200  * @param[in]  weights_ptr                           Pointer to the weights tensor. Supported data types: same as @p src_ptr
 201  * @param[in]  weights_stride_x                      Stride of the weights tensor in X dimension (in bytes)
 202  * @param[in]  weights_step_x                        weights_stride_x * number of elements along X processed per workitem(in bytes)
 203  * @param[in]  weights_stride_y                      Stride of the weights tensor in Y dimension (in bytes)
 204  * @param[in]  weights_step_y                        weights_stride_y * number of elements along y processed per workitem(in bytes)
 205  * @param[in]  weights_stride_z                      Stride of the weights tensor in Z dimension (in bytes)
 206  * @param[in]  weights_step_z                        weights_stride_z * number of elements along Z processed per workitem(in bytes)
 207  * @param[in]  weights_offset_first_element_in_bytes The offset of the first element in the weights tensor
 208  * @param[in]  biases_ptr                            Pointer to the biases tensor. Same as @p src_ptr
 209  * @param[in]  biases_stride_x                       Stride of the biases tensor in X dimension (in bytes)
 210  * @param[in]  biases_step_x                         biases_stride_x * number of elements along X processed per workitem(in bytes)
 211  * @param[in]  biases_offset_first_element_in_bytes  The offset of the first element in the biases tensor
 212  * @param[in]  weights_stride_w                      Stride of the weights tensor in the 4th dimension
 213  */
 214 __kernel void direct_convolution5x5_f32_bifrost(
 215     TENSOR3D_DECLARATION(src),
 216     TENSOR3D_DECLARATION(dst),
 217     TENSOR3D_DECLARATION(weights),
 218 #ifdef HAS_BIAS
 219     VECTOR_DECLARATION(biases),
 220 #endif /* defined(HAS_BIAS) */
 221     unsigned int weights_stride_w)
 222 {
 223     // Get the kernel index
 224     const int kernel_index = get_global_id(2);
 225
 226     Image    src = CONVERT_TO_IMAGE_STRUCT(src);
 227     Tensor3D dst = CONVERT_TO_TENSOR3D_STRUCT(dst);
 228
 229     float4 pixels0 = 0.0f;
 230     float4 pixels1 = 0.0f;
 231
 232     __global uchar *weights_addr = (__global uchar *)(weights_ptr + weights_offset_first_element_in_bytes + kernel_index * weights_stride_w);
 233     __global uchar *src_addr     = (__global uchar *)offset(&src, 0, 0);
 234
 235     // Note: Since each work-item computes 4x2 elements, we need to load 6 rows from the input tensor
 236
 237     for(ushort d = 0; d < (ushort)WEIGHTS_DEPTH; ++d)
 238     {
 239         // Load the weights from row0 and row1
 240         float4 weights_row00 = vload4(0, (__global float *)(weights_addr + 0 * weights_stride_y));
 241         float  weights_row01 = *((__global float *)(weights_addr + 0 * weights_stride_y) + 4);
 242         float4 weights_row10 = vload4(0, (__global float *)(weights_addr + 1 * weights_stride_y));
 243         float  weights_row11 = *((__global float *)(weights_addr + 1 * weights_stride_y) + 4);
 244         float8 src0;
 245
 246         // Load values from row0 of input tensor
 247         src0 = vload8(0, (__global float *)(src_addr + 0 * src_stride_y));
 248
 249         // Accumulate
 250         CONVOLUTION1x5_BIFROST(pixels0, src0, weights_row00, weights_row01);
 251
 252         // Load values from row1 of input tensor
 253         src0 = vload8(0, (__global float *)(src_addr + 1 * src_stride_y));
 254
 255         // Accumulate
 256         CONVOLUTION1x5_BIFROST(pixels0, src0, weights_row10, weights_row11);
 257         CONVOLUTION1x5_BIFROST(pixels1, src0, weights_row00, weights_row01);
 258
 259         // Load values from row2 of input tensor
 260         src0 = vload8(0, (__global float *)(src_addr + 2 * src_stride_y));
 261
 262         // Load weights from row2
 263         weights_row00 = vload4(0, (__global float *)(weights_addr + 2 * weights_stride_y));
 264         weights_row01 = *((__global float *)(weights_addr + 2 * weights_stride_y) + 4);
 265
 266         // Accumulate
 267         CONVOLUTION1x5_BIFROST(pixels0, src0, weights_row00, weights_row01);
 268         CONVOLUTION1x5_BIFROST(pixels1, src0, weights_row10, weights_row11);
 269
 270         // Load values from row3 of input tensor
 271         src0 = vload8(0, (__global float *)(src_addr + 3 * src_stride_y));
 272
 273         // Load weights from row3
 274         weights_row10 = vload4(0, (__global float *)(weights_addr + 3 * weights_stride_y));
 275         weights_row11 = *((__global float *)(weights_addr + 3 * weights_stride_y) + 4);
 276
 277         // Accumulate
 278         CONVOLUTION1x5_BIFROST(pixels0, src0, weights_row10, weights_row11);
 279         CONVOLUTION1x5_BIFROST(pixels1, src0, weights_row00, weights_row01);
 280
 281         // Load values from row4 of input tensor
 282         src0 = vload8(0, (__global float *)(src_addr + 4 * src_stride_y));
 283
 284         // Load weights from row4
 285         weights_row00 = vload4(0, (__global float *)(weights_addr + 4 * weights_stride_y));
 286         weights_row01 = *((__global float *)(weights_addr + 4 * weights_stride_y) + 4);
 287
 288         CONVOLUTION1x5_BIFROST(pixels0, src0, weights_row00, weights_row01);
 289         CONVOLUTION1x5_BIFROST(pixels1, src0, weights_row10, weights_row11);
 290
 291         // Load values from row5 of input tensor
 292         src0 = vload8(0, (__global float *)(src_addr + 5 * src_stride_y));
 293
 294         // Accumulate
 295         CONVOLUTION1x5_BIFROST(pixels1, src0, weights_row00, weights_row01);
 296
 297         src_addr += src_stride_z;
 298         weights_addr += weights_stride_z;
 299     }
 300
 301 #ifdef HAS_BIAS
 302     Vector biases = CONVERT_TO_VECTOR_STRUCT_NO_STEP(biases);
 303
 304     float4 bias = (float4) * ((__global float *)(vector_offset(&biases, kernel_index)));
 305
 306     pixels0 += bias;
 307     pixels1 += bias;
 308 #endif /* defined(HAS_BIAS) */
 309
 310     vstore4(pixels0, 0, (__global float *)(dst.ptr + 0 * dst_stride_y));
 311     vstore4(pixels1, 0, (__global float *)(dst.ptr + 1 * dst_stride_y));
 312 }
 313 #endif // defined(WEIGHTS_DEPTH)