1 # Copyright (c) 2015-2016 The Khronos Group Inc.
3 # Permission is hereby granted, free of charge, to any person obtaining a
4 # copy of this software and/or associated documentation files (the
5 # "Materials"), to deal in the Materials without restriction, including
6 # without limitation the rights to use, copy, modify, merge, publish,
7 # distribute, sublicense, and/or sell copies of the Materials, and to
8 # permit persons to whom the Materials are furnished to do so, subject to
9 # the following conditions:
11 # The above copyright notice and this permission notice shall be included
12 # in all copies or substantial portions of the Materials.
14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
17 # https://www.khronos.org/registry/
19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
27 set(GRAMMAR_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_grammar_tables.py")
29 # macro() definitions are used in the following because we need to append .inc
30 # file paths into some global lists (*_CPP_DEPENDS). And those global lists are
31 # later used by set_source_files_properties() calls.
32 # function() definitions are not suitable because they create new scopes.
33 macro(spvtools_core_tables VERSION)
34 set(GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/spirv-${VERSION}.core.grammar.json")
35 set(GRAMMAR_INSTS_INC_FILE "${spirv-tools_BINARY_DIR}/core.insts-${VERSION}.inc")
36 set(GRAMMAR_KINDS_INC_FILE "${spirv-tools_BINARY_DIR}/operand.kinds-${VERSION}.inc")
37 add_custom_command(OUTPUT ${GRAMMAR_INSTS_INC_FILE} ${GRAMMAR_KINDS_INC_FILE}
38 COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
39 --spirv-core-grammar=${GRAMMAR_JSON_FILE}
40 --core-insts-output=${GRAMMAR_INSTS_INC_FILE}
41 --operand-kinds-output=${GRAMMAR_KINDS_INC_FILE}
42 DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
43 COMMENT "Generate info tables for SPIR-V v${VERSION} core instructions and operands.")
44 list(APPEND OPCODE_CPP_DEPENDS ${GRAMMAR_INSTS_INC_FILE})
45 list(APPEND OPERAND_CPP_DEPENDS ${GRAMMAR_KINDS_INC_FILE})
46 endmacro(spvtools_core_tables)
48 macro(spvtools_glsl_tables VERSION)
49 set(CORE_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/spirv-${VERSION}.core.grammar.json")
50 set(GLSL_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/extinst-${VERSION}.glsl.std.450.grammar.json")
51 set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/glsl.std.450.insts-${VERSION}.inc")
52 add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
53 COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
54 --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
55 --extinst-glsl-grammar=${GLSL_GRAMMAR_JSON_FILE}
56 --glsl-insts-output=${GRAMMAR_INC_FILE}
57 DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${GLSL_GRAMMAR_JSON_FILE}
58 COMMENT "Generate info tables for GLSL extended instructions and operands v${VERSION}.")
59 list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
60 endmacro(spvtools_glsl_tables)
62 macro(spvtools_opencl_tables VERSION)
63 set(CORE_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/spirv-${VERSION}.core.grammar.json")
64 set(OPENCL_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/extinst-${VERSION}.opencl.std.grammar.json")
65 set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/opencl.std.insts-${VERSION}.inc")
66 add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
67 COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
68 --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
69 --extinst-opencl-grammar=${OPENCL_GRAMMAR_JSON_FILE}
70 --opencl-insts-output=${GRAMMAR_INC_FILE}
71 DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${OPENCL_GRAMMAR_JSON_FILE}
72 COMMENT "Generate info tables for OpenCL extended instructions and operands v${VERSION}.")
73 list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
74 endmacro(spvtools_opencl_tables)
76 spvtools_core_tables("1-0")
77 spvtools_core_tables("1-1")
78 spvtools_opencl_tables("1-0")
79 spvtools_glsl_tables("1-0")
81 # The following .cpp files include the above generated .inc files.
82 # Add those .inc files as their dependencies.
84 # Why using such an awkward way?
85 # * If we use add_custom_target() to define a target to generate all .inc files
86 # and let ${SPIRV_TOOLS} depend on it, then we need to run ninja twice every
87 # time the grammar is updated: the first time is for generating those .inc
88 # files, and the second time is for rebuilding .cpp files, when ninja finds
89 # out that .inc files are updated.
90 # * If we use add_custom_command() with PRE_BUILD, then the grammar processing
91 # script will always run no matter whether the grammar is updated.
92 # * add_dependencies() is used to add *target* dependencies to a target.
93 # * The following solution only generates .inc files when the script or the
94 # grammar files is updated, and in a single ninja run.
95 set_source_files_properties(
96 ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
97 PROPERTIES OBJECT_DEPENDS "${OPCODE_CPP_DEPENDS}")
98 set_source_files_properties(
99 ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
100 PROPERTIES OBJECT_DEPENDS "${OPERAND_CPP_DEPENDS}")
101 set_source_files_properties(
102 ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
103 PROPERTIES OBJECT_DEPENDS "${EXTINST_CPP_DEPENDS}")
106 ${spirv-tools_SOURCE_DIR}/include/spirv-tools/libspirv.h
107 ${spirv-tools_SOURCE_DIR}/include/spirv/spirv.h
108 ${spirv-tools_SOURCE_DIR}/include/spirv/GLSL.std.450.h
109 ${spirv-tools_SOURCE_DIR}/include/spirv/OpenCL.std.h
111 ${CMAKE_CURRENT_SOURCE_DIR}/util/bitutils.h
112 ${CMAKE_CURRENT_SOURCE_DIR}/util/hex_float.h
113 ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.h
114 ${CMAKE_CURRENT_SOURCE_DIR}/binary.h
115 ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.h
116 ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.h
117 ${CMAKE_CURRENT_SOURCE_DIR}/instruction.h
118 ${CMAKE_CURRENT_SOURCE_DIR}/opcode.h
119 ${CMAKE_CURRENT_SOURCE_DIR}/operand.h
120 ${CMAKE_CURRENT_SOURCE_DIR}/print.h
121 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_constant.h
122 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_definition.h
123 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.h
124 ${CMAKE_CURRENT_SOURCE_DIR}/table.h
125 ${CMAKE_CURRENT_SOURCE_DIR}/text.h
126 ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.h
127 ${CMAKE_CURRENT_SOURCE_DIR}/validate.h
129 ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.cpp
130 ${CMAKE_CURRENT_SOURCE_DIR}/binary.cpp
131 ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.cpp
132 ${CMAKE_CURRENT_SOURCE_DIR}/disassemble.cpp
133 ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.cpp
134 ${CMAKE_CURRENT_SOURCE_DIR}/instruction.cpp
135 ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
136 ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
137 ${CMAKE_CURRENT_SOURCE_DIR}/print.cpp
138 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.cpp
139 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_target_env.cpp
140 ${CMAKE_CURRENT_SOURCE_DIR}/table.cpp
141 ${CMAKE_CURRENT_SOURCE_DIR}/text.cpp
142 ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.cpp
143 ${CMAKE_CURRENT_SOURCE_DIR}/validate.cpp
144 ${CMAKE_CURRENT_SOURCE_DIR}/validate_cfg.cpp
145 ${CMAKE_CURRENT_SOURCE_DIR}/validate_id.cpp
146 ${CMAKE_CURRENT_SOURCE_DIR}/validate_instruction.cpp
147 ${CMAKE_CURRENT_SOURCE_DIR}/validate_layout.cpp
148 ${CMAKE_CURRENT_SOURCE_DIR}/validate_ssa.cpp
149 ${CMAKE_CURRENT_SOURCE_DIR}/validate_types.cpp)
151 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
152 spvtools_default_compile_options(${SPIRV_TOOLS})
153 target_include_directories(${SPIRV_TOOLS}
154 PUBLIC ${spirv-tools_SOURCE_DIR}/include
155 PRIVATE ${spirv-tools_BINARY_DIR}
158 install(TARGETS ${SPIRV_TOOLS}
159 RUNTIME DESTINATION bin
160 LIBRARY DESTINATION lib
161 ARCHIVE DESTINATION lib)