src/clients/meson.build

   1 simple_shm_shell_files = ['simple-shm-shell.c']
   2 simple_shm_shell_deps = [
   3   dependency('wayland-client', required: true),
   4 ]
   5
   6 executable('ds-simple-shm-shell',
   7   simple_shm_shell_files,
   8   dependencies: simple_shm_shell_deps,
   9   install_dir: libds_bindir,
  10   install: true,
  11 )
  12
  13 wayland_tbm_client = dependency('wayland-tbm-client', required: false)
  14 libtbm = dependency('libtbm', required: false)
  15 tizen_extension_client = dependency('tizen-extension-client', required: true)
  16
  17 if not wayland_tbm_client.found() or not libtbm.found()
  18   subdir_done()
  19 endif
  20
  21 simple_tbm_files = ['simple-tbm.c']
  22 simple_tbm_deps = [
  23   dependency('wayland-client', required: true),
  24   wayland_tbm_client,
  25   libtbm,
  26   tizen_extension_client,
  27 ]
  28
  29 protocols = {
  30   'xdg-shell': wl_protocol_dir / 'stable/xdg-shell/xdg-shell.xml',
  31 }
  32
  33 protocols_code = {}
  34 protocols_client_header = {}
  35 foreach name, path : protocols
  36   code = custom_target(
  37     name.underscorify() + '_c',
  38     input: path,
  39     output: '@BASENAME@-protocol.c',
  40     command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
  41     )
  42   simple_tbm_files += code
  43
  44   client_header = custom_target(
  45     name.underscorify() + '_client_h',
  46     input: path,
  47     output: '@BASENAME@-client-protocol.h',
  48     command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
  49     build_by_default: false,
  50   )
  51   simple_tbm_files += client_header
  52 endforeach
  53
  54 executable('ds-simple-tbm',
  55   simple_tbm_files,
  56   dependencies: simple_tbm_deps,
  57   install_dir: libds_bindir,
  58   install: true,
  59 )
  60
  61 executable('ds-simple-dpms',
  62   'simple-dpms.c',
  63   dependencies: [
  64       dependency('wayland-client', required: true),
  65       dependency('tizen-dpms-client', required: true),
  66     ],
  67   install_dir: libds_bindir,
  68   install: true,
  69 )
  70
  71 input_generator_files = ['input-generator.c']
  72 input_generator_deps = [
  73   dependency('wayland-client', required: true),
  74   tizen_extension_client,
  75 ]
  76
  77 executable('input-generator',
  78   input_generator_files,
  79   dependencies: input_generator_deps,
  80   install_dir: libds_bindir,
  81   install: true,
  82 )